src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 set(libgromacs_object_library_dependencies "")
  47 function (_gmx_add_files_to_property PROPERTY)
  48     foreach (_file ${ARGN})
  49         if (IS_ABSOLUTE "${_file}")
  50             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  51         else()
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  53                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  54         endif()
  55     endforeach()
  56 endfunction ()
  57
  58 function (gmx_add_libgromacs_sources)
  59     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  60 endfunction ()
  61
  62 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  63 # approach, at least for the build system. See Redmine #2530
  64 function (gmx_compile_cpp_as_cuda)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 # Add these contents first because linking their tests can take a lot
  69 # of time, so we want lots of parallel work still available after
  70 # linking starts.
  71 add_subdirectory(utility)
  72 # Add normal contents
  73 add_subdirectory(gmxlib)
  74 add_subdirectory(mdlib)
  75 add_subdirectory(applied_forces)
  76 add_subdirectory(listed_forces)
  77 add_subdirectory(nbnxm)
  78 add_subdirectory(commandline)
  79 add_subdirectory(domdec)
  80 add_subdirectory(ewald)
  81 add_subdirectory(fft)
  82 add_subdirectory(gpu_utils)
  83 add_subdirectory(hardware)
  84 add_subdirectory(linearalgebra)
  85 add_subdirectory(math)
  86 add_subdirectory(mdrun)
  87 add_subdirectory(mdrunutility)
  88 add_subdirectory(mdspan)
  89 add_subdirectory(mdtypes)
  90 add_subdirectory(onlinehelp)
  91 add_subdirectory(options)
  92 add_subdirectory(pbcutil)
  93 add_subdirectory(random)
  94 add_subdirectory(restraint)
  95 add_subdirectory(tables)
  96 add_subdirectory(taskassignment)
  97 add_subdirectory(timing)
  98 add_subdirectory(topology)
  99 add_subdirectory(trajectory)
 100 add_subdirectory(swap)
 101 add_subdirectory(essentialdynamics)
 102 add_subdirectory(pulling)
 103 add_subdirectory(awh)
 104 add_subdirectory(simd)
 105 add_subdirectory(imd)
 106 add_subdirectory(compat)
 107 add_subdirectory(mimic)
 108 add_subdirectory(modularsimulator)
 109 if (NOT GMX_BUILD_MDRUN_ONLY)
 110     add_subdirectory(gmxana)
 111     add_subdirectory(gmxpreprocess)
 112     add_subdirectory(correlationfunctions)
 113     add_subdirectory(statistics)
 114     add_subdirectory(analysisdata)
 115     add_subdirectory(coordinateio)
 116     add_subdirectory(trajectoryanalysis)
 117     add_subdirectory(energyanalysis)
 118     add_subdirectory(tools)
 119 endif()
 120
 121 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 122 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 123
 124 # This would be the standard way to include thread_mpi, but
 125 # we want libgromacs to link the functions directly
 126 #if(GMX_THREAD_MPI)
 127 #    add_subdirectory(thread_mpi)
 128 #endif()
 129 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 130 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 131 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 132 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 133 gmx_target_compile_options(thread_mpi)
 134 if (WIN32)
 135     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 136 endif()
 137 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 138
 139 configure_file(version.h.cmakein version.h)
 140 if(GMX_INSTALL_LEGACY_API)
 141   install(FILES
 142           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 143           DESTINATION include/gromacs)
 144 endif()
 145
 146 # This code is here instead of utility/CMakeLists.txt, because CMake
 147 # custom commands and source file properties can only be set in the directory
 148 # that contains the target that uses them.
 149 # TODO: Generate a header instead that can be included from baseversion.cpp.
 150 # That probably simplifies things somewhat.
 151 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 152 gmx_configure_version_file(
 153     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 154     REMOTE_HASH
 155     EXTRA_VARS
 156         GMX_SOURCE_DOI
 157         )
 158 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 159
 160 # Mark some shared GPU implementation files to compile with CUDA if needed
 161 if (GMX_USE_CUDA)
 162     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 163     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 164 endif()
 165
 166 # set up CUDA compilation with clang
 167 if (GMX_CLANG_CUDA)
 168     foreach (_file ${LIBGROMACS_SOURCES})
 169         get_filename_component(_ext ${_file} EXT)
 170         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 171         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 172             gmx_compile_cuda_file_with_clang(${_file})
 173         endif()
 174     endforeach()
 175 endif()
 176
 177 if (GMX_USE_CUDA)
 178     # Work around FindCUDA that prevents using target_link_libraries()
 179     # with keywords otherwise...
 180     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 181     if (NOT GMX_CLANG_CUDA)
 182         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 183     else()
 184         add_library(libgromacs ${LIBGROMACS_SOURCES})
 185     endif()
 186     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 187 else()
 188     add_library(libgromacs ${LIBGROMACS_SOURCES})
 189 endif()
 190
 191 # Add these contents first because linking their tests can take a lot
 192 # of time, so we want lots of parallel work still available after
 193 # linking starts.
 194 add_subdirectory(fileio)
 195 add_subdirectory(selection)
 196
 197 # Suppress a warning about our abuse of t_inputrec
 198 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 199
 200 # Handle the object libraries that contain the source file
 201 # dependencies that need special handling because they are generated
 202 # or external code.
 203 foreach(object_library ${libgromacs_object_library_dependencies})
 204     if (BUILD_SHARED_LIBS)
 205         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 206     endif()
 207     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 208
 209     # Add the sources from the object libraries to the main library.
 210     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 211 endforeach()
 212 gmx_target_compile_options(libgromacs)
 213 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 214 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 215
 216 if (GMX_USE_OPENCL)
 217     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 218     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 219
 220     # Default to using clFFT found on the system
 221     # switch to quiet at the second run.
 222     if (DEFINED clFFT_LIBRARY)
 223         set (clFFT_FIND_QUIETLY TRUE)
 224     endif()
 225     find_package(clFFT)
 226     if (NOT clFFT_FOUND)
 227         if (GMX_EXTERNAL_CLFFT)
 228             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 229         endif()
 230
 231         if(MSVC)
 232             message(FATAL_ERROR
 233 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 234 requires clFFT, which was not found on your system. GROMACS does bundle
 235 clFFT to help with building for OpenCL, but that clFFT has not yet been
 236 ported to the more recent versions of that compiler that GROMACS itself
 237 requires. Thus for now, OpenCL is not available with MSVC and the internal
 238 build of clFFT in GROMACS 2019. Either change compiler, try installing
 239 a clFFT package, or use the latest GROMACS 2018 point release.")
 240         endif()
 241
 242         # Fall back on the internal version
 243         set (_clFFT_dir ../external/clFFT/src)
 244         add_subdirectory(${_clFFT_dir} clFFT-build)
 245         target_sources(libgromacs PRIVATE
 246             $<TARGET_OBJECTS:clFFT>
 247         )
 248         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 249         # Use the magic variable for how to link any library needed for
 250         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 251         # (e.g. Windows, BSD, Mac).
 252         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 253     else()
 254         target_link_libraries(libgromacs PRIVATE clFFT)
 255     endif()
 256 endif()
 257
 258 # Permit GROMACS code to include externally developed headers, such as
 259 # the functionality from the nonstd project that we use for
 260 # gmx::compat::optional. These are included as system headers so that
 261 # no warnings are issued from them.
 262 #
 263 # TODO Perhaps generalize this for all headers from src/external
 264 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 265
 266 # Temporary fix to allow external access to restraintpotentail
 267 target_include_directories(libgromacs PUBLIC
 268                            $<INSTALL_INTERFACE:include>
 269                            )
 270
 271 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 272     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 273     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 274     # with the SIMD_AVX_512_CXX_FLAGS flags.
 275     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 276 endif()
 277
 278 gmx_setup_tng_for_libgromacs()
 279
 280 target_link_libraries(libgromacs
 281                       PRIVATE
 282                       ${EXTRAE_LIBRARIES}
 283                       ${GMX_EXTRA_LIBRARIES}
 284                       ${GMX_COMMON_LIBRARIES}
 285                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 286                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 287                       ${OpenCL_LIBRARIES}
 288                       PUBLIC
 289                       ${GMX_PUBLIC_LIBRARIES}
 290                       )
 291 if (GMX_OPENMP)
 292     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 293 endif()
 294 set_target_properties(libgromacs PROPERTIES
 295                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 296                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 297                       VERSION ${LIBRARY_VERSION}
 298                       )
 299
 300 gmx_manage_lmfit()
 301 target_link_libraries(libgromacs PRIVATE lmfit)
 302
 303 # Fix everything found by the latest version of clang that we use in
 304 # Jenkins testing. This should be updated when we update the latest
 305 # tested version of clang.
 306 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^7\.0")
 307    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 308 endif()
 309 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 310    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 311      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 312      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 313      /wd6001  #unitialized memory
 314      /wd6011  #derefencing NULL
 315      /wd6053  #prior call not zero-terminate
 316      /wd6054  #might not be zero-terminated
 317      /wd6385  #reading invalid data
 318      /wd6386  #buffer overrun
 319      /wd6387  #could be '0'
 320      /wd28199 #uninitialized memory
 321      # For compile time constant (e.g. templates) the following warnings have flase postives
 322      /wd6239  #(<non-zero> && <expr>)
 323      /wd6240  #(<expr> && <non-zero>)
 324      /wd6294  #Ill-defined for-loop
 325      /wd6326  #comparison of constant with other constant
 326      /wd28020 #expression involving paramter is not true
 327      # Misc
 328      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 329      /wd6993  #OpenMP ignored
 330      #TODO
 331      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 332      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 333      /wd6246  #hides declaration
 334      >
 335    )
 336 endif()
 337
 338 if (GMX_CLANG_TIDY)
 339    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 340        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 341 endif()
 342
 343 # Only install the library in mdrun-only mode if it is actually necessary
 344 # for the binary
 345 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 346     install(TARGETS libgromacs
 347             EXPORT libgromacs
 348             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 349             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 350             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 351             INCLUDES DESTINATION include
 352             COMPONENT libraries)
 353 endif()
 354
 355 if (NOT GMX_BUILD_MDRUN_ONLY)
 356     include(InstallLibInfo.cmake)
 357 endif()
 358
 359 # Technically, the user could want to do this for an OpenCL build
 360 # using the CUDA runtime, but currently there's no reason to want to
 361 # do that.
 362 if (INSTALL_CUDART_LIB) #can be set manual by user
 363     if (GMX_USE_CUDA)
 364         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 365             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 366             if(IS_CUDART) #libcuda should not be installed
 367                 #install also name-links (linker uses those)
 368                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 369                 install(FILES ${CUDA_LIBS} DESTINATION
 370                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 371             endif()
 372         endforeach()
 373     else()
 374         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 375     endif()
 376 endif()
 377
 378 if(GMX_USE_OPENCL)
 379     # Install the utility headers
 380     file(GLOB OPENCL_INSTALLED_FILES
 381         gpu_utils/vectype_ops.clh
 382         gpu_utils/device_utils.clh
 383         )
 384     install(FILES ${OPENCL_INSTALLED_FILES}
 385         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 386         COMPONENT libraries)
 387     file(GLOB OPENCL_INSTALLED_FILES
 388         pbcutil/ishift.h
 389         )
 390     install(FILES ${OPENCL_INSTALLED_FILES}
 391         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 392         COMPONENT libraries)
 393
 394     # Install the NBNXM source and headers
 395     file(GLOB OPENCL_INSTALLED_FILES
 396         nbnxm/constants.h
 397         )
 398     install(FILES ${OPENCL_INSTALLED_FILES}
 399         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 400         COMPONENT libraries)
 401     file(GLOB OPENCL_INSTALLED_FILES
 402         nbnxm/opencl/nbnxm_ocl_kernels.cl
 403         nbnxm/opencl/nbnxm_ocl_kernel.clh
 404         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 405         nbnxm/opencl/nbnxm_ocl_kernels.clh
 406         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 407         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 408         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 409         nbnxm/opencl/nbnxm_ocl_consts.h
 410         )
 411     install(FILES ${OPENCL_INSTALLED_FILES}
 412         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 413         COMPONENT libraries)
 414
 415     # Install the PME source and headers
 416     file(GLOB OPENCL_INSTALLED_FILES
 417         ewald/pme_spread.clh
 418         ewald/pme_solve.clh
 419         ewald/pme_gather.clh
 420         ewald/pme_gpu_utils.clh
 421         ewald/pme_program.cl
 422         ewald/pme_gpu_types.h
 423         )
 424     install(FILES ${OPENCL_INSTALLED_FILES}
 425         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 426         COMPONENT libraries)
 427 endif()