src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 add_subdirectory(gmxlib)
  49 add_subdirectory(mdlib)
  50 add_subdirectory(gmxpreprocess)
  51 add_subdirectory(commandline)
  52 add_subdirectory(fft)
  53 add_subdirectory(linearalgebra)
  54 add_subdirectory(onlinehelp)
  55 add_subdirectory(options)
  56 add_subdirectory(timing)
  57 add_subdirectory(utility)
  58 add_subdirectory(fileio)
  59 if (NOT GMX_BUILD_MDRUN_ONLY)
  60     add_subdirectory(legacyheaders)
  61     add_subdirectory(gmxana)
  62     add_subdirectory(analysisdata)
  63     add_subdirectory(selection)
  64     add_subdirectory(trajectoryanalysis)
  65 endif ()
  66
  67 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  68
  69 file(GLOB LIBGROMACS_HEADERS *.h)
  70 configure_file(version.h.cmakein version.h)
  71 gmx_install_headers("" ${LIBGROMACS_HEADERS})
  72 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  73
  74 # Add target that generates gitversion.c every time make is run
  75 # if git version info is requested
  76 # This code is here instead of utility/CMakeLists.txt because CMake
  77 # ignores set_source_file_properties from subdirectories.
  78 if (GMX_GIT_VERSION_INFO)
  79     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  80     add_custom_target(gmx-version ALL
  81             COMMAND ${CMAKE_COMMAND}
  82                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  83                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  84                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  85                 -D VERSION_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  86                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
  87                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  88             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  89             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  90             COMMENT "Generating git version information")
  91     set_source_files_properties(${GENERATED_VERSION_FILE}
  92                                 PROPERTIES GENERATED true)
  93     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
  94 endif()
  95
  96 # apply gcc 4.4.x bug workaround
  97 if(GMX_USE_GCC44_BUG_WORKAROUND)
  98    include(gmxGCC44O3BugWorkaround)
  99    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 100    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 101    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 102 endif()
 103
 104 add_library(libgromacs ${LIBGROMACS_SOURCES})
 105 if (GMX_GIT_VERSION_INFO)
 106     add_dependencies(libgromacs gmx-version)
 107 endif ()
 108
 109 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 110 # is a generated source file. These are awkward to suppress inline, so
 111 # we do it in the compilation command (after testing that the compiler
 112 # supports the suppressions). Setting the properties only works after
 113 # the related target has been created, e.g. after when the file is
 114 # used with add_library().
 115 include(CheckCXXCompilerFlag)
 116 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 117 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 118 if (HAS_NO_UNUSED_PARAMETER)
 119     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 120 endif()
 121 if (HAS_NO_DEPRECATED_REGISTER)
 122     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 123 endif()
 124 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 125
 126 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 127                       ${GMX_EXTRA_LIBRARIES}
 128                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 129                       ${XML_LIBRARIES} ${GSL_LIBRARIES}
 130                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 131 set_target_properties(libgromacs PROPERTIES
 132                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 133                       SOVERSION ${SOVERSION}
 134                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 135
 136 # Only install the library in mdrun-only mode if it is actually necessary
 137 # for the binary
 138 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 139     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 140 endif()
 141
 142 if (NOT GMX_BUILD_MDRUN_ONLY)
 143     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 144                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 145     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 146             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 147             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 148             COMPONENT development)
 149 endif()
 150
 151 if (INSTALL_CUDART_LIB) #can be set manual by user
 152     if (GMX_GPU)
 153         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 154             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 155             if(IS_CUDART) #libcuda should not be installed
 156                 #install also name-links (linker uses those)
 157                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 158                 install(FILES ${CUDA_LIBS} DESTINATION
 159                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 160             endif()
 161         endforeach()
 162     else()
 163         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 164     endif()
 165 endif ()