src/gromacs/gpu_utils/tests/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Arrange to compile files with test infrastructure as normal C++, and
  36 # other files that sometimes have platform-specific symbols using the
  37 # required infrastructure to compile and link, without needing three
  38 # different files and strategies for the different GPU implementation
  39 # flavours.
  40
  41 # Always compiled as plain C++
  42 file(GLOB SOURCES_FROM_CXX
  43     clfftinitializer.cpp
  44     hostallocator.cpp
  45     )
  46
  47 if(GMX_USE_CUDA)
  48     # CUDA-only test
  49     list(APPEND SOURCES_FROM_CXX
  50         pinnedmemorychecker.cpp
  51         )
  52     # TODO Making a separate library is heavy handed, but nothing else
  53     # seems to work. Also don't use a hyphen in its name, because nvcc
  54     # can't cope with that.
  55     #
  56     # Perhaps FindCUDA's support for single compilation units will help?
  57     if (NOT GMX_CLANG_CUDA)
  58         # Work around FindCUDA that prevents using target_link_libraries()
  59         # with keywords otherwise...
  60         set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
  61         cuda_add_library(gpu_utilstest_cuda
  62             devicetransfers.cu
  63             )
  64     else()
  65         include(gmxClangCudaUtils)
  66         gmx_compile_cuda_file_with_clang(devicetransfers.cu)
  67         add_library(gpu_utilstest_cuda
  68             devicetransfers.cu
  69             )
  70     endif()
  71
  72     target_link_libraries(gpu_utilstest_cuda PRIVATE ${GMX_EXTRA_LIBRARIES} libgromacs)
  73
  74 elseif(GMX_USE_OPENCL)
  75     # Do normal compilation of OpenCL files
  76     list(APPEND SOURCES_FROM_CXX
  77         devicetransfers_ocl.cpp
  78         )
  79 else()
  80     # Do normal compilation of files with null implementations
  81     list(APPEND SOURCES_FROM_CXX
  82         devicetransfers.cpp
  83         )
  84 endif()
  85
  86 gmx_add_unit_test(GpuUtilsUnitTests gpu_utils-test
  87     # Infrastructure
  88     gputest.cpp
  89     # Tests of code
  90     ${SOURCES_FROM_CXX}
  91     )
  92
  93 if(GMX_USE_CUDA)
  94     target_link_libraries(gpu_utils-test PRIVATE gpu_utilstest_cuda)
  95 endif()
  96 if(GMX_USE_OPENCL)
  97     target_link_libraries(gpu_utils-test PRIVATE ${OpenCL_LIBRARIES})
  98 endif()