src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 if(GMX_USE_TNG)
  49     option(GMX_EXTERNAL_TNG "Use external TNG instead of compiling the version shipped with GROMACS."
  50            OFF)
  51     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  52     if(GMX_EXTERNAL_TNG)
  53         find_package(TNG_IO 1.6.0)
  54         if(NOT TNG_IO_FOUND)
  55             message(FATAL_ERROR
  56                 "TNG >= 1.6.0 not found. "
  57                 "You can set GMX_EXTERNAL_TNG=OFF to compile TNG.")
  58         endif()
  59         include_directories(${TNG_IO_INCLUDE_DIRS})
  60     endif()
  61     if(NOT GMX_EXTERNAL_TNG)
  62         # TNG wants zlib if it is available
  63         find_package(ZLIB QUIET)
  64         include(gmxTestZLib)
  65         gmx_test_zlib(HAVE_ZLIB)
  66
  67         include(${CMAKE_SOURCE_DIR}/src/external/tng_io/BuildTNG.cmake)
  68         tng_get_source_list(TNG_SOURCES TNG_IO_DEFINITIONS)
  69         list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
  70         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
  71
  72         if (HAVE_ZLIB)
  73             list(APPEND GMX_EXTRA_LIBRARIES ${ZLIB_LIBRARIES})
  74             include_directories(${ZLIB_INCLUDE_DIRS})
  75         endif()
  76     endif()
  77 else()
  78     # We still need to get tng/tng_io_fwd.h from somewhere!
  79     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/tng_io/include)
  80 endif()
  81
  82 add_subdirectory(gmxlib)
  83 add_subdirectory(mdlib)
  84 add_subdirectory(gmxpreprocess)
  85 add_subdirectory(commandline)
  86 add_subdirectory(fft)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(random)
  90 add_subdirectory(onlinehelp)
  91 add_subdirectory(options)
  92 add_subdirectory(pbcutil)
  93 add_subdirectory(timing)
  94 add_subdirectory(topology)
  95 add_subdirectory(utility)
  96 add_subdirectory(fileio)
  97 add_subdirectory(swap)
  98 add_subdirectory(essentialdynamics)
  99 add_subdirectory(pulling)
 100 add_subdirectory(simd)
 101 add_subdirectory(imd)
 102 if (NOT GMX_BUILD_MDRUN_ONLY)
 103     add_subdirectory(legacyheaders)
 104     add_subdirectory(gmxana)
 105     add_subdirectory(statistics)
 106     add_subdirectory(analysisdata)
 107     add_subdirectory(selection)
 108     add_subdirectory(trajectoryanalysis)
 109     add_subdirectory(tools)
 110 endif()
 111
 112 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
 113
 114 # This would be the standard way to include thread_mpi, but
 115 # we want libgromacs to link the functions directly
 116 #if(GMX_THREAD_MPI)
 117 #    add_subdirectory(thread_mpi)
 118 #endif()
 119 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 120
 121 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 122 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 123
 124 set(LIBGROMACS_HEADERS
 125     analysisdata.h
 126     commandline.h
 127     options.h
 128     selection.h
 129     trajectoryanalysis.h
 130     utility.h)
 131 configure_file(version.h.cmakein version.h)
 132 gmx_install_headers("" ${LIBGROMACS_HEADERS})
 133 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
 134
 135 # This code is here instead of utility/CMakeLists.txt, because CMake
 136 # custom commands and source file properties can only be set in the directory
 137 # that contains the target that uses them.
 138 # TODO: Generate a header instead that can be included from baseversion.c.
 139 # That probably simplifies things somewhat.
 140 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 141 gmx_configure_version_file(
 142     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 143     REMOTE_HASH SOURCE_FILE)
 144 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 145
 146 # apply gcc 4.4.x bug workaround
 147 if(GMX_USE_GCC44_BUG_WORKAROUND)
 148    include(gmxGCC44O3BugWorkaround)
 149    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 150    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 151    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 152 endif()
 153
 154 if (GMX_GPU)
 155     cuda_add_library(libgromacs ${LIBGROMACS_SOURCES}
 156             OPTIONS
 157             RELWITHDEBINFO -g
 158             DEBUG -g -D_DEBUG_=1)
 159 else()
 160     add_library(libgromacs ${LIBGROMACS_SOURCES})
 161 endif()
 162
 163 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 164 # is a generated source file. These are awkward to suppress inline, so
 165 # we do it in the compilation command (after testing that the compiler
 166 # supports the suppressions). Setting the properties only works after
 167 # the related target has been created, e.g. after when the file is
 168 # used with add_library().
 169 include(CheckCXXCompilerFlag)
 170 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 171 if (HAS_NO_UNUSED_PARAMETER)
 172     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 173 endif()
 174 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 175 if (HAS_NO_DEPRECATED_REGISTER)
 176     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 177 else()
 178     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 179     if (HAS_NO_DEPRECATED)
 180         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 181     endif()
 182 endif()
 183 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 184
 185 target_link_libraries(libgromacs
 186                       ${EXTRAE_LIBRARIES}
 187                       ${GMX_EXTRA_LIBRARIES}
 188                       ${TNG_IO_LIBRARIES}
 189                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 190                       ${XML_LIBRARIES}
 191                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 192 set_target_properties(libgromacs PROPERTIES
 193                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 194                       SOVERSION ${LIBRARY_SOVERSION}
 195                       VERSION ${LIBRARY_VERSION}
 196                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 197
 198 # Only install the library in mdrun-only mode if it is actually necessary
 199 # for the binary
 200 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 201     install(TARGETS libgromacs
 202             EXPORT libgromacs
 203             DESTINATION ${LIB_INSTALL_DIR}
 204             COMPONENT libraries)
 205 endif()
 206
 207 if (NOT GMX_BUILD_MDRUN_ONLY)
 208     include(InstallLibInfo.cmake)
 209 endif()
 210
 211 if (INSTALL_CUDART_LIB) #can be set manual by user
 212     if (GMX_GPU)
 213         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 214             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 215             if(IS_CUDART) #libcuda should not be installed
 216                 #install also name-links (linker uses those)
 217                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 218                 install(FILES ${CUDA_LIBS} DESTINATION
 219                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 220             endif()
 221         endforeach()
 222     else()
 223         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 224     endif()
 225 endif()