src/gromacs/ewald/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   5 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 gmx_add_libgromacs_sources(
  37     calculate_spline_moduli.cpp
  38     ewald.cpp
  39     ewald_utils.cpp
  40     long_range_correction.cpp
  41     pme.cpp
  42     pme_gather.cpp
  43     pme_grid.cpp
  44     pme_load_balancing.cpp
  45     pme_only.cpp
  46     pme_pp.cpp
  47     pme_redistribute.cpp
  48     pme_solve.cpp
  49     pme_spline_work.cpp
  50     pme_spread.cpp
  51     # Files that implement stubs
  52     pme_gpu_program.cpp
  53     pme_pp_comm_gpu_impl.cpp
  54     pme_coordinate_receiver_gpu_impl.cpp
  55     pme_force_sender_gpu_impl.cpp
  56     )
  57 if (GMX_GPU_CUDA)
  58     gmx_add_libgromacs_sources(
  59         # CUDA-specific sources
  60         pme_gather.cu
  61         pme_gpu_3dfft.cu
  62         pme_solve.cu
  63         pme_spread.cu
  64         pme_gpu_program_impl.cu
  65         pme_pp_comm_gpu_impl.cu
  66         pme_force_sender_gpu_impl.cu
  67         pme_coordinate_receiver_gpu_impl.cu
  68         # GPU-specific sources
  69         pme_gpu.cpp
  70         pme_gpu_internal.cpp
  71         pme_gpu_timings.cpp
  72         )
  73 elseif (GMX_GPU_OPENCL)
  74     gmx_add_libgromacs_sources(
  75         # OpenCL-specific sources
  76         pme_gpu_3dfft_ocl.cpp
  77         pme_gpu_program_impl_ocl.cpp
  78         # GPU-specific sources
  79         pme_gpu.cpp
  80         pme_gpu_internal.cpp
  81         pme_gpu_timings.cpp
  82         )
  83 elseif (GMX_GPU_SYCL)
  84     # SYCL-TODO: proper implementation
  85     gmx_add_libgromacs_sources(
  86         pme_gpu_program_impl.cpp
  87         )
  88     _gmx_add_files_to_property(SYCL_SOURCES
  89         pme_gpu_program_impl.cpp
  90         pme_gpu_program.cpp
  91         )
  92 else()
  93     gmx_add_libgromacs_sources(
  94         # Files that implement stubs
  95         pme_gpu_program_impl.cpp
  96         )
  97 endif()
  98
  99 if (BUILD_TESTING)
 100     add_subdirectory(tests)
 101 endif()
 102
 103
 104 set(PME_OCL_KERNEL_SOURCES
 105     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gpu_calculate_splines.clh"
 106     "${CMAKE_CURRENT_SOURCE_DIR}/pme_solve.clh"
 107     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gather.clh"
 108     "${CMAKE_CURRENT_SOURCE_DIR}/pme_spread.clh")
 109
 110 if(CLANG_TIDY_EXE)
 111    set(OCL_COMPILER "${CLANG_TIDY_EXE}")
 112    set(CLANG_TIDY_ARGS "-quiet;-checks=*,-readability-implicit-bool-conversion,-llvm-header-guard,-hicpp-signed-bitwise,-clang-analyzer-deadcode.DeadStores,-google-readability-todo,-clang-diagnostic-padded,-fcomment-block-commands=internal;--;${CMAKE_C_COMPILER}")
 113 else()
 114    set(OCL_COMPILER "${CMAKE_C_COMPILER}")
 115 endif()
 116
 117 # TODO: test all warp sizes on all vendor targets?
 118 foreach(VENDOR AMD NVIDIA INTEL)
 119     foreach(WARPSIZE 16 32 64)
 120         math(EXPR SPREAD_WG_SIZE "8*${WARPSIZE}")
 121         math(EXPR SOLVE_WG_SIZE "8*${WARPSIZE}")
 122         math(EXPR GATHER_WG_SIZE "4*${WARPSIZE}")
 123         set(OBJ_FILE pme_ocl_kernel_warpSize${WARPSIZE}_${VENDOR}.o)
 124         add_custom_command(OUTPUT ${OBJ_FILE} COMMAND ${OCL_COMPILER}
 125         ${CMAKE_CURRENT_SOURCE_DIR}/pme_program.cl ${CLANG_TIDY_ARGS}
 126         -Xclang -finclude-default-header  -D_${VENDOR}_SOURCE_
 127         -Dwarp_size=${WARPSIZE}
 128         -Dorder=4
 129         -DthreadsPerAtom=16
 130         -Dc_pmeMaxUnitcellShift=2
 131         -Dc_skipNeutralAtoms=false
 132         -Dc_virialAndEnergyCount=7
 133         -Dc_spreadWorkGroupSize=${SPREAD_WG_SIZE}
 134         -Dc_solveMaxWorkGroupSize=${SOLVE_WG_SIZE}
 135         -Dc_gatherWorkGroupSize=${GATHER_WG_SIZE}
 136         -DDIM=3 -DXX=0 -DYY=1 -DZZ=2
 137         -DwrapX=true -DwrapY=true
 138         -c -I ${CMAKE_SOURCE_DIR}/src -std=cl1.2
 139         -Weverything  -Wno-conversion -Wno-missing-variable-declarations -Wno-used-but-marked-unused
 140         -Wno-cast-align -Wno-incompatible-pointer-types
 141         # to avoid  "warning: unknown command tag name" for \internal
 142         -Wno-documentation-unknown-command
 143         # to avoid pme_gpu_types.h:100:52: warning: padding struct 'struct PmeGpuConstParams' with 4 bytes to align 'd_virialAndEnergy'
 144         -Wno-padded
 145         -o${OBJ_FILE}
 146         )
 147         list(APPEND PME_OCL_KERNELS ${OBJ_FILE})
 148     endforeach()
 149 endforeach()
 150
 151 add_custom_target(ocl_pme_kernels DEPENDS ${PME_OCL_KERNELS} )
 152 gmx_set_custom_target_output(ocl_pme_kernels ${PME_OCL_KERNELS})