src/gromacs/ewald/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   5 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 # Set up the module library
  37 add_library(ewald INTERFACE)
  38 gmx_add_libgromacs_sources(
  39     calculate_spline_moduli.cpp
  40     ewald.cpp
  41     ewald_utils.cpp
  42     long_range_correction.cpp
  43     pme.cpp
  44     pme_gather.cpp
  45     pme_grid.cpp
  46     pme_load_balancing.cpp
  47     pme_only.cpp
  48     pme_pp.cpp
  49     pme_redistribute.cpp
  50     pme_solve.cpp
  51     pme_spline_work.cpp
  52     pme_spread.cpp
  53     # Files that implement stubs
  54     pme_gpu_program.cpp
  55     pme_pp_comm_gpu_impl.cpp
  56     pme_coordinate_receiver_gpu_impl.cpp
  57     pme_force_sender_gpu_impl.cpp
  58     )
  59 if (GMX_GPU_CUDA)
  60     gmx_add_libgromacs_sources(
  61         # CUDA-specific sources
  62         pme_gather.cu
  63         pme_gpu_3dfft.cu
  64         pme_solve.cu
  65         pme_spread.cu
  66         pme_gpu_program_impl.cu
  67         pme_pp_comm_gpu_impl.cu
  68         pme_force_sender_gpu_impl.cu
  69         pme_coordinate_receiver_gpu_impl.cu
  70         # GPU-specific sources
  71         pme_gpu.cpp
  72         pme_gpu_internal.cpp
  73         pme_gpu_timings.cpp
  74         )
  75     _gmx_add_files_to_property(CUDA_SOURCES
  76         # Must add these files so they can include device_information.h
  77         pme_gpu_internal.cpp
  78         pme_gpu_timings.cpp
  79         )
  80 elseif (GMX_GPU_OPENCL)
  81     gmx_add_libgromacs_sources(
  82         # OpenCL-specific sources
  83         pme_gpu_3dfft_ocl.cpp
  84         pme_gpu_program_impl_ocl.cpp
  85         # GPU-specific sources
  86         pme_gpu.cpp
  87         pme_gpu_internal.cpp
  88         pme_gpu_timings.cpp
  89         )
  90 elseif (GMX_GPU_SYCL)
  91     # SYCL-TODO: proper implementation
  92     gmx_add_libgromacs_sources(
  93         pme_gpu_program_impl.cpp
  94         )
  95     _gmx_add_files_to_property(SYCL_SOURCES
  96         pme_gpu_program_impl.cpp
  97         pme_gpu_program.cpp
  98         )
  99 else()
 100     gmx_add_libgromacs_sources(
 101         # Files that implement stubs
 102         pme_gpu_program_impl.cpp
 103         )
 104 endif()
 105
 106 # Source files have the following private module dependencies.
 107 target_link_libraries(ewald PRIVATE
 108                       #                      gmxlib
 109                       #                      math
 110                       #                      mdtypes
 111                       #                      tng_io
 112                       )
 113
 114 # Public interface for modules, including dependencies and interfaces
 115 #target_include_directories(ewald PUBLIC
 116 target_include_directories(ewald INTERFACE
 117                            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
 118 #target_link_libraries(ewald PUBLIC
 119 target_link_libraries(ewald INTERFACE
 120                       legacy_api
 121                       )
 122
 123 # TODO: when fileio is an OBJECT target
 124 #target_link_libraries(ewald PUBLIC legacy_api)
 125 #target_link_libraries(ewald PRIVATE common)
 126
 127 # Module dependencies
 128 # This module convey transitive dependence on these modules.
 129 #target_link_libraries(ewald PUBLIC
 130 target_link_libraries(ewald INTERFACE
 131                       #                      utility
 132                       )
 133 # Source files have the following private module dependencies.
 134 #target_link_libraries(ewald PRIVATE tng_io)
 135 # TODO: Explicitly link specific modules.
 136 #target_link_libraries(ewald PRIVATE legacy_modules)
 137
 138 if (BUILD_TESTING)
 139     add_subdirectory(tests)
 140 endif()
 141
 142
 143 set(PME_OCL_KERNEL_SOURCES
 144     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gpu_calculate_splines.clh"
 145     "${CMAKE_CURRENT_SOURCE_DIR}/pme_solve.clh"
 146     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gather.clh"
 147     "${CMAKE_CURRENT_SOURCE_DIR}/pme_spread.clh")
 148
 149 if(CLANG_TIDY_EXE)
 150    set(OCL_COMPILER "${CLANG_TIDY_EXE}")
 151    set(CLANG_TIDY_ARGS "-quiet;-checks=*,-readability-implicit-bool-conversion,-llvm-header-guard,-hicpp-signed-bitwise,-clang-analyzer-deadcode.DeadStores,-google-readability-todo,-clang-diagnostic-padded,-fcomment-block-commands=internal;--;${CMAKE_C_COMPILER}")
 152 else()
 153    set(OCL_COMPILER "${CMAKE_C_COMPILER}")
 154 endif()
 155
 156 # TODO: test all warp sizes on all vendor targets?
 157 foreach(VENDOR AMD NVIDIA INTEL)
 158     foreach(WARPSIZE 16 32 64)
 159         math(EXPR SPREAD_WG_SIZE "8*${WARPSIZE}")
 160         math(EXPR SOLVE_WG_SIZE "8*${WARPSIZE}")
 161         math(EXPR GATHER_WG_SIZE "4*${WARPSIZE}")
 162         set(OBJ_FILE pme_ocl_kernel_warpSize${WARPSIZE}_${VENDOR}.o)
 163         add_custom_command(OUTPUT ${OBJ_FILE} COMMAND ${OCL_COMPILER}
 164         ${CMAKE_CURRENT_SOURCE_DIR}/pme_program.cl ${CLANG_TIDY_ARGS}
 165         -Xclang -finclude-default-header  -D_${VENDOR}_SOURCE_
 166         -Dwarp_size=${WARPSIZE}
 167         -Dorder=4
 168         -DthreadsPerAtom=16
 169         -Dc_pmeMaxUnitcellShift=2
 170         -Dc_skipNeutralAtoms=false
 171         -Dc_virialAndEnergyCount=7
 172         -Dc_spreadWorkGroupSize=${SPREAD_WG_SIZE}
 173         -Dc_solveMaxWorkGroupSize=${SOLVE_WG_SIZE}
 174         -Dc_gatherWorkGroupSize=${GATHER_WG_SIZE}
 175         -DDIM=3 -DXX=0 -DYY=1 -DZZ=2
 176         -DwrapX=true -DwrapY=true
 177         -c -I ${CMAKE_SOURCE_DIR}/src -std=cl1.2
 178         -Weverything  -Wno-conversion -Wno-missing-variable-declarations -Wno-used-but-marked-unused
 179         -Wno-cast-align -Wno-incompatible-pointer-types
 180         # to avoid  "warning: unknown command tag name" for \internal
 181         -Wno-documentation-unknown-command
 182         # to avoid pme_gpu_types.h:100:52: warning: padding struct 'struct PmeGpuConstParams' with 4 bytes to align 'd_virialAndEnergy'
 183         -Wno-padded
 184         -o${OBJ_FILE}
 185         )
 186         list(APPEND PME_OCL_KERNELS ${OBJ_FILE})
 187     endforeach()
 188 endforeach()
 189
 190 add_custom_target(ocl_pme_kernels DEPENDS ${PME_OCL_KERNELS} )
 191 gmx_set_custom_target_output(ocl_pme_kernels ${PME_OCL_KERNELS})