src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY CUDA_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # Permit the configuration to disable compiling the many nbnxm kernels
  64 # and others involved in force calculations. Currently only
  65 # short-ranged and bonded kernels are disabled this way, but in future
  66 # others may be appropriate. Thus the cmake option is not specific to
  67 # nbnxm module.
  68 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  69 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  70
  71 # Add these contents first because linking their tests can take a lot
  72 # of time, so we want lots of parallel work still available after
  73 # linking starts.
  74 add_subdirectory(utility)
  75 # Add normal contents
  76 add_subdirectory(gmxlib)
  77 add_subdirectory(mdlib)
  78 add_subdirectory(applied_forces)
  79 add_subdirectory(listed_forces)
  80 add_subdirectory(nbnxm)
  81 add_subdirectory(commandline)
  82 add_subdirectory(domdec)
  83 add_subdirectory(ewald)
  84 add_subdirectory(fft)
  85 add_subdirectory(gpu_utils)
  86 add_subdirectory(hardware)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(mdrun)
  90 add_subdirectory(mdrunutility)
  91 add_subdirectory(mdspan)
  92 add_subdirectory(mdtypes)
  93 add_subdirectory(onlinehelp)
  94 add_subdirectory(options)
  95 add_subdirectory(pbcutil)
  96 add_subdirectory(random)
  97 add_subdirectory(restraint)
  98 add_subdirectory(tables)
  99 add_subdirectory(taskassignment)
 100 add_subdirectory(timing)
 101 add_subdirectory(topology)
 102 add_subdirectory(trajectory)
 103 add_subdirectory(swap)
 104 add_subdirectory(essentialdynamics)
 105 add_subdirectory(pulling)
 106 add_subdirectory(simd)
 107 add_subdirectory(imd)
 108 add_subdirectory(compat)
 109 add_subdirectory(mimic)
 110 add_subdirectory(modularsimulator)
 111 if (NOT GMX_BUILD_MDRUN_ONLY)
 112     add_subdirectory(gmxana)
 113     add_subdirectory(gmxpreprocess)
 114     add_subdirectory(correlationfunctions)
 115     add_subdirectory(statistics)
 116     add_subdirectory(analysisdata)
 117     add_subdirectory(coordinateio)
 118     add_subdirectory(trajectoryanalysis)
 119     add_subdirectory(energyanalysis)
 120     add_subdirectory(tools)
 121 endif()
 122
 123 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 124 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 125
 126 # This would be the standard way to include thread_mpi, but
 127 # we want libgromacs to link the functions directly
 128 #if(GMX_THREAD_MPI)
 129 #    add_subdirectory(thread_mpi)
 130 #endif()
 131 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 132 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 133 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 134 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 135 if(CYGWIN)
 136     # Needs POSIX-isms for strdup, not just std-isms
 137     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 138 endif()
 139 gmx_target_compile_options(thread_mpi)
 140 if (WIN32)
 141     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 142 endif()
 143 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 144
 145 if(GMX_INSTALL_LEGACY_API)
 146   install(FILES
 147           analysisdata.h
 148           options.h
 149           selection.h
 150           trajectoryanalysis.h
 151           DESTINATION include/gromacs)
 152 endif()
 153
 154 # This code is here instead of utility/CMakeLists.txt, because CMake
 155 # custom commands and source file properties can only be set in the directory
 156 # that contains the target that uses them.
 157 # TODO: Generate a header instead that can be included from baseversion.cpp.
 158 # That probably simplifies things somewhat.
 159 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 160 gmx_configure_version_file(
 161     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 162     REMOTE_HASH
 163     EXTRA_VARS
 164         GMX_SOURCE_DOI
 165         GMX_RELEASE_HASH
 166         GMX_SOURCE_HASH
 167         )
 168 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 169
 170 # Mark some shared GPU implementation files to compile with CUDA if needed
 171 if (GMX_GPU_CUDA)
 172     get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 173     set_source_files_properties(${CUDA_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 174 endif()
 175
 176 if (GMX_GPU_CUDA)
 177     # Work around FindCUDA that prevents using target_link_libraries()
 178     # with keywords otherwise...
 179     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 180     if (NOT GMX_CLANG_CUDA)
 181         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 182     else()
 183         add_library(libgromacs ${LIBGROMACS_SOURCES})
 184     endif()
 185     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 186 else()
 187     add_library(libgromacs ${LIBGROMACS_SOURCES})
 188 endif()
 189 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:common>)
 190 # As long as the libgromacs target has source files that reference headers from
 191 # modules that don't provide CMake targets, libgromacs needs to use `src/`
 192 # amongst its include directories (to support `#include "gromacs/module/header.h"`).
 193 add_library(legacy_modules INTERFACE)
 194 target_include_directories(legacy_modules INTERFACE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>)
 195 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:legacy_modules>)
 196
 197 # Add these contents first because linking their tests can take a lot
 198 # of time, so we want lots of parallel work still available after
 199 # linking starts.
 200 add_subdirectory(fileio)
 201 add_subdirectory(selection)
 202
 203 # Suppress a warning about our abuse of t_inputrec
 204 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 205
 206 # Handle the object libraries that contain the source file
 207 # dependencies that need special handling because they are generated
 208 # or external code.
 209 foreach(object_library ${libgromacs_object_library_dependencies})
 210     if (BUILD_SHARED_LIBS)
 211         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 212     endif()
 213     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 214     target_link_libraries(${object_library} PRIVATE common)
 215
 216     # Add the sources from the object libraries to the main library.
 217     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 218 endforeach()
 219 gmx_target_compile_options(libgromacs)
 220 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 221 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 222
 223 if (GMX_GPU_OPENCL)
 224     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 225     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 226
 227     # Default to using clFFT found on the system
 228     # switch to quiet at the second run.
 229     if (DEFINED clFFT_LIBRARY)
 230         set (clFFT_FIND_QUIETLY TRUE)
 231     endif()
 232     find_package(clFFT)
 233     if (NOT clFFT_FOUND)
 234         if (GMX_EXTERNAL_CLFFT)
 235             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 236         endif()
 237
 238         if(MSVC)
 239             message(FATAL_ERROR
 240 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 241 requires clFFT, which was not found on your system. GROMACS does bundle
 242 clFFT to help with building for OpenCL, but that clFFT has not yet been
 243 ported to the more recent versions of that compiler that GROMACS itself
 244 requires. Thus for now, OpenCL is not available with MSVC and the internal
 245 build of clFFT in GROMACS 2019. Either change compiler, try installing
 246 a clFFT package, or use the latest GROMACS 2018 point release.")
 247         endif()
 248
 249         # Fall back on the internal version
 250         set (_clFFT_dir ../external/clFFT/src)
 251         add_subdirectory(${_clFFT_dir} clFFT-build)
 252         target_sources(libgromacs PRIVATE
 253             $<TARGET_OBJECTS:clFFT>
 254         )
 255         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 256         # Use the magic variable for how to link any library needed for
 257         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 258         # (e.g. Windows, BSD, Mac).
 259         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 260     else()
 261         target_link_libraries(libgromacs PRIVATE clFFT)
 262     endif()
 263 endif()
 264
 265 # Permit GROMACS code to include externally developed headers, such as
 266 # the functionality from the nonstd project that we use for
 267 # gmx::compat::optional. These are included as system headers so that
 268 # no warnings are issued from them.
 269 #
 270 # TODO Perhaps generalize this for all headers from src/external
 271 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 272
 273 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 274     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 275     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 276     # with the SIMD_AVX_512_CXX_FLAGS flags.
 277     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 278 endif()
 279
 280 # Do any special handling needed for .cpp files that use
 281 # CUDA runtime headers
 282 if (GMX_GPU_CUDA AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 283     # CUDA header cuda_runtime_api.h in at least CUDA 10.1 uses 0
 284     # where nullptr would be preferable. GROMACS can't fix these, so
 285     # must suppress them.
 286     GMX_TEST_CXXFLAG(CXXFLAGS_NO_ZERO_AS_NULL_POINTER_CONSTANT "-Wno-zero-as-null-pointer-constant" NVCC_CLANG_SUPPRESSIONS_CXXFLAGS)
 287
 288     foreach(_compile_flag ${NVCC_CLANG_SUPPRESSIONS_CXXFLAGS})
 289         set(GMX_CUDA_CLANG_FLAGS "${GMX_CUDA_CLANG_FLAGS} ${_compile_flag}")
 290     endforeach()
 291     if (GMX_CLANG_CUDA)
 292         foreach (_file ${LIBGROMACS_SOURCES})
 293             get_filename_component(_ext ${_file} EXT)
 294             get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 295             if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 296                 gmx_compile_cuda_file_with_clang(${_file})
 297             endif()
 298         endforeach()
 299     else()
 300         get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 301         set_source_files_properties(${CUDA_SOURCES} PROPERTIES COMPILE_FLAGS ${GMX_CUDA_CLANG_FLAGS})
 302     endif()
 303 endif()
 304
 305 # Only add the -fsycl flag to sources that really need it
 306 if (GMX_GPU_SYCL)
 307     get_property(SYCL_SOURCES GLOBAL PROPERTY SYCL_SOURCES)
 308     set_source_files_properties(${SYCL_SOURCES} PROPERTIES COMPILE_FLAGS "${SYCL_CXX_FLAGS}")
 309 endif()
 310
 311 gmx_setup_tng_for_libgromacs()
 312
 313 # We apply the SYCL flag explicitly just for libgromacs, since bugs in the beta versions of
 314 # icpx/dpcpp leads to crashes if we try to link an library without any SYCL code with the
 315 # -fsycl flag enabled. Once that bug is fixed, we should change it to simply add
 316 # SYCL_CXX_FLAGS to GMX_SHARED_LINKER_FLAGS.
 317 target_link_libraries(libgromacs
 318                       PRIVATE
 319                       ${EXTRAE_LIBRARIES}
 320                       ${GMX_EXTRA_LIBRARIES}
 321                       ${GMX_COMMON_LIBRARIES}
 322                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 323                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 324                       ${SYCL_CXX_FLAGS}
 325                       ${OpenCL_LIBRARIES}
 326                       $<$<PLATFORM_ID:SunOS>:socket>
 327                       PUBLIC
 328                       ${GMX_PUBLIC_LIBRARIES}
 329                       )
 330 target_link_libraries(libgromacs PUBLIC legacy_api)
 331 # Dependencies from libgromacs to the modules are set up here, but
 332 # once the add_subdirectory() commands are re-ordered then
 333 # responsibility for setting this up will move to the respective
 334 # modules.
 335 target_link_libraries(libgromacs PRIVATE
 336                       $<BUILD_INTERFACE:analysisdata>
 337                       $<BUILD_INTERFACE:applied_forces>
 338                       $<BUILD_INTERFACE:commandline>
 339                       $<BUILD_INTERFACE:compat>
 340                       $<BUILD_INTERFACE:coordinateio>
 341                       $<BUILD_INTERFACE:correlationfunctions>
 342                       $<BUILD_INTERFACE:domdec>
 343 #                      $<BUILD_INTERFACE:energyanalysis>
 344                       $<BUILD_INTERFACE:essentialdynamics>
 345                       $<BUILD_INTERFACE:ewald>
 346                       $<BUILD_INTERFACE:fft>
 347                       $<BUILD_INTERFACE:fileio>
 348                       $<BUILD_INTERFACE:gmxana>
 349                       $<BUILD_INTERFACE:gmxlib>
 350                       $<BUILD_INTERFACE:gmxpreprocess>
 351                       $<BUILD_INTERFACE:gpu_utils>
 352                       $<BUILD_INTERFACE:hardware>
 353                       $<BUILD_INTERFACE:imd>
 354                       $<BUILD_INTERFACE:linearalgebra>
 355                       $<BUILD_INTERFACE:listed_forces>
 356                       $<BUILD_INTERFACE:math>
 357                       $<BUILD_INTERFACE:mdlib>
 358                       $<BUILD_INTERFACE:mdrun>
 359                       $<BUILD_INTERFACE:mdrunutility>
 360                       $<BUILD_INTERFACE:mdspan>
 361                       $<BUILD_INTERFACE:mdtypes>
 362                       $<BUILD_INTERFACE:mimic>
 363                       $<BUILD_INTERFACE:modularsimulator>
 364                       $<BUILD_INTERFACE:nbnxm>
 365                       $<BUILD_INTERFACE:onlinehelp>
 366                       $<BUILD_INTERFACE:options>
 367                       $<BUILD_INTERFACE:pbcutil>
 368                       $<BUILD_INTERFACE:pulling>
 369                       $<BUILD_INTERFACE:random>
 370                       $<BUILD_INTERFACE:restraint>
 371                       $<BUILD_INTERFACE:selection>
 372                       $<BUILD_INTERFACE:simd>
 373                       $<BUILD_INTERFACE:statistics>
 374                       $<BUILD_INTERFACE:swap>
 375                       $<BUILD_INTERFACE:tables>
 376                       $<BUILD_INTERFACE:taskassignment>
 377                       $<BUILD_INTERFACE:timing>
 378                       $<BUILD_INTERFACE:tools>
 379                       $<BUILD_INTERFACE:topology>
 380                       $<BUILD_INTERFACE:trajectory>
 381                       $<BUILD_INTERFACE:trajectoryanalysis>
 382                       $<BUILD_INTERFACE:utility>
 383                       )
 384 if (GMX_OPENMP)
 385     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 386 endif()
 387 set_target_properties(libgromacs PROPERTIES
 388                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 389                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 390                       VERSION ${LIBRARY_VERSION}
 391                       )
 392
 393 gmx_manage_lmfit()
 394 target_link_libraries(libgromacs PRIVATE lmfit)
 395
 396 # Make sure we fix "everything" found by more recent versions of clang.
 397 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 398    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 399 endif()
 400 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 401    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 402      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 403      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 404      /wd6001  #unitialized memory
 405      /wd6011  #derefencing NULL
 406      /wd6053  #prior call not zero-terminate
 407      /wd6054  #might not be zero-terminated
 408      /wd6385  #reading invalid data
 409      /wd6386  #buffer overrun
 410      /wd6387  #could be '0'
 411      /wd28199 #uninitialized memory
 412      # For compile time constant (e.g. templates) the following warnings have flase postives
 413      /wd6239  #(<non-zero> && <expr>)
 414      /wd6240  #(<expr> && <non-zero>)
 415      /wd6294  #Ill-defined for-loop
 416      /wd6326  #comparison of constant with other constant
 417      /wd28020 #expression involving paramter is not true
 418      # Misc
 419      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 420      /wd6993  #OpenMP ignored
 421      #TODO
 422      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 423      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 424      /wd6246  #hides declaration
 425      >
 426    )
 427 endif()
 428
 429 if (GMX_CLANG_TIDY)
 430    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 431        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 432 endif()
 433
 434 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 435 # and we know they are not real issues. So we only check that it can compile without error
 436 # but ignore all warnings.
 437 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 438     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 439 endif()
 440
 441 # Only install the library in mdrun-only mode if it is actually necessary
 442 # for the binary
 443 # TODO: Stop installing libgromacs. Possibly allow installation during deprecation period with GMX_INSTALL_LEGACY_API.
 444 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 445     install(TARGETS libgromacs
 446             EXPORT libgromacs
 447             LIBRARY
 448                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 449                 COMPONENT libraries
 450             RUNTIME
 451                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 452                 COMPONENT libraries
 453             ARCHIVE
 454                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 455                 COMPONENT libraries
 456             INCLUDES DESTINATION include)
 457     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 458     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 459     if(GMX_INSTALL_LEGACY_API)
 460         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 461     endif()
 462 endif()
 463 add_library(Gromacs::libgromacs ALIAS libgromacs)
 464
 465 if (NOT GMX_BUILD_MDRUN_ONLY)
 466     include(InstallLibInfo.cmake)
 467 endif()
 468
 469 # Technically, the user could want to do this for an OpenCL build
 470 # using the CUDA runtime, but currently there's no reason to want to
 471 # do that.
 472 if (INSTALL_CUDART_LIB) #can be set manual by user
 473     if (GMX_GPU_CUDA)
 474         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 475             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 476             if(IS_CUDART) #libcuda should not be installed
 477                 #install also name-links (linker uses those)
 478                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 479                 install(FILES ${CUDA_LIBS} DESTINATION
 480                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 481             endif()
 482         endforeach()
 483     else()
 484         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 485     endif()
 486 endif()
 487
 488 if(GMX_GPU_OPENCL)
 489     # Install the utility headers
 490     file(GLOB OPENCL_INSTALLED_FILES
 491         gpu_utils/vectype_ops.clh
 492         gpu_utils/device_utils.clh
 493         )
 494     install(FILES ${OPENCL_INSTALLED_FILES}
 495         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 496         COMPONENT libraries)
 497     file(GLOB OPENCL_INSTALLED_FILES
 498         pbcutil/ishift.h
 499         )
 500     install(FILES ${OPENCL_INSTALLED_FILES}
 501         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 502         COMPONENT libraries)
 503
 504     # Install the NBNXM source and headers
 505     file(GLOB OPENCL_INSTALLED_FILES
 506         nbnxm/constants.h
 507         )
 508     install(FILES ${OPENCL_INSTALLED_FILES}
 509         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 510         COMPONENT libraries)
 511     file(GLOB OPENCL_INSTALLED_FILES
 512         nbnxm/opencl/nbnxm_ocl_kernels.cl
 513         nbnxm/opencl/nbnxm_ocl_kernel.clh
 514         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 515         nbnxm/opencl/nbnxm_ocl_kernels.clh
 516         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 517         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 518         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 519         nbnxm/opencl/nbnxm_ocl_consts.h
 520         )
 521     install(FILES ${OPENCL_INSTALLED_FILES}
 522         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 523         COMPONENT libraries)
 524
 525     # Install the PME source and headers
 526     file(GLOB OPENCL_INSTALLED_FILES
 527         ewald/pme_spread.clh
 528         ewald/pme_solve.clh
 529         ewald/pme_gather.clh
 530         ewald/pme_gpu_calculate_splines.clh
 531         ewald/pme_program.cl
 532         ewald/pme_gpu_types.h
 533         )
 534     install(FILES ${OPENCL_INSTALLED_FILES}
 535         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 536         COMPONENT libraries)
 537 endif()