src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 set(libgromacs_object_library_dependencies "")
  47 function (_gmx_add_files_to_property PROPERTY)
  48     foreach (_file ${ARGN})
  49         if (IS_ABSOLUTE "${_file}")
  50             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  51         else()
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  53                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  54         endif()
  55     endforeach()
  56 endfunction ()
  57
  58 function (gmx_add_libgromacs_sources)
  59     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  60 endfunction ()
  61
  62 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  63 # approach, at least for the build system. See Redmine #2530
  64 function (gmx_compile_cpp_as_cuda)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 function (gmx_install_headers)
  69     if (NOT GMX_BUILD_MDRUN_ONLY)
  70         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  71         install(FILES       ${ARGN}
  72                 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${_dest}"
  73                 COMPONENT   development)
  74     endif()
  75     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  76 endfunction ()
  77
  78 function (gmx_write_installed_header_list)
  79     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  80     string(REPLACE ";" "\n" _list "${_list}")
  81     # TODO: Make this only update the file timestamp if the contents actually change.
  82     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  83 endfunction()
  84
  85 add_subdirectory(gmxlib)
  86 add_subdirectory(mdlib)
  87 add_subdirectory(applied_forces)
  88 add_subdirectory(listed_forces)
  89 add_subdirectory(nbnxm)
  90 add_subdirectory(commandline)
  91 add_subdirectory(domdec)
  92 add_subdirectory(ewald)
  93 add_subdirectory(fft)
  94 add_subdirectory(gpu_utils)
  95 add_subdirectory(hardware)
  96 add_subdirectory(linearalgebra)
  97 add_subdirectory(math)
  98 add_subdirectory(mdrun)
  99 add_subdirectory(mdrunutility)
 100 add_subdirectory(mdspan)
 101 add_subdirectory(mdtypes)
 102 add_subdirectory(onlinehelp)
 103 add_subdirectory(options)
 104 add_subdirectory(pbcutil)
 105 add_subdirectory(random)
 106 add_subdirectory(restraint)
 107 add_subdirectory(tables)
 108 add_subdirectory(taskassignment)
 109 add_subdirectory(timing)
 110 add_subdirectory(topology)
 111 add_subdirectory(trajectory)
 112 add_subdirectory(utility)
 113 add_subdirectory(swap)
 114 add_subdirectory(essentialdynamics)
 115 add_subdirectory(pulling)
 116 add_subdirectory(awh)
 117 add_subdirectory(simd)
 118 add_subdirectory(imd)
 119 add_subdirectory(compat)
 120 add_subdirectory(mimic)
 121 if (NOT GMX_BUILD_MDRUN_ONLY)
 122     add_subdirectory(gmxana)
 123     add_subdirectory(gmxpreprocess)
 124     add_subdirectory(correlationfunctions)
 125     add_subdirectory(statistics)
 126     add_subdirectory(analysisdata)
 127     add_subdirectory(coordinateio)
 128     add_subdirectory(trajectoryanalysis)
 129     add_subdirectory(energyanalysis)
 130     add_subdirectory(tools)
 131 endif()
 132
 133 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 134 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 135
 136 # This would be the standard way to include thread_mpi, but
 137 # we want libgromacs to link the functions directly
 138 #if(GMX_THREAD_MPI)
 139 #    add_subdirectory(thread_mpi)
 140 #endif()
 141 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 142 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 143 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 144 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 145 gmx_target_compile_options(thread_mpi)
 146 if (WIN32)
 147     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 148 endif()
 149 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 150
 151 configure_file(version.h.cmakein version.h)
 152 gmx_install_headers(
 153     analysisdata.h
 154     commandline.h
 155     options.h
 156     random.h
 157     selection.h
 158     trajectoryanalysis.h
 159     utility.h
 160     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 161     )
 162
 163 # This code is here instead of utility/CMakeLists.txt, because CMake
 164 # custom commands and source file properties can only be set in the directory
 165 # that contains the target that uses them.
 166 # TODO: Generate a header instead that can be included from baseversion.cpp.
 167 # That probably simplifies things somewhat.
 168 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 169 gmx_configure_version_file(
 170     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 171     REMOTE_HASH
 172     EXTRA_VARS
 173         GMX_SOURCE_DOI
 174         )
 175 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 176
 177 # Mark some shared GPU implementation files to compile with CUDA if needed
 178 if (GMX_USE_CUDA)
 179     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 180     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 181 endif()
 182
 183 # set up CUDA compilation with clang
 184 if (GMX_CLANG_CUDA)
 185     foreach (_file ${LIBGROMACS_SOURCES})
 186         get_filename_component(_ext ${_file} EXT)
 187         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 188         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 189             gmx_compile_cuda_file_with_clang(${_file})
 190         endif()
 191     endforeach()
 192 endif()
 193
 194 if (GMX_USE_CUDA)
 195     # Work around FindCUDA that prevents using target_link_libraries()
 196     # with keywords otherwise...
 197     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 198     if (NOT GMX_CLANG_CUDA)
 199         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 200     else()
 201         add_library(libgromacs ${LIBGROMACS_SOURCES})
 202     endif()
 203     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 204 else()
 205     add_library(libgromacs ${LIBGROMACS_SOURCES})
 206 endif()
 207
 208 add_subdirectory(fileio)
 209 if (NOT GMX_BUILD_MDRUN_ONLY)
 210     add_subdirectory(selection)
 211 endif()
 212
 213 # Suppress a warning about our abuse of t_inputrec
 214 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 215
 216 # Handle the object libraries that contain the source file
 217 # dependencies that need special handling because they are generated
 218 # or external code.
 219 foreach(object_library ${libgromacs_object_library_dependencies})
 220     if (BUILD_SHARED_LIBS)
 221         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 222     endif()
 223     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 224
 225     # Add the sources from the object libraries to the main library.
 226     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 227 endforeach()
 228 gmx_target_compile_options(libgromacs)
 229 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 230 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 231
 232 if (GMX_USE_OPENCL)
 233     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 234     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 235
 236     # Default to using clFFT found on the system
 237     # switch to quiet at the second run.
 238     if (DEFINED clFFT_LIBRARY)
 239         set (clFFT_FIND_QUIETLY TRUE)
 240     endif()
 241     find_package(clFFT)
 242     if (NOT clFFT_FOUND)
 243         if (GMX_EXTERNAL_CLFFT)
 244             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 245         endif()
 246
 247         if(MSVC)
 248             message(FATAL_ERROR
 249 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 250 requires clFFT, which was not found on your system. GROMACS does bundle
 251 clFFT to help with building for OpenCL, but that clFFT has not yet been
 252 ported to the more recent versions of that compiler that GROMACS itself
 253 requires. Thus for now, OpenCL is not available with MSVC and the internal
 254 build of clFFT in GROMACS 2019. Either change compiler, try installing
 255 a clFFT package, or use the latest GROMACS 2018 point release.")
 256         endif()
 257
 258         # Fall back on the internal version
 259         set (_clFFT_dir ../external/clFFT/src)
 260         add_subdirectory(${_clFFT_dir} clFFT-build)
 261         target_sources(libgromacs PRIVATE
 262             $<TARGET_OBJECTS:clFFT>
 263         )
 264         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 265         # Use the magic variable for how to link any library needed for
 266         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 267         # (e.g. Windows, BSD, Mac).
 268         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 269     else()
 270         target_link_libraries(libgromacs PRIVATE clFFT)
 271     endif()
 272 endif()
 273
 274 # Permit GROMACS code to include externally developed headers, such as
 275 # the functionality from the nonstd project that we use for
 276 # gmx::compat::optional. These are included as system headers so that
 277 # no warnings are issued from them.
 278 #
 279 # TODO Perhaps generalize this for all headers from src/external
 280 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 281
 282 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 283     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 284     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 285     # with the SIMD_AVX_512_CXX_FLAGS flags.
 286     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 287 endif()
 288
 289 gmx_setup_tng_for_libgromacs()
 290
 291 target_link_libraries(libgromacs
 292                       PRIVATE
 293                       ${EXTRAE_LIBRARIES}
 294                       ${GMX_EXTRA_LIBRARIES}
 295                       ${GMX_COMMON_LIBRARIES}
 296                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 297                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 298                       ${OpenCL_LIBRARIES}
 299                       PUBLIC
 300                       ${GMX_PUBLIC_LIBRARIES}
 301                       )
 302 if (GMX_OPENMP)
 303     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 304 endif()
 305 set_target_properties(libgromacs PROPERTIES
 306                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 307                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 308                       VERSION ${LIBRARY_VERSION}
 309                       )
 310
 311 gmx_manage_lmfit()
 312 target_link_libraries(libgromacs PRIVATE lmfit)
 313
 314 # Fix everything found by the latest version of clang that we use in
 315 # Jenkins testing. This should be updated when we update the latest
 316 # tested version of clang.
 317 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^7\.0")
 318    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 319 endif()
 320 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 321    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 322      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 323      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 324      /wd6001  #unitialized memory
 325      /wd6011  #derefencing NULL
 326      /wd6053  #prior call not zero-terminate
 327      /wd6054  #might not be zero-terminated
 328      /wd6385  #reading invalid data
 329      /wd6386  #buffer overrun
 330      /wd6387  #could be '0'
 331      /wd28199 #uninitialized memory
 332      # For compile time constant (e.g. templates) the following warnings have flase postives
 333      /wd6239  #(<non-zero> && <expr>)
 334      /wd6240  #(<expr> && <non-zero>)
 335      /wd6294  #Ill-defined for-loop
 336      /wd6326  #comparison of constant with other constant
 337      /wd28020 #expression involving paramter is not true
 338      # Misc
 339      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 340      /wd6993  #OpenMP ignored
 341      #TODO
 342      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 343      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 344      /wd6246  #hides declaration
 345      >
 346    )
 347 endif()
 348
 349 if (GMX_CLANG_TIDY)
 350    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 351        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 352 endif()
 353
 354 gmx_write_installed_header_list()
 355
 356 # Only install the library in mdrun-only mode if it is actually necessary
 357 # for the binary
 358 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 359     install(TARGETS libgromacs
 360             EXPORT libgromacs
 361             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 362             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 363             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 364             COMPONENT libraries)
 365 endif()
 366
 367 if (NOT GMX_BUILD_MDRUN_ONLY)
 368     include(InstallLibInfo.cmake)
 369 endif()
 370
 371 # Technically, the user could want to do this for an OpenCL build
 372 # using the CUDA runtime, but currently there's no reason to want to
 373 # do that.
 374 if (INSTALL_CUDART_LIB) #can be set manual by user
 375     if (GMX_USE_CUDA)
 376         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 377             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 378             if(IS_CUDART) #libcuda should not be installed
 379                 #install also name-links (linker uses those)
 380                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 381                 install(FILES ${CUDA_LIBS} DESTINATION
 382                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 383             endif()
 384         endforeach()
 385     else()
 386         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 387     endif()
 388 endif()
 389
 390 if(GMX_USE_OPENCL)
 391     # Install the utility headers
 392     file(GLOB OPENCL_INSTALLED_FILES
 393         gpu_utils/vectype_ops.clh
 394         gpu_utils/device_utils.clh
 395         )
 396     install(FILES ${OPENCL_INSTALLED_FILES}
 397         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 398         COMPONENT libraries)
 399     file(GLOB OPENCL_INSTALLED_FILES
 400         pbcutil/ishift.h
 401         )
 402     install(FILES ${OPENCL_INSTALLED_FILES}
 403         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 404         COMPONENT libraries)
 405
 406     # Install the NBNXM source and headers
 407     file(GLOB OPENCL_INSTALLED_FILES
 408         nbnxm/constants.h
 409         )
 410     install(FILES ${OPENCL_INSTALLED_FILES}
 411         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 412         COMPONENT libraries)
 413     file(GLOB OPENCL_INSTALLED_FILES
 414         nbnxm/opencl/nbnxm_ocl_kernels.cl
 415         nbnxm/opencl/nbnxm_ocl_kernel.clh
 416         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 417         nbnxm/opencl/nbnxm_ocl_kernels.clh
 418         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 419         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 420         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 421         nbnxm/opencl/nbnxm_ocl_consts.h
 422         )
 423     install(FILES ${OPENCL_INSTALLED_FILES}
 424         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 425         COMPONENT libraries)
 426
 427     # Install the PME source and headers
 428     file(GLOB OPENCL_INSTALLED_FILES
 429         ewald/pme_spread.clh
 430         ewald/pme_solve.clh
 431         ewald/pme_gather.clh
 432         ewald/pme_gpu_utils.clh
 433         ewald/pme_program.cl
 434         ewald/pme_gpu_types.h
 435         )
 436     install(FILES ${OPENCL_INSTALLED_FILES}
 437         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 438         COMPONENT libraries)
 439 endif()