src/gromacs/gpu_utils/devicebuffer.cuh

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2018,2019,2020, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 #ifndef GMX_GPU_UTILS_DEVICEBUFFER_CUH
  36 #define GMX_GPU_UTILS_DEVICEBUFFER_CUH
  37
  38 /*! \libinternal \file
  39  *  \brief Implements the DeviceBuffer type and routines for CUDA.
  40  *  Should only be included directly by the main DeviceBuffer file devicebuffer.h.
  41  *  TODO: the intent is for DeviceBuffer to become a class.
  42  *
  43  *  \author Aleksei Iupinov <a.yupinov@gmail.com>
  44  *
  45  *  \inlibraryapi
  46  */
  47
  48 #include "gromacs/gpu_utils/cuda_arch_utils.cuh"
  49 #include "gromacs/gpu_utils/cudautils.cuh"
  50 #include "gromacs/gpu_utils/device_context.h"
  51 #include "gromacs/gpu_utils/device_stream.h"
  52 #include "gromacs/gpu_utils/devicebuffer_datatype.h"
  53 #include "gromacs/gpu_utils/gpu_utils.h" //only for GpuApiCallBehavior
  54 #include "gromacs/gpu_utils/gputraits.cuh"
  55 #include "gromacs/utility/gmxassert.h"
  56 #include "gromacs/utility/stringutil.h"
  57
  58 /*! \brief
  59  * Allocates a device-side buffer.
  60  * It is currently a caller's responsibility to call it only on not-yet allocated buffers.
  61  *
  62  * \tparam        ValueType            Raw value type of the \p buffer.
  63  * \param[in,out] buffer               Pointer to the device-side buffer.
  64  * \param[in]     numValues            Number of values to accommodate.
  65  * \param[in]     deviceContext        The buffer's dummy device  context - not managed explicitly in CUDA RT.
  66  */
  67 template<typename ValueType>
  68 void allocateDeviceBuffer(DeviceBuffer<ValueType>* buffer, size_t numValues, const DeviceContext& /* deviceContext */)
  69 {
  70     GMX_ASSERT(buffer, "needs a buffer pointer");
  71     cudaError_t stat = cudaMalloc((void**)buffer, numValues * sizeof(ValueType));
  72     GMX_RELEASE_ASSERT(
  73             stat == cudaSuccess,
  74             ("Allocation of the device buffer failed. " + gmx::getDeviceErrorString(stat)).c_str());
  75 }
  76
  77 /*! \brief
  78  * Frees a device-side buffer.
  79  * This does not reset separately stored size/capacity integers,
  80  * as this is planned to be a destructor of DeviceBuffer as a proper class,
  81  * and no calls on \p buffer should be made afterwards.
  82  *
  83  * \param[in] buffer  Pointer to the buffer to free.
  84  */
  85 template<typename DeviceBuffer>
  86 void freeDeviceBuffer(DeviceBuffer* buffer)
  87 {
  88     GMX_ASSERT(buffer, "needs a buffer pointer");
  89     if (*buffer)
  90     {
  91         cudaError_t stat = cudaFree(*buffer);
  92         GMX_RELEASE_ASSERT(
  93                 stat == cudaSuccess,
  94                 ("Freeing of the device buffer failed. " + gmx::getDeviceErrorString(stat)).c_str());
  95     }
  96 }
  97
  98 /*! \brief
  99  * Performs the host-to-device data copy, synchronous or asynchronously on request.
 100  *
 101  * \tparam        ValueType            Raw value type of the \p buffer.
 102  * \param[in,out] buffer               Pointer to the device-side buffer
 103  * \param[in]     hostBuffer           Pointer to the raw host-side memory, also typed \p ValueType
 104  * \param[in]     startingOffset       Offset (in values) at the device-side buffer to copy into.
 105  * \param[in]     numValues            Number of values to copy.
 106  * \param[in]     deviceStream         GPU stream to perform asynchronous copy in.
 107  * \param[in]     transferKind         Copy type: synchronous or asynchronous.
 108  * \param[out]    timingEvent          A dummy pointer to the H2D copy timing event to be filled in.
 109  *                                     Not used in CUDA implementation.
 110  */
 111 template<typename ValueType>
 112 void copyToDeviceBuffer(DeviceBuffer<ValueType>* buffer,
 113                         const ValueType*         hostBuffer,
 114                         size_t                   startingOffset,
 115                         size_t                   numValues,
 116                         const DeviceStream&      deviceStream,
 117                         GpuApiCallBehavior       transferKind,
 118                         CommandEvent* /*timingEvent*/)
 119 {
 120     if (numValues == 0)
 121     {
 122         return;
 123     }
 124     GMX_ASSERT(buffer, "needs a buffer pointer");
 125     GMX_ASSERT(hostBuffer, "needs a host buffer pointer");
 126     cudaError_t  stat;
 127     const size_t bytes = numValues * sizeof(ValueType);
 128
 129     switch (transferKind)
 130     {
 131         case GpuApiCallBehavior::Async:
 132             GMX_ASSERT(isHostMemoryPinned(hostBuffer), "Source host buffer was not pinned for CUDA");
 133             stat = cudaMemcpyAsync(*((ValueType**)buffer) + startingOffset,
 134                                    hostBuffer,
 135                                    bytes,
 136                                    cudaMemcpyHostToDevice,
 137                                    deviceStream.stream());
 138             GMX_RELEASE_ASSERT(
 139                     stat == cudaSuccess,
 140                     ("Asynchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 141             break;
 142
 143         case GpuApiCallBehavior::Sync:
 144             stat = cudaMemcpy(
 145                     *((ValueType**)buffer) + startingOffset, hostBuffer, bytes, cudaMemcpyHostToDevice);
 146             GMX_RELEASE_ASSERT(
 147                     stat == cudaSuccess,
 148                     ("Synchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 149             break;
 150
 151         default: throw;
 152     }
 153 }
 154
 155 /*! \brief
 156  * Performs the device-to-host data copy, synchronous or asynchronously on request.
 157  *
 158  * \tparam        ValueType            Raw value type of the \p buffer.
 159  * \param[in,out] hostBuffer           Pointer to the raw host-side memory, also typed \p ValueType
 160  * \param[in]     buffer               Pointer to the device-side buffer
 161  * \param[in]     startingOffset       Offset (in values) at the device-side buffer to copy from.
 162  * \param[in]     numValues            Number of values to copy.
 163  * \param[in]     deviceStream         GPU stream to perform asynchronous copy in.
 164  * \param[in]     transferKind         Copy type: synchronous or asynchronous.
 165  * \param[out]    timingEvent          A dummy pointer to the H2D copy timing event to be filled in.
 166  *                                     Not used in CUDA implementation.
 167  */
 168 template<typename ValueType>
 169 void copyFromDeviceBuffer(ValueType*               hostBuffer,
 170                           DeviceBuffer<ValueType>* buffer,
 171                           size_t                   startingOffset,
 172                           size_t                   numValues,
 173                           const DeviceStream&      deviceStream,
 174                           GpuApiCallBehavior       transferKind,
 175                           CommandEvent* /*timingEvent*/)
 176 {
 177     if (numValues == 0)
 178     {
 179         return;
 180     }
 181     GMX_ASSERT(buffer, "needs a buffer pointer");
 182     GMX_ASSERT(hostBuffer, "needs a host buffer pointer");
 183
 184     cudaError_t  stat;
 185     const size_t bytes = numValues * sizeof(ValueType);
 186     switch (transferKind)
 187     {
 188         case GpuApiCallBehavior::Async:
 189             GMX_ASSERT(isHostMemoryPinned(hostBuffer),
 190                        "Destination host buffer was not pinned for CUDA");
 191             stat = cudaMemcpyAsync(hostBuffer,
 192                                    *((ValueType**)buffer) + startingOffset,
 193                                    bytes,
 194                                    cudaMemcpyDeviceToHost,
 195                                    deviceStream.stream());
 196             GMX_RELEASE_ASSERT(
 197                     stat == cudaSuccess,
 198                     ("Asynchronous D2H copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 199             break;
 200
 201         case GpuApiCallBehavior::Sync:
 202             stat = cudaMemcpy(
 203                     hostBuffer, *((ValueType**)buffer) + startingOffset, bytes, cudaMemcpyDeviceToHost);
 204             GMX_RELEASE_ASSERT(
 205                     stat == cudaSuccess,
 206                     ("Synchronous D2H copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 207             break;
 208
 209         default: throw;
 210     }
 211 }
 212
 213 /*! \brief
 214  * Clears the device buffer asynchronously.
 215  *
 216  * \tparam        ValueType       Raw value type of the \p buffer.
 217  * \param[in,out] buffer          Pointer to the device-side buffer
 218  * \param[in]     startingOffset  Offset (in values) at the device-side buffer to start clearing at.
 219  * \param[in]     numValues       Number of values to clear.
 220  * \param[in]     deviceStream    GPU stream.
 221  */
 222 template<typename ValueType>
 223 void clearDeviceBufferAsync(DeviceBuffer<ValueType>* buffer,
 224                             size_t                   startingOffset,
 225                             size_t                   numValues,
 226                             const DeviceStream&      deviceStream)
 227 {
 228     GMX_ASSERT(buffer, "needs a buffer pointer");
 229     const size_t bytes   = numValues * sizeof(ValueType);
 230     const char   pattern = 0;
 231
 232     cudaError_t stat = cudaMemsetAsync(
 233             *((ValueType**)buffer) + startingOffset, pattern, bytes, deviceStream.stream());
 234     GMX_RELEASE_ASSERT(stat == cudaSuccess,
 235                        ("Couldn't clear the device buffer. " + gmx::getDeviceErrorString(stat)).c_str());
 236 }
 237
 238 /*! \brief Check the validity of the device buffer.
 239  *
 240  * Checks if the buffer is not nullptr.
 241  *
 242  * \todo Add checks on the buffer size when it will be possible.
 243  *
 244  * \param[in] buffer        Device buffer to be checked.
 245  * \param[in] requiredSize  Number of elements that the buffer will have to accommodate.
 246  *
 247  * \returns Whether the device buffer can be set.
 248  */
 249 template<typename T>
 250 gmx_unused static bool checkDeviceBuffer(DeviceBuffer<T> buffer, gmx_unused int requiredSize)
 251 {
 252     GMX_ASSERT(buffer != nullptr, "The device pointer is nullptr");
 253     return buffer != nullptr;
 254 }
 255
 256 //! Device texture wrapper.
 257 using DeviceTexture = cudaTextureObject_t;
 258
 259 /*! \brief Create a texture object for an array of type ValueType.
 260  *
 261  * Creates the device buffer, copies data and binds texture object for an array of type ValueType.
 262  *
 263  * \todo Test if using textures is still relevant on modern hardware.
 264  *
 265  * \tparam      ValueType      Raw data type.
 266  *
 267  * \param[out]  deviceBuffer   Device buffer to store data in.
 268  * \param[out]  deviceTexture  Device texture object to initialize.
 269  * \param[in]   hostBuffer     Host buffer to get date from
 270  * \param[in]   numValues      Number of elements in the buffer.
 271  * \param[in]   deviceContext  GPU device context.
 272  */
 273 template<typename ValueType>
 274 void initParamLookupTable(DeviceBuffer<ValueType>* deviceBuffer,
 275                           DeviceTexture*           deviceTexture,
 276                           const ValueType*         hostBuffer,
 277                           int                      numValues,
 278                           const DeviceContext&     deviceContext)
 279 {
 280     if (numValues == 0)
 281     {
 282         return;
 283     }
 284     GMX_ASSERT(hostBuffer, "Host buffer should be specified.");
 285
 286     allocateDeviceBuffer(deviceBuffer, numValues, deviceContext);
 287
 288     const size_t sizeInBytes = numValues * sizeof(ValueType);
 289
 290     cudaError_t stat =
 291             cudaMemcpy(*((ValueType**)deviceBuffer), hostBuffer, sizeInBytes, cudaMemcpyHostToDevice);
 292
 293     GMX_RELEASE_ASSERT(stat == cudaSuccess,
 294                        ("Synchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 295
 296     if (!c_disableCudaTextures)
 297     {
 298         cudaResourceDesc rd;
 299         cudaTextureDesc  td;
 300
 301         memset(&rd, 0, sizeof(rd));
 302         rd.resType                = cudaResourceTypeLinear;
 303         rd.res.linear.devPtr      = *deviceBuffer;
 304         rd.res.linear.desc        = cudaCreateChannelDesc<ValueType>();
 305         rd.res.linear.sizeInBytes = sizeInBytes;
 306
 307         memset(&td, 0, sizeof(td));
 308         td.readMode = cudaReadModeElementType;
 309         stat        = cudaCreateTextureObject(deviceTexture, &rd, &td, nullptr);
 310         GMX_RELEASE_ASSERT(
 311                 stat == cudaSuccess,
 312                 ("Binding of the texture object failed. " + gmx::getDeviceErrorString(stat)).c_str());
 313     }
 314 }
 315
 316 /*! \brief Unbind the texture and release the CUDA texture object.
 317  *
 318  * \tparam         ValueType      Raw data type
 319  *
 320  * \param[in,out]  deviceBuffer   Device buffer to store data in.
 321  * \param[in,out]  deviceTexture  Device texture object to unbind.
 322  */
 323 template<typename ValueType>
 324 void destroyParamLookupTable(DeviceBuffer<ValueType>* deviceBuffer, DeviceTexture& deviceTexture)
 325 {
 326     if (!c_disableCudaTextures && deviceTexture && deviceBuffer)
 327     {
 328         cudaError_t stat = cudaDestroyTextureObject(deviceTexture);
 329         GMX_RELEASE_ASSERT(
 330                 stat == cudaSuccess,
 331                 ("Destruction of the texture object failed. " + gmx::getDeviceErrorString(stat)).c_str());
 332     }
 333     freeDeviceBuffer(deviceBuffer);
 334 }
 335
 336 #endif