src/gromacs/gpu_utils/device_event.cuh

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2018,2019,2020,2021, by the GROMACS development team, led by
   5  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6  * and including many others, as listed in the AUTHORS file in the
   7  * top-level source directory and at http://www.gromacs.org.
   8  *
   9  * GROMACS is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public License
  11  * as published by the Free Software Foundation; either version 2.1
  12  * of the License, or (at your option) any later version.
  13  *
  14  * GROMACS is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with GROMACS; if not, see
  21  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23  *
  24  * If you want to redistribute modifications to GROMACS, please
  25  * consider that scientific software is very special. Version
  26  * control is crucial - bugs must be traceable. We will be happy to
  27  * consider code for inclusion in the official distribution, but
  28  * derived work must not be called official GROMACS. Details are found
  29  * in the README & COPYING files - if they are missing, get the
  30  * official version at http://www.gromacs.org.
  31  *
  32  * To help us fund GROMACS development, we humbly ask that you cite
  33  * the research papers on the package. Check out http://www.gromacs.org.
  34  */
  35 /*! \libinternal \file
  36  *  \brief Implements a DeviceEvent class for CUDA.
  37  *
  38  *  \author Aleksei Iupinov <a.yupinov@gmail.com>
  39  *  \author Andrey Alekseenko <al42and@gmail.com>
  40  *  \inlibraryapi
  41  */
  42 #ifndef GMX_GPU_UTILS_DEVICE_EVENT_CUH
  43 #define GMX_GPU_UTILS_DEVICE_EVENT_CUH
  44
  45 #include "gromacs/gpu_utils/cudautils.cuh"
  46 #include "gromacs/gpu_utils/device_stream.h"
  47 #include "gromacs/gpu_utils/gputraits.cuh"
  48 #include "gromacs/utility/gmxassert.h"
  49
  50 #ifndef DOXYGEN
  51
  52 class DeviceEvent
  53 {
  54 public:
  55     DeviceEvent() : isMarked_(false)
  56     {
  57         cudaError_t stat = cudaEventCreateWithFlags(&event_, cudaEventDisableTiming);
  58         if (stat != cudaSuccess)
  59         {
  60             GMX_THROW(gmx::InternalError("cudaEventCreate failed: " + gmx::getDeviceErrorString(stat)));
  61         }
  62     }
  63     ~DeviceEvent() { cudaEventDestroy(event_); }
  64     // Disable copy, move, and assignment. Move can be allowed, but not needed yet.
  65     DeviceEvent& operator=(const DeviceEvent&) = delete;
  66     DeviceEvent(const DeviceEvent&)            = delete;
  67     DeviceEvent& operator=(DeviceEvent&&) = delete;
  68     DeviceEvent(DeviceEvent&&)            = delete;
  69
  70     /*! \brief Marks the synchronization point in the \p stream.
  71      * Should be followed by waitForEvent().
  72      */
  73     inline void mark(const DeviceStream& deviceStream)
  74     {
  75         cudaError_t stat = cudaEventRecord(event_, deviceStream.stream());
  76         if (stat != cudaSuccess)
  77         {
  78             GMX_THROW(gmx::InternalError("cudaEventRecord failed: " + gmx::getDeviceErrorString(stat)));
  79         }
  80         isMarked_ = true;
  81     }
  82     //! Synchronizes the host thread on the marked event.
  83     inline void wait()
  84     {
  85         cudaError_t gmx_used_in_debug stat = cudaEventSynchronize(event_);
  86         if (stat != cudaSuccess)
  87         {
  88             GMX_THROW(gmx::InternalError("cudaEventSynchronize failed: " + gmx::getDeviceErrorString(stat)));
  89         }
  90     }
  91     //! Checks the completion of the underlying event.
  92     inline bool isReady()
  93     {
  94         cudaError_t stat = cudaEventQuery(event_);
  95         if (stat != cudaSuccess && stat != cudaErrorNotReady)
  96         {
  97             GMX_THROW(gmx::InternalError("cudaEventQuery failed: " + gmx::getDeviceErrorString(stat)));
  98         }
  99         return (stat == cudaSuccess);
 100     }
 101     //! Check if this event was marked
 102     inline bool isMarked() const { return isMarked_; }
 103     //! Enqueues a wait for the recorded event in stream \p stream
 104     inline void enqueueWait(const DeviceStream& deviceStream)
 105     {
 106         cudaError_t stat = cudaStreamWaitEvent(deviceStream.stream(), event_, 0);
 107         if (stat != cudaSuccess)
 108         {
 109             GMX_THROW(gmx::InternalError("cudaStreamWaitEvent failed: " + gmx::getDeviceErrorString(stat)));
 110         }
 111     }
 112     //! Reset the event
 113     inline void reset() { isMarked_ = false; }
 114
 115 private:
 116     cudaEvent_t event_;
 117     bool        isMarked_;
 118 };
 119
 120 #endif
 121
 122 #endif