src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015, The GROMACS development team.
   5 # Copyright (c) 2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  64 # approach, at least for the build system. See Redmine #2530
  65 function (gmx_compile_cpp_as_cuda)
  66     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  67 endfunction ()
  68
  69 # Add these contents first because linking their tests can take a lot
  70 # of time, so we want lots of parallel work still available after
  71 # linking starts.
  72 add_subdirectory(utility)
  73 # Add normal contents
  74 add_subdirectory(gmxlib)
  75 add_subdirectory(mdlib)
  76 add_subdirectory(applied_forces)
  77 add_subdirectory(listed_forces)
  78 add_subdirectory(nbnxm)
  79 add_subdirectory(commandline)
  80 add_subdirectory(domdec)
  81 add_subdirectory(ewald)
  82 add_subdirectory(fft)
  83 add_subdirectory(gpu_utils)
  84 add_subdirectory(hardware)
  85 add_subdirectory(linearalgebra)
  86 add_subdirectory(math)
  87 add_subdirectory(mdrun)
  88 add_subdirectory(mdrunutility)
  89 add_subdirectory(mdspan)
  90 add_subdirectory(mdtypes)
  91 add_subdirectory(onlinehelp)
  92 add_subdirectory(options)
  93 add_subdirectory(pbcutil)
  94 add_subdirectory(random)
  95 add_subdirectory(restraint)
  96 add_subdirectory(tables)
  97 add_subdirectory(taskassignment)
  98 add_subdirectory(timing)
  99 add_subdirectory(topology)
 100 add_subdirectory(trajectory)
 101 add_subdirectory(swap)
 102 add_subdirectory(essentialdynamics)
 103 add_subdirectory(pulling)
 104 add_subdirectory(awh)
 105 add_subdirectory(simd)
 106 add_subdirectory(imd)
 107 add_subdirectory(compat)
 108 add_subdirectory(mimic)
 109 add_subdirectory(modularsimulator)
 110 if (NOT GMX_BUILD_MDRUN_ONLY)
 111     add_subdirectory(gmxana)
 112     add_subdirectory(gmxpreprocess)
 113     add_subdirectory(correlationfunctions)
 114     add_subdirectory(statistics)
 115     add_subdirectory(analysisdata)
 116     add_subdirectory(coordinateio)
 117     add_subdirectory(trajectoryanalysis)
 118     add_subdirectory(energyanalysis)
 119     add_subdirectory(tools)
 120 endif()
 121
 122 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 123 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 124
 125 # This would be the standard way to include thread_mpi, but
 126 # we want libgromacs to link the functions directly
 127 #if(GMX_THREAD_MPI)
 128 #    add_subdirectory(thread_mpi)
 129 #endif()
 130 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 131 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 132 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 133 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 134 gmx_target_compile_options(thread_mpi)
 135 if (WIN32)
 136     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 137 endif()
 138 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 139
 140 configure_file(version.h.cmakein version.h)
 141 if(GMX_INSTALL_LEGACY_API)
 142   install(FILES
 143           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 144           DESTINATION include/gromacs)
 145 endif()
 146
 147 # This code is here instead of utility/CMakeLists.txt, because CMake
 148 # custom commands and source file properties can only be set in the directory
 149 # that contains the target that uses them.
 150 # TODO: Generate a header instead that can be included from baseversion.cpp.
 151 # That probably simplifies things somewhat.
 152 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 153 gmx_configure_version_file(
 154     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 155     REMOTE_HASH
 156     EXTRA_VARS
 157         GMX_SOURCE_DOI
 158         GMX_RELEASE_HASH
 159         GMX_SOURCE_HASH
 160         )
 161 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 162
 163 # Mark some shared GPU implementation files to compile with CUDA if needed
 164 if (GMX_USE_CUDA)
 165     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 166     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 167 endif()
 168
 169 # set up CUDA compilation with clang
 170 if (GMX_CLANG_CUDA)
 171     foreach (_file ${LIBGROMACS_SOURCES})
 172         get_filename_component(_ext ${_file} EXT)
 173         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 174         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 175             gmx_compile_cuda_file_with_clang(${_file})
 176         endif()
 177     endforeach()
 178 endif()
 179
 180 if (GMX_USE_CUDA)
 181     # Work around FindCUDA that prevents using target_link_libraries()
 182     # with keywords otherwise...
 183     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 184     if (NOT GMX_CLANG_CUDA)
 185         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 186     else()
 187         add_library(libgromacs ${LIBGROMACS_SOURCES})
 188     endif()
 189     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 190 else()
 191     add_library(libgromacs ${LIBGROMACS_SOURCES})
 192 endif()
 193
 194 # Add these contents first because linking their tests can take a lot
 195 # of time, so we want lots of parallel work still available after
 196 # linking starts.
 197 add_subdirectory(fileio)
 198 add_subdirectory(selection)
 199
 200 # Suppress a warning about our abuse of t_inputrec
 201 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 202
 203 # Handle the object libraries that contain the source file
 204 # dependencies that need special handling because they are generated
 205 # or external code.
 206 foreach(object_library ${libgromacs_object_library_dependencies})
 207     if (BUILD_SHARED_LIBS)
 208         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 209     endif()
 210     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 211
 212     # Add the sources from the object libraries to the main library.
 213     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 214 endforeach()
 215 gmx_target_compile_options(libgromacs)
 216 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 217 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 218
 219 if (GMX_USE_OPENCL)
 220     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 221     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 222
 223     # Default to using clFFT found on the system
 224     # switch to quiet at the second run.
 225     if (DEFINED clFFT_LIBRARY)
 226         set (clFFT_FIND_QUIETLY TRUE)
 227     endif()
 228     find_package(clFFT)
 229     if (NOT clFFT_FOUND)
 230         if (GMX_EXTERNAL_CLFFT)
 231             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 232         endif()
 233
 234         if(MSVC)
 235             message(FATAL_ERROR
 236 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 237 requires clFFT, which was not found on your system. GROMACS does bundle
 238 clFFT to help with building for OpenCL, but that clFFT has not yet been
 239 ported to the more recent versions of that compiler that GROMACS itself
 240 requires. Thus for now, OpenCL is not available with MSVC and the internal
 241 build of clFFT in GROMACS 2019. Either change compiler, try installing
 242 a clFFT package, or use the latest GROMACS 2018 point release.")
 243         endif()
 244
 245         # Fall back on the internal version
 246         set (_clFFT_dir ../external/clFFT/src)
 247         add_subdirectory(${_clFFT_dir} clFFT-build)
 248         target_sources(libgromacs PRIVATE
 249             $<TARGET_OBJECTS:clFFT>
 250         )
 251         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 252         # Use the magic variable for how to link any library needed for
 253         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 254         # (e.g. Windows, BSD, Mac).
 255         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 256     else()
 257         target_link_libraries(libgromacs PRIVATE clFFT)
 258     endif()
 259 endif()
 260
 261 # Permit GROMACS code to include externally developed headers, such as
 262 # the functionality from the nonstd project that we use for
 263 # gmx::compat::optional. These are included as system headers so that
 264 # no warnings are issued from them.
 265 #
 266 # TODO Perhaps generalize this for all headers from src/external
 267 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 268
 269 # Temporary fix to allow external access to restraintpotentail
 270 target_include_directories(libgromacs PUBLIC
 271                            $<INSTALL_INTERFACE:include>
 272                            )
 273
 274 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 275     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 276     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 277     # with the SIMD_AVX_512_CXX_FLAGS flags.
 278     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 279 endif()
 280
 281 gmx_setup_tng_for_libgromacs()
 282
 283 target_link_libraries(libgromacs
 284                       PRIVATE
 285                       ${EXTRAE_LIBRARIES}
 286                       ${GMX_EXTRA_LIBRARIES}
 287                       ${GMX_COMMON_LIBRARIES}
 288                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 289                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 290                       ${OpenCL_LIBRARIES}
 291                       $<$<PLATFORM_ID:SunOS>:socket>
 292                       PUBLIC
 293                       ${GMX_PUBLIC_LIBRARIES}
 294                       )
 295 if (GMX_OPENMP)
 296     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 297 endif()
 298 set_target_properties(libgromacs PROPERTIES
 299                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 300                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 301                       VERSION ${LIBRARY_VERSION}
 302                       )
 303
 304 gmx_manage_lmfit()
 305 target_link_libraries(libgromacs PRIVATE lmfit)
 306
 307 # Fix everything found by the latest version of clang that we use in
 308 # Jenkins testing. This should be updated when we update the latest
 309 # tested version of clang.
 310 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^7\.0")
 311    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 312 endif()
 313 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 314    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 315      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 316      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 317      /wd6001  #unitialized memory
 318      /wd6011  #derefencing NULL
 319      /wd6053  #prior call not zero-terminate
 320      /wd6054  #might not be zero-terminated
 321      /wd6385  #reading invalid data
 322      /wd6386  #buffer overrun
 323      /wd6387  #could be '0'
 324      /wd28199 #uninitialized memory
 325      # For compile time constant (e.g. templates) the following warnings have flase postives
 326      /wd6239  #(<non-zero> && <expr>)
 327      /wd6240  #(<expr> && <non-zero>)
 328      /wd6294  #Ill-defined for-loop
 329      /wd6326  #comparison of constant with other constant
 330      /wd28020 #expression involving paramter is not true
 331      # Misc
 332      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 333      /wd6993  #OpenMP ignored
 334      #TODO
 335      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 336      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 337      /wd6246  #hides declaration
 338      >
 339    )
 340 endif()
 341
 342 if (GMX_CLANG_TIDY)
 343    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 344        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 345 endif()
 346
 347 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 348 # and we know they are not real issues. So we only check that it can compile without error
 349 # but ignore all warnings.
 350 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 351     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 352 endif()
 353
 354 # Only install the library in mdrun-only mode if it is actually necessary
 355 # for the binary
 356 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 357     install(TARGETS libgromacs
 358             EXPORT libgromacs
 359             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 360             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 361             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 362             INCLUDES DESTINATION include
 363             COMPONENT libraries)
 364 endif()
 365
 366 if (NOT GMX_BUILD_MDRUN_ONLY)
 367     include(InstallLibInfo.cmake)
 368 endif()
 369
 370 # Technically, the user could want to do this for an OpenCL build
 371 # using the CUDA runtime, but currently there's no reason to want to
 372 # do that.
 373 if (INSTALL_CUDART_LIB) #can be set manual by user
 374     if (GMX_USE_CUDA)
 375         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 376             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 377             if(IS_CUDART) #libcuda should not be installed
 378                 #install also name-links (linker uses those)
 379                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 380                 install(FILES ${CUDA_LIBS} DESTINATION
 381                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 382             endif()
 383         endforeach()
 384     else()
 385         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 386     endif()
 387 endif()
 388
 389 if(GMX_USE_OPENCL)
 390     # Install the utility headers
 391     file(GLOB OPENCL_INSTALLED_FILES
 392         gpu_utils/vectype_ops.clh
 393         gpu_utils/device_utils.clh
 394         )
 395     install(FILES ${OPENCL_INSTALLED_FILES}
 396         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 397         COMPONENT libraries)
 398     file(GLOB OPENCL_INSTALLED_FILES
 399         pbcutil/ishift.h
 400         )
 401     install(FILES ${OPENCL_INSTALLED_FILES}
 402         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 403         COMPONENT libraries)
 404
 405     # Install the NBNXM source and headers
 406     file(GLOB OPENCL_INSTALLED_FILES
 407         nbnxm/constants.h
 408         )
 409     install(FILES ${OPENCL_INSTALLED_FILES}
 410         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 411         COMPONENT libraries)
 412     file(GLOB OPENCL_INSTALLED_FILES
 413         nbnxm/opencl/nbnxm_ocl_kernels.cl
 414         nbnxm/opencl/nbnxm_ocl_kernel.clh
 415         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 416         nbnxm/opencl/nbnxm_ocl_kernels.clh
 417         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 418         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 419         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 420         nbnxm/opencl/nbnxm_ocl_consts.h
 421         )
 422     install(FILES ${OPENCL_INSTALLED_FILES}
 423         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 424         COMPONENT libraries)
 425
 426     # Install the PME source and headers
 427     file(GLOB OPENCL_INSTALLED_FILES
 428         ewald/pme_spread.clh
 429         ewald/pme_solve.clh
 430         ewald/pme_gather.clh
 431         ewald/pme_gpu_utils.clh
 432         ewald/pme_program.cl
 433         ewald/pme_gpu_types.h
 434         )
 435     install(FILES ${OPENCL_INSTALLED_FILES}
 436         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 437         COMPONENT libraries)
 438 endif()