src/gromacs/gpu_utils/devicebuffer.cuh

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2018,2019,2020,2021, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 #ifndef GMX_GPU_UTILS_DEVICEBUFFER_CUH
  36 #define GMX_GPU_UTILS_DEVICEBUFFER_CUH
  37
  38 /*! \libinternal \file
  39  *  \brief Implements the DeviceBuffer type and routines for CUDA.
  40  *  Should only be included directly by the main DeviceBuffer file devicebuffer.h.
  41  *  TODO: the intent is for DeviceBuffer to become a class.
  42  *
  43  *  \author Aleksei Iupinov <a.yupinov@gmail.com>
  44  *
  45  *  \inlibraryapi
  46  */
  47
  48 #include "gromacs/gpu_utils/cuda_arch_utils.cuh"
  49 #include "gromacs/gpu_utils/cudautils.cuh"
  50 #include "gromacs/gpu_utils/device_context.h"
  51 #include "gromacs/gpu_utils/device_stream.h"
  52 #include "gromacs/gpu_utils/devicebuffer_datatype.h"
  53 #include "gromacs/gpu_utils/gpu_utils.h" //only for GpuApiCallBehavior
  54 #include "gromacs/gpu_utils/gputraits.cuh"
  55 #include "gromacs/utility/gmxassert.h"
  56 #include "gromacs/utility/stringutil.h"
  57
  58 /*! \brief
  59  * Allocates a device-side buffer.
  60  * It is currently a caller's responsibility to call it only on not-yet allocated buffers.
  61  *
  62  * \tparam        ValueType            Raw value type of the \p buffer.
  63  * \param[in,out] buffer               Pointer to the device-side buffer.
  64  * \param[in]     numValues            Number of values to accommodate.
  65  * \param[in]     deviceContext        The buffer's dummy device  context - not managed explicitly in CUDA RT.
  66  */
  67 template<typename ValueType>
  68 void allocateDeviceBuffer(DeviceBuffer<ValueType>* buffer, size_t numValues, const DeviceContext& /* deviceContext */)
  69 {
  70     GMX_ASSERT(buffer, "needs a buffer pointer");
  71     cudaError_t stat = cudaMalloc((void**)buffer, numValues * sizeof(ValueType));
  72     GMX_RELEASE_ASSERT(
  73             stat == cudaSuccess,
  74             ("Allocation of the device buffer failed. " + gmx::getDeviceErrorString(stat)).c_str());
  75 }
  76
  77 /*! \brief
  78  * Frees a device-side buffer.
  79  * This does not reset separately stored size/capacity integers,
  80  * as this is planned to be a destructor of DeviceBuffer as a proper class,
  81  * and no calls on \p buffer should be made afterwards.
  82  *
  83  * \param[in] buffer  Pointer to the buffer to free.
  84  */
  85 template<typename DeviceBuffer>
  86 void freeDeviceBuffer(DeviceBuffer* buffer)
  87 {
  88     GMX_ASSERT(buffer, "needs a buffer pointer");
  89     if (*buffer)
  90     {
  91         cudaError_t stat = cudaFree(*buffer);
  92         GMX_RELEASE_ASSERT(
  93                 stat == cudaSuccess,
  94                 ("Freeing of the device buffer failed. " + gmx::getDeviceErrorString(stat)).c_str());
  95     }
  96 }
  97
  98 /*! \brief
  99  * Performs the host-to-device data copy, synchronous or asynchronously on request.
 100  *
 101  * \tparam        ValueType            Raw value type of the \p buffer.
 102  * \param[in,out] buffer               Pointer to the device-side buffer
 103  * \param[in]     hostBuffer           Pointer to the raw host-side memory, also typed \p ValueType
 104  * \param[in]     startingOffset       Offset (in values) at the device-side buffer to copy into.
 105  * \param[in]     numValues            Number of values to copy.
 106  * \param[in]     deviceStream         GPU stream to perform asynchronous copy in.
 107  * \param[in]     transferKind         Copy type: synchronous or asynchronous.
 108  * \param[out]    timingEvent          A dummy pointer to the H2D copy timing event to be filled in.
 109  *                                     Not used in CUDA implementation.
 110  */
 111 template<typename ValueType>
 112 void copyToDeviceBuffer(DeviceBuffer<ValueType>* buffer,
 113                         const ValueType*         hostBuffer,
 114                         size_t                   startingOffset,
 115                         size_t                   numValues,
 116                         const DeviceStream&      deviceStream,
 117                         GpuApiCallBehavior       transferKind,
 118                         CommandEvent* /*timingEvent*/)
 119 {
 120     if (numValues == 0)
 121     {
 122         return;
 123     }
 124     GMX_ASSERT(buffer, "needs a buffer pointer");
 125     GMX_ASSERT(hostBuffer, "needs a host buffer pointer");
 126     cudaError_t  stat;
 127     const size_t bytes = numValues * sizeof(ValueType);
 128
 129     switch (transferKind)
 130     {
 131         case GpuApiCallBehavior::Async:
 132             GMX_ASSERT(isHostMemoryPinned(hostBuffer), "Source host buffer was not pinned for CUDA");
 133             stat = cudaMemcpyAsync(*((ValueType**)buffer) + startingOffset,
 134                                    hostBuffer,
 135                                    bytes,
 136                                    cudaMemcpyHostToDevice,
 137                                    deviceStream.stream());
 138             GMX_RELEASE_ASSERT(
 139                     stat == cudaSuccess,
 140                     ("Asynchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 141             break;
 142
 143         case GpuApiCallBehavior::Sync:
 144             stat = cudaMemcpy(
 145                     *((ValueType**)buffer) + startingOffset, hostBuffer, bytes, cudaMemcpyHostToDevice);
 146             GMX_RELEASE_ASSERT(
 147                     stat == cudaSuccess,
 148                     ("Synchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 149             break;
 150
 151         default: throw;
 152     }
 153 }
 154
 155 /*! \brief
 156  * Performs the device-to-host data copy, synchronous or asynchronously on request.
 157  *
 158  * \tparam        ValueType            Raw value type of the \p buffer.
 159  * \param[in,out] hostBuffer           Pointer to the raw host-side memory, also typed \p ValueType
 160  * \param[in]     buffer               Pointer to the device-side buffer
 161  * \param[in]     startingOffset       Offset (in values) at the device-side buffer to copy from.
 162  * \param[in]     numValues            Number of values to copy.
 163  * \param[in]     deviceStream         GPU stream to perform asynchronous copy in.
 164  * \param[in]     transferKind         Copy type: synchronous or asynchronous.
 165  * \param[out]    timingEvent          A dummy pointer to the H2D copy timing event to be filled in.
 166  *                                     Not used in CUDA implementation.
 167  */
 168 template<typename ValueType>
 169 void copyFromDeviceBuffer(ValueType*               hostBuffer,
 170                           DeviceBuffer<ValueType>* buffer,
 171                           size_t                   startingOffset,
 172                           size_t                   numValues,
 173                           const DeviceStream&      deviceStream,
 174                           GpuApiCallBehavior       transferKind,
 175                           CommandEvent* /*timingEvent*/)
 176 {
 177     if (numValues == 0)
 178     {
 179         return;
 180     }
 181     GMX_ASSERT(buffer, "needs a buffer pointer");
 182     GMX_ASSERT(hostBuffer, "needs a host buffer pointer");
 183
 184     cudaError_t  stat;
 185     const size_t bytes = numValues * sizeof(ValueType);
 186     switch (transferKind)
 187     {
 188         case GpuApiCallBehavior::Async:
 189             GMX_ASSERT(isHostMemoryPinned(hostBuffer),
 190                        "Destination host buffer was not pinned for CUDA");
 191             stat = cudaMemcpyAsync(hostBuffer,
 192                                    *((ValueType**)buffer) + startingOffset,
 193                                    bytes,
 194                                    cudaMemcpyDeviceToHost,
 195                                    deviceStream.stream());
 196             GMX_RELEASE_ASSERT(
 197                     stat == cudaSuccess,
 198                     ("Asynchronous D2H copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 199             break;
 200
 201         case GpuApiCallBehavior::Sync:
 202             stat = cudaMemcpy(
 203                     hostBuffer, *((ValueType**)buffer) + startingOffset, bytes, cudaMemcpyDeviceToHost);
 204             GMX_RELEASE_ASSERT(
 205                     stat == cudaSuccess,
 206                     ("Synchronous D2H copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 207             break;
 208
 209         default: throw;
 210     }
 211 }
 212
 213 /*! \brief
 214  * Performs the device-to-device data copy, synchronous or asynchronously on request.
 215  *
 216  * \tparam        ValueType                Raw value type of the \p buffer.
 217  * \param[in,out] destinationDeviceBuffer  Device-side buffer to copy to
 218  * \param[in]     sourceDeviceBuffer       Device-side buffer to copy from
 219  * \param[in]     numValues                Number of values to copy.
 220  * \param[in]     deviceStream             GPU stream to perform asynchronous copy in.
 221  * \param[in]     transferKind             Copy type: synchronous or asynchronous.
 222  * \param[out]    timingEvent              A dummy pointer to the D2D copy timing event to be filled
 223  * in. Not used in CUDA implementation.
 224  */
 225 template<typename ValueType>
 226 void copyBetweenDeviceBuffers(DeviceBuffer<ValueType>* destinationDeviceBuffer,
 227                               DeviceBuffer<ValueType>* sourceDeviceBuffer,
 228                               size_t                   numValues,
 229                               const DeviceStream&      deviceStream,
 230                               GpuApiCallBehavior       transferKind,
 231                               CommandEvent* /*timingEvent*/)
 232 {
 233     if (numValues == 0)
 234     {
 235         return;
 236     }
 237     GMX_ASSERT(destinationDeviceBuffer, "needs a destination buffer pointer");
 238     GMX_ASSERT(sourceDeviceBuffer, "needs a source buffer pointer");
 239
 240     cudaError_t  stat;
 241     const size_t bytes = numValues * sizeof(ValueType);
 242     switch (transferKind)
 243     {
 244         case GpuApiCallBehavior::Async:
 245             stat = cudaMemcpyAsync(*destinationDeviceBuffer,
 246                                    *sourceDeviceBuffer,
 247                                    bytes,
 248                                    cudaMemcpyDeviceToDevice,
 249                                    deviceStream.stream());
 250             GMX_RELEASE_ASSERT(
 251                     stat == cudaSuccess,
 252                     ("Asynchronous D2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 253             break;
 254
 255         case GpuApiCallBehavior::Sync:
 256             stat = cudaMemcpy(*destinationDeviceBuffer, *sourceDeviceBuffer, bytes, cudaMemcpyDeviceToDevice);
 257             GMX_RELEASE_ASSERT(
 258                     stat == cudaSuccess,
 259                     ("Synchronous D2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 260             break;
 261
 262         default: throw;
 263     }
 264 }
 265
 266 /*! \brief
 267  * Clears the device buffer asynchronously.
 268  *
 269  * \tparam        ValueType       Raw value type of the \p buffer.
 270  * \param[in,out] buffer          Pointer to the device-side buffer
 271  * \param[in]     startingOffset  Offset (in values) at the device-side buffer to start clearing at.
 272  * \param[in]     numValues       Number of values to clear.
 273  * \param[in]     deviceStream    GPU stream.
 274  */
 275 template<typename ValueType>
 276 void clearDeviceBufferAsync(DeviceBuffer<ValueType>* buffer,
 277                             size_t                   startingOffset,
 278                             size_t                   numValues,
 279                             const DeviceStream&      deviceStream)
 280 {
 281     if (numValues == 0)
 282     {
 283         return;
 284     }
 285     GMX_ASSERT(buffer, "needs a buffer pointer");
 286     const size_t bytes   = numValues * sizeof(ValueType);
 287     const char   pattern = 0;
 288
 289     cudaError_t stat = cudaMemsetAsync(
 290             *((ValueType**)buffer) + startingOffset, pattern, bytes, deviceStream.stream());
 291     GMX_RELEASE_ASSERT(stat == cudaSuccess,
 292                        ("Couldn't clear the device buffer. " + gmx::getDeviceErrorString(stat)).c_str());
 293 }
 294
 295 /*! \brief Check the validity of the device buffer.
 296  *
 297  * Checks if the buffer is not nullptr.
 298  *
 299  * \todo Add checks on the buffer size when it will be possible.
 300  *
 301  * \param[in] buffer        Device buffer to be checked.
 302  * \param[in] requiredSize  Number of elements that the buffer will have to accommodate.
 303  *
 304  * \returns Whether the device buffer can be set.
 305  */
 306 template<typename T>
 307 gmx_unused static bool checkDeviceBuffer(DeviceBuffer<T> buffer, gmx_unused int requiredSize)
 308 {
 309     GMX_ASSERT(buffer != nullptr, "The device pointer is nullptr");
 310     return buffer != nullptr;
 311 }
 312
 313 //! Device texture wrapper.
 314 using DeviceTexture = cudaTextureObject_t;
 315
 316 /*! \brief Create a texture object for an array of type ValueType.
 317  *
 318  * Creates the device buffer, copies data and binds texture object for an array of type ValueType.
 319  *
 320  * \todo Test if using textures is still relevant on modern hardware.
 321  *
 322  * \tparam      ValueType      Raw data type.
 323  *
 324  * \param[out]  deviceBuffer   Device buffer to store data in.
 325  * \param[out]  deviceTexture  Device texture object to initialize.
 326  * \param[in]   hostBuffer     Host buffer to get date from
 327  * \param[in]   numValues      Number of elements in the buffer.
 328  * \param[in]   deviceContext  GPU device context.
 329  */
 330 template<typename ValueType>
 331 void initParamLookupTable(DeviceBuffer<ValueType>* deviceBuffer,
 332                           DeviceTexture*           deviceTexture,
 333                           const ValueType*         hostBuffer,
 334                           int                      numValues,
 335                           const DeviceContext&     deviceContext)
 336 {
 337     if (numValues == 0)
 338     {
 339         return;
 340     }
 341     GMX_ASSERT(hostBuffer, "Host buffer should be specified.");
 342
 343     allocateDeviceBuffer(deviceBuffer, numValues, deviceContext);
 344
 345     const size_t sizeInBytes = numValues * sizeof(ValueType);
 346
 347     cudaError_t stat =
 348             cudaMemcpy(*((ValueType**)deviceBuffer), hostBuffer, sizeInBytes, cudaMemcpyHostToDevice);
 349
 350     GMX_RELEASE_ASSERT(stat == cudaSuccess,
 351                        ("Synchronous H2D copy failed. " + gmx::getDeviceErrorString(stat)).c_str());
 352
 353     if (!c_disableCudaTextures)
 354     {
 355         cudaResourceDesc rd;
 356         cudaTextureDesc  td;
 357
 358         memset(&rd, 0, sizeof(rd));
 359         rd.resType                = cudaResourceTypeLinear;
 360         rd.res.linear.devPtr      = *deviceBuffer;
 361         rd.res.linear.desc        = cudaCreateChannelDesc<ValueType>();
 362         rd.res.linear.sizeInBytes = sizeInBytes;
 363
 364         memset(&td, 0, sizeof(td));
 365         td.readMode = cudaReadModeElementType;
 366         stat        = cudaCreateTextureObject(deviceTexture, &rd, &td, nullptr);
 367         GMX_RELEASE_ASSERT(
 368                 stat == cudaSuccess,
 369                 ("Binding of the texture object failed. " + gmx::getDeviceErrorString(stat)).c_str());
 370     }
 371 }
 372
 373 /*! \brief Unbind the texture and release the CUDA texture object.
 374  *
 375  * \tparam         ValueType      Raw data type
 376  *
 377  * \param[in,out]  deviceBuffer   Device buffer to store data in.
 378  * \param[in,out]  deviceTexture  Device texture object to unbind.
 379  */
 380 template<typename ValueType>
 381 void destroyParamLookupTable(DeviceBuffer<ValueType>* deviceBuffer, DeviceTexture& deviceTexture)
 382 {
 383     if (!c_disableCudaTextures && deviceTexture && deviceBuffer)
 384     {
 385         cudaError_t stat = cudaDestroyTextureObject(deviceTexture);
 386         GMX_RELEASE_ASSERT(
 387                 stat == cudaSuccess,
 388                 ("Destruction of the texture object failed. " + gmx::getDeviceErrorString(stat)).c_str());
 389     }
 390     freeDeviceBuffer(deviceBuffer);
 391 }
 392
 393 #endif