src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019 by the GROMACS development team.
   6 # Copyright (c) 2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 set(LIBGROMACS_SOURCES)
  38
  39 if (GMX_CLANG_CUDA)
  40     include(gmxClangCudaUtils)
  41 endif()
  42
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  44 set_property(GLOBAL PROPERTY CUDA_SOURCES)
  45 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  46 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  47
  48 set(libgromacs_object_library_dependencies "")
  49 function (_gmx_add_files_to_property PROPERTY)
  50     foreach (_file ${ARGN})
  51         if (IS_ABSOLUTE "${_file}")
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  53         else()
  54             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  55                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  56         endif()
  57     endforeach()
  58 endfunction ()
  59
  60 function (gmx_add_libgromacs_sources)
  61     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  62 endfunction ()
  63
  64 # Permit the configuration to disable compiling the many nbnxm kernels
  65 # and others involved in force calculations. Currently only
  66 # short-ranged and bonded kernels are disabled this way, but in future
  67 # others may be appropriate. Thus the cmake option is not specific to
  68 # nbnxm module.
  69 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  70 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  71
  72 # Add these contents first because linking their tests can take a lot
  73 # of time, so we want lots of parallel work still available after
  74 # linking starts.
  75 add_subdirectory(utility)
  76 # Add normal contents
  77 add_subdirectory(gmxlib)
  78 add_subdirectory(mdlib)
  79 add_subdirectory(applied_forces)
  80 add_subdirectory(listed_forces)
  81 add_subdirectory(nbnxm)
  82 add_subdirectory(commandline)
  83 add_subdirectory(domdec)
  84 add_subdirectory(ewald)
  85 add_subdirectory(fft)
  86 add_subdirectory(gpu_utils)
  87 add_subdirectory(hardware)
  88 add_subdirectory(linearalgebra)
  89 add_subdirectory(math)
  90 add_subdirectory(mdrun)
  91 add_subdirectory(mdrunutility)
  92 add_subdirectory(mdspan)
  93 add_subdirectory(mdtypes)
  94 add_subdirectory(onlinehelp)
  95 add_subdirectory(options)
  96 add_subdirectory(pbcutil)
  97 add_subdirectory(random)
  98 add_subdirectory(restraint)
  99 add_subdirectory(tables)
 100 add_subdirectory(taskassignment)
 101 add_subdirectory(timing)
 102 add_subdirectory(topology)
 103 add_subdirectory(trajectory)
 104 add_subdirectory(swap)
 105 add_subdirectory(essentialdynamics)
 106 add_subdirectory(pulling)
 107 add_subdirectory(simd)
 108 add_subdirectory(imd)
 109 add_subdirectory(compat)
 110 add_subdirectory(mimic)
 111 add_subdirectory(modularsimulator)
 112 add_subdirectory(gmxana)
 113 add_subdirectory(gmxpreprocess)
 114 add_subdirectory(correlationfunctions)
 115 add_subdirectory(statistics)
 116 add_subdirectory(analysisdata)
 117 add_subdirectory(coordinateio)
 118 add_subdirectory(trajectoryanalysis)
 119 add_subdirectory(energyanalysis)
 120 add_subdirectory(tools)
 121
 122 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 123 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 124
 125 # This would be the standard way to include thread_mpi, but
 126 # we want libgromacs to link the functions directly
 127 #if(GMX_THREAD_MPI)
 128 #    add_subdirectory(thread_mpi)
 129 #endif()
 130 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 131 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 132 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 133 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 134 if(CYGWIN)
 135     # Needs POSIX-isms for strdup, not just std-isms
 136     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 137 endif()
 138 gmx_target_compile_options(thread_mpi)
 139 if (WIN32)
 140     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 141 endif()
 142 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 143
 144 if(GMX_INSTALL_LEGACY_API)
 145   install(FILES
 146           analysisdata.h
 147           options.h
 148           selection.h
 149           trajectoryanalysis.h
 150           DESTINATION include/gromacs)
 151 endif()
 152
 153 # This code is here instead of utility/CMakeLists.txt, because CMake
 154 # custom commands and source file properties can only be set in the directory
 155 # that contains the target that uses them.
 156 # TODO: Generate a header instead that can be included from baseversion.cpp.
 157 # That probably simplifies things somewhat.
 158 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 159 gmx_configure_version_file(
 160     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 161     REMOTE_HASH
 162     EXTRA_VARS
 163         GMX_SOURCE_DOI
 164         GMX_RELEASE_HASH
 165         GMX_SOURCE_HASH
 166         )
 167 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 168
 169 # Mark some shared GPU implementation files to compile with CUDA if needed
 170 if (GMX_GPU_CUDA)
 171     get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 172     set_source_files_properties(${CUDA_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 173 endif()
 174
 175 if (GMX_GPU_CUDA)
 176     # Work around FindCUDA that prevents using target_link_libraries()
 177     # with keywords otherwise...
 178     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 179     if (NOT GMX_CLANG_CUDA)
 180         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 181     else()
 182         add_library(libgromacs ${LIBGROMACS_SOURCES})
 183     endif()
 184     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 185 else()
 186     add_library(libgromacs ${LIBGROMACS_SOURCES})
 187 endif()
 188 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:common>)
 189 # As long as the libgromacs target has source files that reference headers from
 190 # modules that don't provide CMake targets, libgromacs needs to use `src/`
 191 # amongst its include directories (to support `#include "gromacs/module/header.h"`).
 192 add_library(legacy_modules INTERFACE)
 193 target_include_directories(legacy_modules INTERFACE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>)
 194 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:legacy_modules>)
 195
 196 # Add these contents first because linking their tests can take a lot
 197 # of time, so we want lots of parallel work still available after
 198 # linking starts.
 199 add_subdirectory(fileio)
 200 add_subdirectory(selection)
 201
 202 # Suppress a warning about our abuse of t_inputrec
 203 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 204
 205 # Handle the object libraries that contain the source file
 206 # dependencies that need special handling because they are generated
 207 # or external code.
 208 foreach(object_library ${libgromacs_object_library_dependencies})
 209     if (BUILD_SHARED_LIBS)
 210         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 211     endif()
 212     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 213     target_link_libraries(${object_library} PRIVATE common)
 214
 215     # Add the sources from the object libraries to the main library.
 216     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 217 endforeach()
 218 gmx_target_compile_options(libgromacs)
 219 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 220 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 221
 222 if (GMX_GPU_OPENCL)
 223     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 224     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 225
 226     # Default to using clFFT found on the system
 227     # switch to quiet at the second run.
 228     if (DEFINED clFFT_LIBRARY)
 229         set (clFFT_FIND_QUIETLY TRUE)
 230     endif()
 231     find_package(clFFT)
 232     if (NOT clFFT_FOUND)
 233         if (GMX_EXTERNAL_CLFFT)
 234             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 235         endif()
 236
 237         if(MSVC)
 238             message(FATAL_ERROR
 239 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 240 requires clFFT, which was not found on your system. GROMACS does bundle
 241 clFFT to help with building for OpenCL, but that clFFT has not yet been
 242 ported to the more recent versions of that compiler that GROMACS itself
 243 requires. Thus for now, OpenCL is not available with MSVC and the internal
 244 build of clFFT in GROMACS 2019. Either change compiler, try installing
 245 a clFFT package, or use the latest GROMACS 2018 point release.")
 246         endif()
 247
 248         # Fall back on the internal version
 249         set (_clFFT_dir ../external/clFFT/src)
 250         add_subdirectory(${_clFFT_dir} clFFT-build)
 251         target_sources(libgromacs PRIVATE
 252             $<TARGET_OBJECTS:clFFT>
 253         )
 254         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 255         # Use the magic variable for how to link any library needed for
 256         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 257         # (e.g. Windows, BSD, Mac).
 258         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 259     else()
 260         target_link_libraries(libgromacs PRIVATE clFFT)
 261     endif()
 262 endif()
 263
 264 # Permit GROMACS code to include externally developed headers, such as
 265 # the functionality from the nonstd project that we use for
 266 # gmx::compat::optional. These are included as system headers so that
 267 # no warnings are issued from them.
 268 #
 269 # TODO Perhaps generalize this for all headers from src/external
 270 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 271
 272 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 273     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 274     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 275     # with the SIMD_AVX_512_CXX_FLAGS flags.
 276     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 277 endif()
 278
 279 # Do any special handling needed for .cpp files that use
 280 # CUDA runtime headers
 281 if (GMX_GPU_CUDA AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 282     # CUDA header cuda_runtime_api.h in at least CUDA 10.1 uses 0
 283     # where nullptr would be preferable. GROMACS can't fix these, so
 284     # must suppress them.
 285     GMX_TEST_CXXFLAG(CXXFLAGS_NO_ZERO_AS_NULL_POINTER_CONSTANT "-Wno-zero-as-null-pointer-constant" NVCC_CLANG_SUPPRESSIONS_CXXFLAGS)
 286
 287     foreach(_compile_flag ${NVCC_CLANG_SUPPRESSIONS_CXXFLAGS})
 288         set(GMX_CUDA_CLANG_FLAGS "${GMX_CUDA_CLANG_FLAGS} ${_compile_flag}")
 289     endforeach()
 290     if (GMX_CLANG_CUDA)
 291         foreach (_file ${LIBGROMACS_SOURCES})
 292             get_filename_component(_ext ${_file} EXT)
 293             get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 294             if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 295                 gmx_compile_cuda_file_with_clang(${_file})
 296             endif()
 297         endforeach()
 298     else()
 299         get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 300         set_source_files_properties(${CUDA_SOURCES} PROPERTIES COMPILE_FLAGS ${GMX_CUDA_CLANG_FLAGS})
 301     endif()
 302 endif()
 303
 304 # Only add the -fsycl flag to sources that really need it
 305 if (GMX_GPU_SYCL)
 306     get_property(SYCL_SOURCES GLOBAL PROPERTY SYCL_SOURCES)
 307     add_sycl_to_target(TARGET libgromacs SOURCES ${SYCL_SOURCES})
 308 endif()
 309
 310 gmx_setup_tng_for_libgromacs()
 311
 312 # We apply the SYCL flag explicitly just for libgromacs, since bugs in the beta versions of
 313 # icpx/dpcpp leads to crashes if we try to link an library without any SYCL code with the
 314 # -fsycl flag enabled. Once that bug is fixed, we should change it to simply add
 315 # SYCL_CXX_FLAGS to GMX_SHARED_LINKER_FLAGS.
 316 target_link_libraries(libgromacs
 317                       PRIVATE
 318                       ${EXTRAE_LIBRARIES}
 319                       ${GMX_EXTRA_LIBRARIES}
 320                       ${GMX_COMMON_LIBRARIES}
 321                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 322                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 323                       ${SYCL_CXX_FLAGS}
 324                       ${OpenCL_LIBRARIES}
 325                       $<$<PLATFORM_ID:SunOS>:socket>
 326                       PUBLIC
 327                       ${GMX_PUBLIC_LIBRARIES}
 328                       )
 329 target_link_libraries(libgromacs PUBLIC legacy_api)
 330 # Dependencies from libgromacs to the modules are set up here, but
 331 # once the add_subdirectory() commands are re-ordered then
 332 # responsibility for setting this up will move to the respective
 333 # modules.
 334 target_link_libraries(libgromacs PRIVATE
 335                       $<BUILD_INTERFACE:analysisdata>
 336                       $<BUILD_INTERFACE:applied_forces>
 337                       $<BUILD_INTERFACE:commandline>
 338                       $<BUILD_INTERFACE:compat>
 339                       $<BUILD_INTERFACE:coordinateio>
 340                       $<BUILD_INTERFACE:correlationfunctions>
 341                       $<BUILD_INTERFACE:domdec>
 342 #                      $<BUILD_INTERFACE:energyanalysis>
 343                       $<BUILD_INTERFACE:essentialdynamics>
 344                       $<BUILD_INTERFACE:ewald>
 345                       $<BUILD_INTERFACE:fft>
 346                       $<BUILD_INTERFACE:fileio>
 347                       $<BUILD_INTERFACE:gmxana>
 348                       $<BUILD_INTERFACE:gmxlib>
 349                       $<BUILD_INTERFACE:gmxpreprocess>
 350                       $<BUILD_INTERFACE:gpu_utils>
 351                       $<BUILD_INTERFACE:hardware>
 352                       $<BUILD_INTERFACE:imd>
 353                       $<BUILD_INTERFACE:linearalgebra>
 354                       $<BUILD_INTERFACE:listed_forces>
 355                       $<BUILD_INTERFACE:math>
 356                       $<BUILD_INTERFACE:mdlib>
 357                       $<BUILD_INTERFACE:mdrun>
 358                       $<BUILD_INTERFACE:mdrunutility>
 359                       $<BUILD_INTERFACE:mdspan>
 360                       $<BUILD_INTERFACE:mdtypes>
 361                       $<BUILD_INTERFACE:mimic>
 362                       $<BUILD_INTERFACE:modularsimulator>
 363                       $<BUILD_INTERFACE:nbnxm>
 364                       $<BUILD_INTERFACE:onlinehelp>
 365                       $<BUILD_INTERFACE:options>
 366                       $<BUILD_INTERFACE:pbcutil>
 367                       $<BUILD_INTERFACE:pulling>
 368                       $<BUILD_INTERFACE:random>
 369                       $<BUILD_INTERFACE:restraint>
 370                       $<BUILD_INTERFACE:selection>
 371                       $<BUILD_INTERFACE:simd>
 372                       $<BUILD_INTERFACE:statistics>
 373                       $<BUILD_INTERFACE:swap>
 374                       $<BUILD_INTERFACE:tables>
 375                       $<BUILD_INTERFACE:taskassignment>
 376                       $<BUILD_INTERFACE:timing>
 377                       $<BUILD_INTERFACE:tools>
 378                       $<BUILD_INTERFACE:topology>
 379                       $<BUILD_INTERFACE:trajectory>
 380                       $<BUILD_INTERFACE:trajectoryanalysis>
 381                       $<BUILD_INTERFACE:utility>
 382     )
 383 if (GMX_OPENMP)
 384     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 385 endif()
 386 set_target_properties(libgromacs PROPERTIES
 387                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 388                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 389                       VERSION ${LIBRARY_VERSION}
 390                       )
 391
 392 gmx_manage_lmfit()
 393 target_link_libraries(libgromacs PRIVATE lmfit)
 394
 395 # Make sure we fix "everything" found by more recent versions of clang.
 396 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 397    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 398 endif()
 399 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 400    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 401      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 402      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 403      /wd6001  #unitialized memory
 404      /wd6011  #derefencing NULL
 405      /wd6053  #prior call not zero-terminate
 406      /wd6054  #might not be zero-terminated
 407      /wd6385  #reading invalid data
 408      /wd6386  #buffer overrun
 409      /wd6387  #could be '0'
 410      /wd28199 #uninitialized memory
 411      # For compile time constant (e.g. templates) the following warnings have flase postives
 412      /wd6239  #(<non-zero> && <expr>)
 413      /wd6240  #(<expr> && <non-zero>)
 414      /wd6294  #Ill-defined for-loop
 415      /wd6326  #comparison of constant with other constant
 416      /wd28020 #expression involving paramter is not true
 417      # Misc
 418      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 419      /wd6993  #OpenMP ignored
 420      #TODO
 421      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 422      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 423      /wd6246  #hides declaration
 424      >
 425    )
 426 endif()
 427
 428 if (GMX_CLANG_TIDY)
 429    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 430        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 431 endif()
 432
 433 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 434 # and we know they are not real issues. So we only check that it can compile without error
 435 # but ignore all warnings.
 436 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 437     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 438 endif()
 439
 440 # TODO: Stop installing libgromacs. Possibly allow installation during deprecation period with GMX_INSTALL_LEGACY_API.
 441 if (BUILD_SHARED_LIBS)
 442     install(TARGETS libgromacs
 443             EXPORT libgromacs
 444             LIBRARY
 445                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 446                 COMPONENT libraries
 447             RUNTIME
 448                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 449                 COMPONENT libraries
 450             ARCHIVE
 451                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 452                 COMPONENT libraries
 453             INCLUDES DESTINATION include)
 454     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 455     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 456     if(GMX_INSTALL_LEGACY_API)
 457         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 458     endif()
 459 endif()
 460 add_library(Gromacs::libgromacs ALIAS libgromacs)
 461
 462 include(InstallLibInfo.cmake)
 463
 464 # Technically, the user could want to do this for an OpenCL build
 465 # using the CUDA runtime, but currently there's no reason to want to
 466 # do that.
 467 if (INSTALL_CUDART_LIB) #can be set manual by user
 468     if (GMX_GPU_CUDA)
 469         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 470             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 471             if(IS_CUDART) #libcuda should not be installed
 472                 #install also name-links (linker uses those)
 473                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 474                 install(FILES ${CUDA_LIBS} DESTINATION
 475                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 476             endif()
 477         endforeach()
 478     else()
 479         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 480     endif()
 481 endif()
 482
 483 if(GMX_GPU_OPENCL)
 484     # Install the utility headers
 485     file(GLOB OPENCL_INSTALLED_FILES
 486         gpu_utils/vectype_ops.clh
 487         gpu_utils/device_utils.clh
 488         )
 489     install(FILES ${OPENCL_INSTALLED_FILES}
 490         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 491         COMPONENT libraries)
 492     file(GLOB OPENCL_INSTALLED_FILES
 493         pbcutil/ishift.h
 494         )
 495     install(FILES ${OPENCL_INSTALLED_FILES}
 496         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 497         COMPONENT libraries)
 498
 499     # Install the NBNXM source and headers
 500     file(GLOB OPENCL_INSTALLED_FILES
 501         nbnxm/constants.h
 502         )
 503     install(FILES ${OPENCL_INSTALLED_FILES}
 504         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 505         COMPONENT libraries)
 506     file(GLOB OPENCL_INSTALLED_FILES
 507         nbnxm/opencl/nbnxm_ocl_kernels.cl
 508         nbnxm/opencl/nbnxm_ocl_kernel.clh
 509         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 510         nbnxm/opencl/nbnxm_ocl_kernels.clh
 511         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 512         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 513         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 514         nbnxm/opencl/nbnxm_ocl_consts.h
 515         )
 516     install(FILES ${OPENCL_INSTALLED_FILES}
 517         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 518         COMPONENT libraries)
 519
 520     # Install the PME source and headers
 521     file(GLOB OPENCL_INSTALLED_FILES
 522         ewald/pme_spread.clh
 523         ewald/pme_solve.clh
 524         ewald/pme_gather.clh
 525         ewald/pme_gpu_calculate_splines.clh
 526         ewald/pme_program.cl
 527         ewald/pme_gpu_types.h
 528         )
 529     install(FILES ${OPENCL_INSTALLED_FILES}
 530         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 531         COMPONENT libraries)
 532 endif()