src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 set(libgromacs_object_library_dependencies "")
  47 function (_gmx_add_files_to_property PROPERTY)
  48     foreach (_file ${ARGN})
  49         if (IS_ABSOLUTE "${_file}")
  50             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  51         else()
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  53                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  54         endif()
  55     endforeach()
  56 endfunction ()
  57
  58 function (gmx_add_libgromacs_sources)
  59     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  60 endfunction ()
  61
  62 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  63 # approach, at least for the build system. See Redmine #2530
  64 function (gmx_compile_cpp_as_cuda)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 # Add these contents first because linking their tests can take a lot
  69 # of time, so we want lots of parallel work still available after
  70 # linking starts.
  71 add_subdirectory(utility)
  72 # Add normal contents
  73 add_subdirectory(gmxlib)
  74 add_subdirectory(mdlib)
  75 add_subdirectory(applied_forces)
  76 add_subdirectory(listed_forces)
  77 add_subdirectory(nbnxm)
  78 add_subdirectory(commandline)
  79 add_subdirectory(domdec)
  80 add_subdirectory(ewald)
  81 add_subdirectory(fft)
  82 add_subdirectory(gpu_utils)
  83 add_subdirectory(hardware)
  84 add_subdirectory(linearalgebra)
  85 add_subdirectory(math)
  86 add_subdirectory(mdrun)
  87 add_subdirectory(mdrunutility)
  88 add_subdirectory(mdspan)
  89 add_subdirectory(mdtypes)
  90 add_subdirectory(onlinehelp)
  91 add_subdirectory(options)
  92 add_subdirectory(pbcutil)
  93 add_subdirectory(random)
  94 add_subdirectory(restraint)
  95 add_subdirectory(tables)
  96 add_subdirectory(taskassignment)
  97 add_subdirectory(timing)
  98 add_subdirectory(topology)
  99 add_subdirectory(trajectory)
 100 add_subdirectory(swap)
 101 add_subdirectory(essentialdynamics)
 102 add_subdirectory(pulling)
 103 add_subdirectory(awh)
 104 add_subdirectory(simd)
 105 add_subdirectory(imd)
 106 add_subdirectory(compat)
 107 add_subdirectory(mimic)
 108 add_subdirectory(modularsimulator)
 109 if (NOT GMX_BUILD_MDRUN_ONLY)
 110     add_subdirectory(gmxana)
 111     add_subdirectory(gmxpreprocess)
 112     add_subdirectory(correlationfunctions)
 113     add_subdirectory(statistics)
 114     add_subdirectory(analysisdata)
 115     add_subdirectory(coordinateio)
 116     add_subdirectory(trajectoryanalysis)
 117     add_subdirectory(energyanalysis)
 118     add_subdirectory(tools)
 119 endif()
 120
 121 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 122 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 123
 124 # This would be the standard way to include thread_mpi, but
 125 # we want libgromacs to link the functions directly
 126 #if(GMX_THREAD_MPI)
 127 #    add_subdirectory(thread_mpi)
 128 #endif()
 129 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 130 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 131 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 132 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 133 gmx_target_compile_options(thread_mpi)
 134 if (WIN32)
 135     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 136 endif()
 137 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 138
 139 configure_file(version.h.cmakein version.h)
 140
 141 # This code is here instead of utility/CMakeLists.txt, because CMake
 142 # custom commands and source file properties can only be set in the directory
 143 # that contains the target that uses them.
 144 # TODO: Generate a header instead that can be included from baseversion.cpp.
 145 # That probably simplifies things somewhat.
 146 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 147 gmx_configure_version_file(
 148     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 149     REMOTE_HASH
 150     EXTRA_VARS
 151         GMX_SOURCE_DOI
 152         )
 153 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 154
 155 # Mark some shared GPU implementation files to compile with CUDA if needed
 156 if (GMX_USE_CUDA)
 157     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 158     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 159 endif()
 160
 161 # set up CUDA compilation with clang
 162 if (GMX_CLANG_CUDA)
 163     foreach (_file ${LIBGROMACS_SOURCES})
 164         get_filename_component(_ext ${_file} EXT)
 165         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 166         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 167             gmx_compile_cuda_file_with_clang(${_file})
 168         endif()
 169     endforeach()
 170 endif()
 171
 172 if (GMX_USE_CUDA)
 173     # Work around FindCUDA that prevents using target_link_libraries()
 174     # with keywords otherwise...
 175     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 176     if (NOT GMX_CLANG_CUDA)
 177         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 178     else()
 179         add_library(libgromacs ${LIBGROMACS_SOURCES})
 180     endif()
 181     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 182 else()
 183     add_library(libgromacs ${LIBGROMACS_SOURCES})
 184 endif()
 185
 186 # Add these contents first because linking their tests can take a lot
 187 # of time, so we want lots of parallel work still available after
 188 # linking starts.
 189 if (NOT GMX_BUILD_MDRUN_ONLY)
 190     add_subdirectory(selection)
 191 endif()
 192 # Add normal contents
 193 add_subdirectory(fileio)
 194
 195 # Suppress a warning about our abuse of t_inputrec
 196 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 197
 198 # Handle the object libraries that contain the source file
 199 # dependencies that need special handling because they are generated
 200 # or external code.
 201 foreach(object_library ${libgromacs_object_library_dependencies})
 202     if (BUILD_SHARED_LIBS)
 203         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 204     endif()
 205     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 206
 207     # Add the sources from the object libraries to the main library.
 208     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 209 endforeach()
 210 gmx_target_compile_options(libgromacs)
 211 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 212 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 213
 214 if (GMX_USE_OPENCL)
 215     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 216     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 217
 218     # Default to using clFFT found on the system
 219     # switch to quiet at the second run.
 220     if (DEFINED clFFT_LIBRARY)
 221         set (clFFT_FIND_QUIETLY TRUE)
 222     endif()
 223     find_package(clFFT)
 224     if (NOT clFFT_FOUND)
 225         if (GMX_EXTERNAL_CLFFT)
 226             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 227         endif()
 228
 229         if(MSVC)
 230             message(FATAL_ERROR
 231 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 232 requires clFFT, which was not found on your system. GROMACS does bundle
 233 clFFT to help with building for OpenCL, but that clFFT has not yet been
 234 ported to the more recent versions of that compiler that GROMACS itself
 235 requires. Thus for now, OpenCL is not available with MSVC and the internal
 236 build of clFFT in GROMACS 2019. Either change compiler, try installing
 237 a clFFT package, or use the latest GROMACS 2018 point release.")
 238         endif()
 239
 240         # Fall back on the internal version
 241         set (_clFFT_dir ../external/clFFT/src)
 242         add_subdirectory(${_clFFT_dir} clFFT-build)
 243         target_sources(libgromacs PRIVATE
 244             $<TARGET_OBJECTS:clFFT>
 245         )
 246         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 247         # Use the magic variable for how to link any library needed for
 248         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 249         # (e.g. Windows, BSD, Mac).
 250         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 251     else()
 252         target_link_libraries(libgromacs PRIVATE clFFT)
 253     endif()
 254 endif()
 255
 256 # Permit GROMACS code to include externally developed headers, such as
 257 # the functionality from the nonstd project that we use for
 258 # gmx::compat::optional. These are included as system headers so that
 259 # no warnings are issued from them.
 260 #
 261 # TODO Perhaps generalize this for all headers from src/external
 262 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 263
 264 # Temporary fix to allow external access to restraintpotentail
 265 target_include_directories(libgromacs PUBLIC
 266                            $<INSTALL_INTERFACE:include>
 267                            )
 268
 269 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 270     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 271     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 272     # with the SIMD_AVX_512_CXX_FLAGS flags.
 273     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 274 endif()
 275
 276 gmx_setup_tng_for_libgromacs()
 277
 278 target_link_libraries(libgromacs
 279                       PRIVATE
 280                       ${EXTRAE_LIBRARIES}
 281                       ${GMX_EXTRA_LIBRARIES}
 282                       ${GMX_COMMON_LIBRARIES}
 283                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 284                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 285                       ${OpenCL_LIBRARIES}
 286                       PUBLIC
 287                       ${GMX_PUBLIC_LIBRARIES}
 288                       )
 289 if (GMX_OPENMP)
 290     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 291 endif()
 292 set_target_properties(libgromacs PROPERTIES
 293                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 294                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 295                       VERSION ${LIBRARY_VERSION}
 296                       )
 297
 298 gmx_manage_lmfit()
 299 target_link_libraries(libgromacs PRIVATE lmfit)
 300
 301 # Fix everything found by the latest version of clang that we use in
 302 # Jenkins testing. This should be updated when we update the latest
 303 # tested version of clang.
 304 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^7\.0")
 305    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 306 endif()
 307 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 308    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 309      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 310      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 311      /wd6001  #unitialized memory
 312      /wd6011  #derefencing NULL
 313      /wd6053  #prior call not zero-terminate
 314      /wd6054  #might not be zero-terminated
 315      /wd6385  #reading invalid data
 316      /wd6386  #buffer overrun
 317      /wd6387  #could be '0'
 318      /wd28199 #uninitialized memory
 319      # For compile time constant (e.g. templates) the following warnings have flase postives
 320      /wd6239  #(<non-zero> && <expr>)
 321      /wd6240  #(<expr> && <non-zero>)
 322      /wd6294  #Ill-defined for-loop
 323      /wd6326  #comparison of constant with other constant
 324      /wd28020 #expression involving paramter is not true
 325      # Misc
 326      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 327      /wd6993  #OpenMP ignored
 328      #TODO
 329      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 330      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 331      /wd6246  #hides declaration
 332      >
 333    )
 334 endif()
 335
 336 if (GMX_CLANG_TIDY)
 337    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 338        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 339 endif()
 340
 341 # Only install the library in mdrun-only mode if it is actually necessary
 342 # for the binary
 343 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 344     install(TARGETS libgromacs
 345             EXPORT libgromacs
 346             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 347             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 348             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 349             INCLUDES DESTINATION include
 350             COMPONENT libraries)
 351 endif()
 352
 353 if (NOT GMX_BUILD_MDRUN_ONLY)
 354     include(InstallLibInfo.cmake)
 355 endif()
 356
 357 # Technically, the user could want to do this for an OpenCL build
 358 # using the CUDA runtime, but currently there's no reason to want to
 359 # do that.
 360 if (INSTALL_CUDART_LIB) #can be set manual by user
 361     if (GMX_USE_CUDA)
 362         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 363             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 364             if(IS_CUDART) #libcuda should not be installed
 365                 #install also name-links (linker uses those)
 366                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 367                 install(FILES ${CUDA_LIBS} DESTINATION
 368                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 369             endif()
 370         endforeach()
 371     else()
 372         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 373     endif()
 374 endif()
 375
 376 if(GMX_USE_OPENCL)
 377     # Install the utility headers
 378     file(GLOB OPENCL_INSTALLED_FILES
 379         gpu_utils/vectype_ops.clh
 380         gpu_utils/device_utils.clh
 381         )
 382     install(FILES ${OPENCL_INSTALLED_FILES}
 383         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 384         COMPONENT libraries)
 385     file(GLOB OPENCL_INSTALLED_FILES
 386         pbcutil/ishift.h
 387         )
 388     install(FILES ${OPENCL_INSTALLED_FILES}
 389         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 390         COMPONENT libraries)
 391
 392     # Install the NBNXM source and headers
 393     file(GLOB OPENCL_INSTALLED_FILES
 394         nbnxm/constants.h
 395         )
 396     install(FILES ${OPENCL_INSTALLED_FILES}
 397         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 398         COMPONENT libraries)
 399     file(GLOB OPENCL_INSTALLED_FILES
 400         nbnxm/opencl/nbnxm_ocl_kernels.cl
 401         nbnxm/opencl/nbnxm_ocl_kernel.clh
 402         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 403         nbnxm/opencl/nbnxm_ocl_kernels.clh
 404         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 405         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 406         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 407         nbnxm/opencl/nbnxm_ocl_consts.h
 408         )
 409     install(FILES ${OPENCL_INSTALLED_FILES}
 410         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 411         COMPONENT libraries)
 412
 413     # Install the PME source and headers
 414     file(GLOB OPENCL_INSTALLED_FILES
 415         ewald/pme_spread.clh
 416         ewald/pme_solve.clh
 417         ewald/pme_gather.clh
 418         ewald/pme_gpu_utils.clh
 419         ewald/pme_program.cl
 420         ewald/pme_gpu_types.h
 421         )
 422     install(FILES ${OPENCL_INSTALLED_FILES}
 423         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 424         COMPONENT libraries)
 425 endif()