src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 add_subdirectory(gmxlib)
  49 add_subdirectory(mdlib)
  50 add_subdirectory(gmxpreprocess)
  51 add_subdirectory(commandline)
  52 add_subdirectory(fft)
  53 add_subdirectory(linearalgebra)
  54 add_subdirectory(math)
  55 add_subdirectory(onlinehelp)
  56 add_subdirectory(options)
  57 add_subdirectory(timing)
  58 add_subdirectory(utility)
  59 add_subdirectory(fileio)
  60 add_subdirectory(essentialdynamics)
  61 add_subdirectory(pulling)
  62 if (NOT GMX_BUILD_MDRUN_ONLY)
  63     add_subdirectory(legacyheaders)
  64     add_subdirectory(gmxana)
  65     add_subdirectory(statistics)
  66     add_subdirectory(analysisdata)
  67     add_subdirectory(selection)
  68     add_subdirectory(trajectoryanalysis)
  69     add_subdirectory(tools)
  70 endif ()
  71
  72 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  73
  74 file(GLOB LIBGROMACS_HEADERS *.h)
  75 configure_file(version.h.cmakein version.h)
  76 gmx_install_headers("" ${LIBGROMACS_HEADERS})
  77 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  78
  79 # Add target that generates gitversion.c every time make is run
  80 # if git version info is requested
  81 # This code is here instead of utility/CMakeLists.txt because CMake
  82 # ignores set_source_file_properties from subdirectories.
  83 if (GMX_GIT_VERSION_INFO)
  84     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  85     add_custom_target(gmx-version ALL
  86             COMMAND ${CMAKE_COMMAND}
  87                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  88                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  89                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  90                 -D VERSION_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  91                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
  92                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  93             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  94             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  95             COMMENT "Generating git version information")
  96     set_source_files_properties(${GENERATED_VERSION_FILE}
  97                                 PROPERTIES GENERATED true)
  98     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
  99 endif()
 100
 101 # apply gcc 4.4.x bug workaround
 102 if(GMX_USE_GCC44_BUG_WORKAROUND)
 103    include(gmxGCC44O3BugWorkaround)
 104    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 105    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 106    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 107 endif()
 108
 109 add_library(libgromacs ${LIBGROMACS_SOURCES})
 110 if (GMX_GIT_VERSION_INFO)
 111     add_dependencies(libgromacs gmx-version)
 112 endif ()
 113
 114 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 115 # is a generated source file. These are awkward to suppress inline, so
 116 # we do it in the compilation command (after testing that the compiler
 117 # supports the suppressions). Setting the properties only works after
 118 # the related target has been created, e.g. after when the file is
 119 # used with add_library().
 120 include(CheckCXXCompilerFlag)
 121 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 122 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 123 if (HAS_NO_UNUSED_PARAMETER)
 124     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 125 endif()
 126 if (HAS_NO_DEPRECATED_REGISTER)
 127     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 128 endif()
 129 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 130
 131 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 132                       ${GMX_EXTRA_LIBRARIES}
 133                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 134                       ${XML_LIBRARIES} ${GSL_LIBRARIES}
 135                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 136 set_target_properties(libgromacs PROPERTIES
 137                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 138                       SOVERSION ${LIBRARY_SOVERSION}
 139                       VERSION ${LIBRARY_VERSION}
 140                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 141
 142 # Only install the library in mdrun-only mode if it is actually necessary
 143 # for the binary
 144 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 145     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 146 endif()
 147
 148 if (NOT GMX_BUILD_MDRUN_ONLY)
 149     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 150                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 151     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 152             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 153             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 154             COMPONENT development)
 155 endif()
 156
 157 if (INSTALL_CUDART_LIB) #can be set manual by user
 158     if (GMX_GPU)
 159         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 160             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 161             if(IS_CUDART) #libcuda should not be installed
 162                 #install also name-links (linker uses those)
 163                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 164                 install(FILES ${CUDA_LIBS} DESTINATION
 165                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 166             endif()
 167         endforeach()
 168     else()
 169         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 170     endif()
 171 endif ()