src/gromacs/gpu_utils/devicebuffer.cuh

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2018,2019,2020, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 #ifndef GMX_GPU_UTILS_DEVICEBUFFER_CUH
  36 #define GMX_GPU_UTILS_DEVICEBUFFER_CUH
  37
  38 /*! \libinternal \file
  39  *  \brief Implements the DeviceBuffer type and routines for CUDA.
  40  *  Should only be included directly by the main DeviceBuffer file devicebuffer.h.
  41  *  TODO: the intent is for DeviceBuffer to become a class.
  42  *
  43  *  \author Aleksei Iupinov <a.yupinov@gmail.com>
  44  *
  45  *  \inlibraryapi
  46  */
  47
  48 #include "gromacs/gpu_utils/cuda_arch_utils.cuh"
  49 #include "gromacs/gpu_utils/cudautils.cuh"
  50 #include "gromacs/gpu_utils/device_context.h"
  51 #include "gromacs/gpu_utils/device_stream.h"
  52 #include "gromacs/gpu_utils/devicebuffer_datatype.h"
  53 #include "gromacs/gpu_utils/gpu_utils.h" //only for GpuApiCallBehavior
  54 #include "gromacs/gpu_utils/gputraits.cuh"
  55 #include "gromacs/utility/gmxassert.h"
  56 #include "gromacs/utility/stringutil.h"
  57
  58 /*! \brief
  59  * Allocates a device-side buffer.
  60  * It is currently a caller's responsibility to call it only on not-yet allocated buffers.
  61  *
  62  * \tparam        ValueType            Raw value type of the \p buffer.
  63  * \param[in,out] buffer               Pointer to the device-side buffer.
  64  * \param[in]     numValues            Number of values to accommodate.
  65  * \param[in]     deviceContext        The buffer's dummy device  context - not managed explicitly in CUDA RT.
  66  */
  67 template<typename ValueType>
  68 void allocateDeviceBuffer(DeviceBuffer<ValueType>* buffer, size_t numValues, const DeviceContext& /* deviceContext */)
  69 {
  70     GMX_ASSERT(buffer, "needs a buffer pointer");
  71     cudaError_t stat = cudaMalloc((void**)buffer, numValues * sizeof(ValueType));
  72     GMX_RELEASE_ASSERT(
  73             stat == cudaSuccess,
  74             ("Allocation of the device buffer failed. " + gmx::getDeviceErrorString(stat)).c_str());
  75 }
  76
  77 /*! \brief
  78  * Frees a device-side buffer.
  79  * This does not reset separately stored size/capacity integers,
  80  * as this is planned to be a destructor of DeviceBuffer as a proper class,
  81  * and no calls on \p buffer should be made afterwards.
  82  *
  83  * \param[in] buffer  Pointer to the buffer to free.
  84  */
  85 template<typename DeviceBuffer>
  86 void freeDeviceBuffer(DeviceBuffer* buffer)
  87 {
  88     GMX_ASSERT(buffer, "needs a buffer pointer");
  89     if (*buffer)
  90     {
  91         cudaError_t stat = cudaFree(*buffer);
  92         GMX_RELEASE_ASSERT(
  93                 stat == cudaSuccess,
  94                 ("Freeing of the device buffer failed. " + gmx::getDeviceErrorString(stat)).c_str());
  95     }
  96 }
  97
  98 /*! \brief
  99  * Performs the host-to-device data copy, synchronous or asynchronously on request.
 100  *
 101  * \tparam        ValueType            Raw value type of the \p buffer.
 102  * \param[in,out] buffer               Pointer to the device-side buffer
 103  * \param[in]     hostBuffer           Pointer to the raw host-side memory, also typed \p ValueType
 104  * \param[in]     startingOffset       Offset (in values) at the device-side buffer to copy into.
 105  * \param[in]     numValues            Number of values to copy.
 106  * \param[in]     deviceStream         GPU stream to perform asynchronous copy in.
 107  * \param[in]     transferKind         Copy type: synchronous or asynchronous.
 108  * \param[out]    timingEvent          A dummy pointer to the H2D copy timing event to be filled in.
 109  *                                     Not used in CUDA implementation.
 110  */
 111 template<typename ValueType>
 112 void copyToDeviceBuffer(DeviceBuffer<ValueType>* buffer,
 113                         const ValueType*         hostBuffer,
 114                         size_t                   startingOffset,
 115                         size_t                   numValues,
 116                         const DeviceStream&      deviceStream,
 117                         GpuApiCallBehavior       transferKind,
 118                         CommandEvent* /*timingEvent*/)
 119 {
 120     if (numValues == 0)
 121     {
 122         return;
 123     }
 124     GMX_ASSERT(buffer, "needs a buffer pointer");
 125     GMX_ASSERT(hostBuffer, "needs a host buffer pointer");
 126     cudaError_t  stat;
 127     const size_t bytes = numValues * sizeof(ValueType);
 128
 129     switch (transferKind)
 130     {
 131         case GpuApiCallBehavior::Async:
 132             GMX_ASSERT(isHostMemoryPinned(hostBuffer),
 133                        "Source host buffer was not pinned for CUDA");
 134             stat = cudaMemcpyAsync(*((ValueType**)buffer) + startingOffset, hostBuffer, bytes,
 135                                    cudaMemcpyHostToDevice, deviceStream.stream());
 136             GMX_RELEASE_ASSERT(
 137                     stat == cudaSuccess,
 138                     ("Asynchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 139             break;
 140
 141         case GpuApiCallBehavior::Sync:
 142             stat = cudaMemcpy(*((ValueType**)buffer) + startingOffset, hostBuffer, bytes,
 143                               cudaMemcpyHostToDevice);
 144             GMX_RELEASE_ASSERT(
 145                     stat == cudaSuccess,
 146                     ("Synchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 147             break;
 148
 149         default: throw;
 150     }
 151 }
 152
 153 /*! \brief
 154  * Performs the device-to-host data copy, synchronous or asynchronously on request.
 155  *
 156  * \tparam        ValueType            Raw value type of the \p buffer.
 157  * \param[in,out] hostBuffer           Pointer to the raw host-side memory, also typed \p ValueType
 158  * \param[in]     buffer               Pointer to the device-side buffer
 159  * \param[in]     startingOffset       Offset (in values) at the device-side buffer to copy from.
 160  * \param[in]     numValues            Number of values to copy.
 161  * \param[in]     deviceStream         GPU stream to perform asynchronous copy in.
 162  * \param[in]     transferKind         Copy type: synchronous or asynchronous.
 163  * \param[out]    timingEvent          A dummy pointer to the H2D copy timing event to be filled in.
 164  *                                     Not used in CUDA implementation.
 165  */
 166 template<typename ValueType>
 167 void copyFromDeviceBuffer(ValueType*               hostBuffer,
 168                           DeviceBuffer<ValueType>* buffer,
 169                           size_t                   startingOffset,
 170                           size_t                   numValues,
 171                           const DeviceStream&      deviceStream,
 172                           GpuApiCallBehavior       transferKind,
 173                           CommandEvent* /*timingEvent*/)
 174 {
 175     if (numValues == 0)
 176     {
 177         return;
 178     }
 179     GMX_ASSERT(buffer, "needs a buffer pointer");
 180     GMX_ASSERT(hostBuffer, "needs a host buffer pointer");
 181
 182     cudaError_t  stat;
 183     const size_t bytes = numValues * sizeof(ValueType);
 184     switch (transferKind)
 185     {
 186         case GpuApiCallBehavior::Async:
 187             GMX_ASSERT(isHostMemoryPinned(hostBuffer),
 188                        "Destination host buffer was not pinned for CUDA");
 189             stat = cudaMemcpyAsync(hostBuffer, *((ValueType**)buffer) + startingOffset, bytes,
 190                                    cudaMemcpyDeviceToHost, deviceStream.stream());
 191             GMX_RELEASE_ASSERT(
 192                     stat == cudaSuccess,
 193                     ("Asynchronous D2H copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 194             break;
 195
 196         case GpuApiCallBehavior::Sync:
 197             stat = cudaMemcpy(hostBuffer, *((ValueType**)buffer) + startingOffset, bytes,
 198                               cudaMemcpyDeviceToHost);
 199             GMX_RELEASE_ASSERT(
 200                     stat == cudaSuccess,
 201                     ("Synchronous D2H copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 202             break;
 203
 204         default: throw;
 205     }
 206 }
 207
 208 /*! \brief
 209  * Clears the device buffer asynchronously.
 210  *
 211  * \tparam        ValueType       Raw value type of the \p buffer.
 212  * \param[in,out] buffer          Pointer to the device-side buffer
 213  * \param[in]     startingOffset  Offset (in values) at the device-side buffer to start clearing at.
 214  * \param[in]     numValues       Number of values to clear.
 215  * \param[in]     deviceStream    GPU stream.
 216  */
 217 template<typename ValueType>
 218 void clearDeviceBufferAsync(DeviceBuffer<ValueType>* buffer,
 219                             size_t                   startingOffset,
 220                             size_t                   numValues,
 221                             const DeviceStream&      deviceStream)
 222 {
 223     GMX_ASSERT(buffer, "needs a buffer pointer");
 224     const size_t bytes   = numValues * sizeof(ValueType);
 225     const char   pattern = 0;
 226
 227     cudaError_t stat = cudaMemsetAsync(*((ValueType**)buffer) + startingOffset, pattern, bytes,
 228                                        deviceStream.stream());
 229     GMX_RELEASE_ASSERT(stat == cudaSuccess,
 230                        ("Couldn't clear the device buffer. " + gmx::getDeviceErrorString(stat)).c_str());
 231 }
 232
 233 /*! \brief Check the validity of the device buffer.
 234  *
 235  * Checks if the buffer is not nullptr.
 236  *
 237  * \todo Add checks on the buffer size when it will be possible.
 238  *
 239  * \param[in] buffer        Device buffer to be checked.
 240  * \param[in] requiredSize  Number of elements that the buffer will have to accommodate.
 241  *
 242  * \returns Whether the device buffer can be set.
 243  */
 244 template<typename T>
 245 gmx_unused static bool checkDeviceBuffer(DeviceBuffer<T> buffer, gmx_unused int requiredSize)
 246 {
 247     GMX_ASSERT(buffer != nullptr, "The device pointer is nullptr");
 248     return buffer != nullptr;
 249 }
 250
 251 //! Device texture wrapper.
 252 using DeviceTexture = cudaTextureObject_t;
 253
 254 /*! \brief Create a texture object for an array of type ValueType.
 255  *
 256  * Creates the device buffer, copies data and binds texture object for an array of type ValueType.
 257  *
 258  * \todo Test if using textures is still relevant on modern hardware.
 259  *
 260  * \tparam      ValueType      Raw data type.
 261  *
 262  * \param[out]  deviceBuffer   Device buffer to store data in.
 263  * \param[out]  deviceTexture  Device texture object to initialize.
 264  * \param[in]   hostBuffer     Host buffer to get date from
 265  * \param[in]   numValues      Number of elements in the buffer.
 266  * \param[in]   deviceContext  GPU device context.
 267  */
 268 template<typename ValueType>
 269 void initParamLookupTable(DeviceBuffer<ValueType>* deviceBuffer,
 270                           DeviceTexture*           deviceTexture,
 271                           const ValueType*         hostBuffer,
 272                           int                      numValues,
 273                           const DeviceContext&     deviceContext)
 274 {
 275     if (numValues == 0)
 276     {
 277         return;
 278     }
 279     GMX_ASSERT(hostBuffer, "Host buffer should be specified.");
 280
 281     allocateDeviceBuffer(deviceBuffer, numValues, deviceContext);
 282
 283     const size_t sizeInBytes = numValues * sizeof(ValueType);
 284
 285     cudaError_t stat =
 286             cudaMemcpy(*((ValueType**)deviceBuffer), hostBuffer, sizeInBytes, cudaMemcpyHostToDevice);
 287
 288     GMX_RELEASE_ASSERT(stat == cudaSuccess,
 289                        ("Synchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 290
 291     if (!c_disableCudaTextures)
 292     {
 293         cudaResourceDesc rd;
 294         cudaTextureDesc  td;
 295
 296         memset(&rd, 0, sizeof(rd));
 297         rd.resType                = cudaResourceTypeLinear;
 298         rd.res.linear.devPtr      = *deviceBuffer;
 299         rd.res.linear.desc        = cudaCreateChannelDesc<ValueType>();
 300         rd.res.linear.sizeInBytes = sizeInBytes;
 301
 302         memset(&td, 0, sizeof(td));
 303         td.readMode = cudaReadModeElementType;
 304         stat        = cudaCreateTextureObject(deviceTexture, &rd, &td, nullptr);
 305         GMX_RELEASE_ASSERT(
 306                 stat == cudaSuccess,
 307                 ("Binding of the texture object failed. " + gmx::getDeviceErrorString(stat)).c_str());
 308     }
 309 }
 310
 311 /*! \brief Unbind the texture and release the CUDA texture object.
 312  *
 313  * \tparam         ValueType      Raw data type
 314  *
 315  * \param[in,out]  deviceBuffer   Device buffer to store data in.
 316  * \param[in,out]  deviceTexture  Device texture object to unbind.
 317  */
 318 template<typename ValueType>
 319 void destroyParamLookupTable(DeviceBuffer<ValueType>* deviceBuffer, DeviceTexture& deviceTexture)
 320 {
 321     if (!c_disableCudaTextures && deviceTexture && deviceBuffer)
 322     {
 323         cudaError_t stat = cudaDestroyTextureObject(deviceTexture);
 324         GMX_RELEASE_ASSERT(
 325                 stat == cudaSuccess,
 326                 ("Destruction of the texture object failed. " + gmx::getDeviceErrorString(stat)).c_str());
 327     }
 328     freeDeviceBuffer(deviceBuffer);
 329 }
 330
 331 #endif