src/gromacs/ewald/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   5 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 # Set up the module library
  37 add_library(ewald INTERFACE)
  38 gmx_add_libgromacs_sources(
  39     calculate_spline_moduli.cpp
  40     ewald.cpp
  41     ewald_utils.cpp
  42     long_range_correction.cpp
  43     pme.cpp
  44     pme_gather.cpp
  45     pme_grid.cpp
  46     pme_load_balancing.cpp
  47     pme_only.cpp
  48     pme_pp.cpp
  49     pme_redistribute.cpp
  50     pme_solve.cpp
  51     pme_spline_work.cpp
  52     pme_spread.cpp
  53     # Files that implement stubs
  54     pme_gpu_program.cpp
  55     pme_pp_comm_gpu_impl.cpp
  56     pme_coordinate_receiver_gpu_impl.cpp
  57     pme_force_sender_gpu_impl.cpp
  58     )
  59 if (GMX_GPU_CUDA)
  60     gmx_add_libgromacs_sources(
  61         # CUDA-specific sources
  62         pme_gather.cu
  63         pme_solve.cu
  64         pme_spread.cu
  65         pme_gpu_program_impl.cu
  66         pme_pp_comm_gpu_impl.cu
  67         pme_force_sender_gpu_impl.cu
  68         pme_coordinate_receiver_gpu_impl.cu
  69         # GPU-specific sources
  70         pme_gpu.cpp
  71         pme_gpu_internal.cpp
  72         pme_gpu_timings.cpp
  73         )
  74     _gmx_add_files_to_property(CUDA_SOURCES
  75         # Must add these files so they can include device_information.h
  76         pme_gpu_internal.cpp
  77         pme_gpu_timings.cpp
  78         )
  79 elseif (GMX_GPU_OPENCL)
  80     gmx_add_libgromacs_sources(
  81         # OpenCL-specific sources
  82         pme_gpu_program_impl_ocl.cpp
  83         # GPU-specific sources
  84         pme_gpu.cpp
  85         pme_gpu_internal.cpp
  86         pme_gpu_timings.cpp
  87         )
  88 elseif (GMX_GPU_SYCL)
  89     # SYCL-TODO: proper implementation
  90     gmx_add_libgromacs_sources(
  91         # GPU-specific sources
  92         pme_gpu.cpp
  93         pme_gpu_internal.cpp
  94         pme_gpu_program_impl_sycl.cpp
  95         pme_spread_sycl.cpp
  96         pme_gpu_timings.cpp
  97         )
  98     _gmx_add_files_to_property(SYCL_SOURCES
  99         pme_gpu_internal.cpp
 100         pme_gpu_program.cpp
 101         pme_gpu_program_impl_sycl.cpp
 102         pme_gpu_3dfft_sycl.cpp
 103         pme_gpu_timings.cpp
 104         pme_spread_sycl.cpp
 105       )
 106 else()
 107     gmx_add_libgromacs_sources(
 108         # Files that implement stubs
 109         pme_gpu_program_impl.cpp
 110         )
 111 endif()
 112
 113 # Source files have the following private module dependencies.
 114 target_link_libraries(ewald PRIVATE
 115                       #                      gmxlib
 116                       #                      math
 117                       #                      mdtypes
 118                       #                      tng_io
 119                       )
 120
 121 # Public interface for modules, including dependencies and interfaces
 122 #target_include_directories(ewald PUBLIC
 123 target_include_directories(ewald INTERFACE
 124                            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
 125 #target_link_libraries(ewald PUBLIC
 126 target_link_libraries(ewald INTERFACE
 127                       legacy_api
 128                       )
 129
 130 # TODO: when fileio is an OBJECT target
 131 #target_link_libraries(ewald PUBLIC legacy_api)
 132 #target_link_libraries(ewald PRIVATE common)
 133
 134 # Module dependencies
 135 # This module convey transitive dependence on these modules.
 136 #target_link_libraries(ewald PUBLIC
 137 target_link_libraries(ewald INTERFACE
 138                       #                      utility
 139                       )
 140 # Source files have the following private module dependencies.
 141 #target_link_libraries(ewald PRIVATE tng_io)
 142 # TODO: Explicitly link specific modules.
 143 #target_link_libraries(ewald PRIVATE legacy_modules)
 144
 145 if (BUILD_TESTING)
 146     add_subdirectory(tests)
 147 endif()
 148
 149
 150 set(PME_OCL_KERNEL_SOURCES
 151     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gpu_calculate_splines.clh"
 152     "${CMAKE_CURRENT_SOURCE_DIR}/pme_solve.clh"
 153     "${CMAKE_CURRENT_SOURCE_DIR}/pme_gather.clh"
 154     "${CMAKE_CURRENT_SOURCE_DIR}/pme_spread.clh")
 155
 156 if(CLANG_TIDY_EXE)
 157    set(OCL_COMPILER "${CLANG_TIDY_EXE}")
 158    set(CLANG_TIDY_ARGS "-quiet;-checks=*,-readability-implicit-bool-conversion,-llvm-header-guard,-hicpp-signed-bitwise,-clang-analyzer-deadcode.DeadStores,-google-readability-todo,-clang-diagnostic-padded,-fcomment-block-commands=internal;--;${CMAKE_C_COMPILER}")
 159 else()
 160    set(OCL_COMPILER "${CMAKE_C_COMPILER}")
 161 endif()
 162
 163 # TODO: test all warp sizes on all vendor targets?
 164 foreach(VENDOR AMD NVIDIA INTEL)
 165     foreach(WARPSIZE 16 32 64)
 166         math(EXPR SPREAD_WG_SIZE "8*${WARPSIZE}")
 167         math(EXPR SOLVE_WG_SIZE "8*${WARPSIZE}")
 168         math(EXPR GATHER_WG_SIZE "4*${WARPSIZE}")
 169         set(OBJ_FILE pme_ocl_kernel_warpSize${WARPSIZE}_${VENDOR}.o)
 170         add_custom_command(OUTPUT ${OBJ_FILE} COMMAND ${OCL_COMPILER}
 171         ${CMAKE_CURRENT_SOURCE_DIR}/pme_program.cl ${CLANG_TIDY_ARGS}
 172         -Xclang -finclude-default-header  -D_${VENDOR}_SOURCE_
 173         -Dwarp_size=${WARPSIZE}
 174         -Dorder=4
 175         -DthreadsPerAtom=16
 176         -Dc_pmeMaxUnitcellShift=2
 177         -Dc_skipNeutralAtoms=false
 178         -Dc_virialAndEnergyCount=7
 179         -Dc_spreadWorkGroupSize=${SPREAD_WG_SIZE}
 180         -Dc_solveMaxWorkGroupSize=${SOLVE_WG_SIZE}
 181         -Dc_gatherWorkGroupSize=${GATHER_WG_SIZE}
 182         -DDIM=3 -DXX=0 -DYY=1 -DZZ=2
 183         -DwrapX=true -DwrapY=true
 184         -c -I ${CMAKE_SOURCE_DIR}/src -std=cl1.2
 185         -Weverything  -Wno-conversion -Wno-missing-variable-declarations -Wno-used-but-marked-unused
 186         -Wno-cast-align -Wno-incompatible-pointer-types
 187         # to avoid  "warning: unknown command tag name" for \internal
 188         -Wno-documentation-unknown-command
 189         # to avoid pme_gpu_types.h:100:52: warning: padding struct 'struct PmeGpuConstParams' with 4 bytes to align 'd_virialAndEnergy'
 190         -Wno-padded
 191         -o${OBJ_FILE}
 192         )
 193         list(APPEND PME_OCL_KERNELS ${OBJ_FILE})
 194     endforeach()
 195 endforeach()
 196
 197 add_custom_target(ocl_pme_kernels DEPENDS ${PME_OCL_KERNELS} )
 198 gmx_set_custom_target_output(ocl_pme_kernels ${PME_OCL_KERNELS})