src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 add_subdirectory(gmxlib)
  49 add_subdirectory(mdlib)
  50 add_subdirectory(gmxpreprocess)
  51 add_subdirectory(commandline)
  52 add_subdirectory(fft)
  53 add_subdirectory(linearalgebra)
  54 add_subdirectory(math)
  55 add_subdirectory(onlinehelp)
  56 add_subdirectory(options)
  57 add_subdirectory(timing)
  58 add_subdirectory(utility)
  59 add_subdirectory(fileio)
  60 add_subdirectory(essentialdynamics)
  61 add_subdirectory(pulling)
  62 if (NOT GMX_BUILD_MDRUN_ONLY)
  63     add_subdirectory(legacyheaders)
  64     add_subdirectory(gmxana)
  65     add_subdirectory(analysisdata)
  66     add_subdirectory(selection)
  67     add_subdirectory(trajectoryanalysis)
  68 endif ()
  69
  70 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  71
  72 file(GLOB LIBGROMACS_HEADERS *.h)
  73 configure_file(version.h.cmakein version.h)
  74 gmx_install_headers("" ${LIBGROMACS_HEADERS})
  75 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  76
  77 # Add target that generates gitversion.c every time make is run
  78 # if git version info is requested
  79 # This code is here instead of utility/CMakeLists.txt because CMake
  80 # ignores set_source_file_properties from subdirectories.
  81 if (GMX_GIT_VERSION_INFO)
  82     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  83     add_custom_target(gmx-version ALL
  84             COMMAND ${CMAKE_COMMAND}
  85                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  86                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  87                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  88                 -D VERSION_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  89                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
  90                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  91             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  92             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  93             COMMENT "Generating git version information")
  94     set_source_files_properties(${GENERATED_VERSION_FILE}
  95                                 PROPERTIES GENERATED true)
  96     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
  97 endif()
  98
  99 # apply gcc 4.4.x bug workaround
 100 if(GMX_USE_GCC44_BUG_WORKAROUND)
 101    include(gmxGCC44O3BugWorkaround)
 102    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 103    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 104    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 105 endif()
 106
 107 add_library(libgromacs ${LIBGROMACS_SOURCES})
 108 if (GMX_GIT_VERSION_INFO)
 109     add_dependencies(libgromacs gmx-version)
 110 endif ()
 111
 112 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 113 # is a generated source file. These are awkward to suppress inline, so
 114 # we do it in the compilation command (after testing that the compiler
 115 # supports the suppressions). Setting the properties only works after
 116 # the related target has been created, e.g. after when the file is
 117 # used with add_library().
 118 include(CheckCXXCompilerFlag)
 119 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 120 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 121 if (HAS_NO_UNUSED_PARAMETER)
 122     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 123 endif()
 124 if (HAS_NO_DEPRECATED_REGISTER)
 125     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 126 endif()
 127 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 128
 129 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 130                       ${GMX_EXTRA_LIBRARIES}
 131                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 132                       ${XML_LIBRARIES} ${GSL_LIBRARIES}
 133                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 134 set_target_properties(libgromacs PROPERTIES
 135                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 136                       SOVERSION ${LIBRARY_SOVERSION}
 137                       VERSION ${LIBRARY_VERSION}
 138                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 139
 140 # Only install the library in mdrun-only mode if it is actually necessary
 141 # for the binary
 142 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 143     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 144 endif()
 145
 146 if (NOT GMX_BUILD_MDRUN_ONLY)
 147     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 148                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 149     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 150             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 151             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 152             COMPONENT development)
 153 endif()
 154
 155 if (INSTALL_CUDART_LIB) #can be set manual by user
 156     if (GMX_GPU)
 157         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 158             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 159             if(IS_CUDART) #libcuda should not be installed
 160                 #install also name-links (linker uses those)
 161                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 162                 install(FILES ${CUDA_LIBS} DESTINATION
 163                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 164             endif()
 165         endforeach()
 166     else()
 167         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 168     endif()
 169 endif ()