src/gromacs/CMakeLists.txt

   1 set(LIBGROMACS_SOURCES)
   2
   3 add_subdirectory(legacyheaders)
   4 add_subdirectory(gmxlib)
   5 add_subdirectory(mdlib)
   6 add_subdirectory(gmxpreprocess)
   7 add_subdirectory(analysisdata)
   8 add_subdirectory(commandline)
   9 add_subdirectory(linearalgebra)
  10 add_subdirectory(onlinehelp)
  11 add_subdirectory(options)
  12 add_subdirectory(selection)
  13 add_subdirectory(trajectoryanalysis)
  14 add_subdirectory(utility)
  15
  16 file(GLOB LIBGROMACS_HEADERS *.h)
  17 install(FILES ${LIBGROMACS_HEADERS} DESTINATION ${INCL_INSTALL_DIR}/gromacs
  18         COMPONENT development)
  19
  20 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  21
  22 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/version.h.cmakein ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  23 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/version.h
  24     DESTINATION ${INCL_INSTALL_DIR}/gromacs
  25     COMPONENT development)
  26
  27 # Add target that generates gitversion.c every time make is run
  28 # if git version info is requested
  29 # This code is here instead of utility/CMakeLists.txt because CMake
  30 # ignores set_source_file_properties from subdirectories.
  31 if (GMX_GIT_VERSION_INFO)
  32     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  33     add_custom_target(gmx_version ALL
  34             COMMAND ${CMAKE_COMMAND}
  35                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  36                 -D GIT_VERSION="${GIT_VERSION}"
  37                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  38                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  39                 -D VERSION_C_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  40                 -D VERSION_C_OUT=${GENERATED_VERSION_FILE}
  41                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  42             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  43             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  44             COMMENT "Generating git version information")
  45     set_source_files_properties(${GENERATED_VERSION_FILE}
  46                                 PROPERTIES GENERATED true)
  47     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
  48 endif()
  49
  50 # apply gcc 4.4.x bug workaround
  51 if(GMX_USE_GCC44_BUG_WORKAROUND)
  52    include(gmxGCC44O3BugWorkaround)
  53    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
  54    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
  55    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
  56 endif()
  57
  58 if(GMX_GPU)
  59     include_directories(${CUDA_TOOLKIT_INCLUDE})
  60 endif()
  61
  62 add_library(libgromacs ${LIBGROMACS_SOURCES})
  63 if (GMX_GIT_VERSION_INFO)
  64     add_dependencies(libgromacs gmx_version)
  65 endif ()
  66
  67 if(GMX_BUILD_OWN_FFTW)
  68     # This dependency has to be made here rather than the CMakeLists.txt that
  69     # does the FFTW build, because of the order in which
  70     # add_subdirectory() calls are made in the top-level CMakeLists.txt; the
  71     # md library target does not necessarily exist yet. Also enabling and
  72     # disabling GMX_BUILD_OWN_FFTW changes dependencies correctly.
  73     add_dependencies(libgromacs gmxfftw)
  74 endif()
  75
  76 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
  77                       ${GMX_EXTRA_LIBRARIES} ${FFT_LIBRARIES} ${XML_LIBRARIES}
  78                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
  79 set_target_properties(libgromacs PROPERTIES
  80                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
  81                       SOVERSION ${SOVERSION}
  82                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  83
  84 install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
  85
  86 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
  87                ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
  88 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
  89         DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
  90         RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
  91         COMPONENT development)
  92
  93 if (INSTALL_CUDART_LIB) #can be set manual by user
  94     if (GMX_OPENMM OR GMX_GPU)
  95         foreach(CUDA_LIB ${CUDA_LIBRARIES})
  96             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
  97             if(IS_CUDART) #libcuda should not be installed
  98                 #install also name-links (linker uses those)
  99                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 100                 install(FILES ${CUDA_LIBS} DESTINATION
 101                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 102             endif()
 103         endforeach()
 104     else()
 105         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_OPENMM or GMX_GPU")
 106     endif()
 107 endif ()