src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 add_library(libgromacs_external OBJECT "")
  47 if(CMAKE_COMPILER_IS_GNUCXX)
  48     # Keep quiet about e.g. linearalgebra module
  49     target_compile_options(libgromacs_external PRIVATE ${CXXFLAGS_NO_STRINGOP_TRUNCATION})
  50 endif()
  51
  52 add_library(libgromacs_generated OBJECT "")
  53 if (BUILD_SHARED_LIBS)
  54     set_target_properties(libgromacs_external PROPERTIES POSITION_INDEPENDENT_CODE true)
  55     set_target_properties(libgromacs_generated PROPERTIES POSITION_INDEPENDENT_CODE true)
  56 endif()
  57
  58 function (_gmx_add_files_to_property PROPERTY)
  59     foreach (_file ${ARGN})
  60         if (IS_ABSOLUTE "${_file}")
  61             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  62         else()
  63             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  64                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  65         endif()
  66     endforeach()
  67 endfunction ()
  68
  69 function (gmx_add_libgromacs_sources)
  70     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  71 endfunction ()
  72
  73 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  74 # approach, at least for the build system. See Redmine #2530
  75 function (gmx_compile_cpp_as_cuda)
  76     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  77 endfunction ()
  78
  79 function (gmx_install_headers)
  80     if (NOT GMX_BUILD_MDRUN_ONLY)
  81         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  82         install(FILES       ${ARGN}
  83                 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${_dest}"
  84                 COMPONENT   development)
  85     endif()
  86     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  87 endfunction ()
  88
  89 function (gmx_write_installed_header_list)
  90     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  91     string(REPLACE ";" "\n" _list "${_list}")
  92     # TODO: Make this only update the file timestamp if the contents actually change.
  93     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  94 endfunction()
  95
  96 add_subdirectory(gmxlib)
  97 add_subdirectory(mdlib)
  98 add_subdirectory(applied-forces)
  99 add_subdirectory(listed-forces)
 100 add_subdirectory(commandline)
 101 add_subdirectory(domdec)
 102 add_subdirectory(ewald)
 103 add_subdirectory(fft)
 104 add_subdirectory(gpu_utils)
 105 add_subdirectory(hardware)
 106 add_subdirectory(linearalgebra)
 107 add_subdirectory(math)
 108 add_subdirectory(mdrun)
 109 add_subdirectory(mdrunutility)
 110 add_subdirectory(mdtypes)
 111 add_subdirectory(onlinehelp)
 112 add_subdirectory(options)
 113 add_subdirectory(pbcutil)
 114 add_subdirectory(random)
 115 add_subdirectory(restraint)
 116 add_subdirectory(tables)
 117 add_subdirectory(taskassignment)
 118 add_subdirectory(timing)
 119 add_subdirectory(topology)
 120 add_subdirectory(trajectory)
 121 add_subdirectory(utility)
 122 add_subdirectory(fileio)
 123 add_subdirectory(swap)
 124 add_subdirectory(essentialdynamics)
 125 add_subdirectory(pulling)
 126 add_subdirectory(awh)
 127 add_subdirectory(simd)
 128 add_subdirectory(imd)
 129 add_subdirectory(compat)
 130 add_subdirectory(mimic)
 131 if (NOT GMX_BUILD_MDRUN_ONLY)
 132     add_subdirectory(gmxana)
 133     add_subdirectory(gmxpreprocess)
 134     add_subdirectory(correlationfunctions)
 135     add_subdirectory(statistics)
 136     add_subdirectory(analysisdata)
 137     add_subdirectory(selection)
 138     add_subdirectory(trajectoryanalysis)
 139     add_subdirectory(energyanalysis)
 140     add_subdirectory(tools)
 141 endif()
 142
 143 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 144 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 145
 146 # This would be the standard way to include thread_mpi, but
 147 # we want libgromacs to link the functions directly
 148 #if(GMX_THREAD_MPI)
 149 #    add_subdirectory(thread_mpi)
 150 #endif()
 151 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 152
 153 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 154 target_sources(libgromacs_external PRIVATE ${THREAD_MPI_SOURCES})
 155
 156 configure_file(version.h.cmakein version.h)
 157 gmx_install_headers(
 158     analysisdata.h
 159     commandline.h
 160     options.h
 161     random.h
 162     selection.h
 163     trajectoryanalysis.h
 164     utility.h
 165     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 166     )
 167
 168 # This code is here instead of utility/CMakeLists.txt, because CMake
 169 # custom commands and source file properties can only be set in the directory
 170 # that contains the target that uses them.
 171 # TODO: Generate a header instead that can be included from baseversion.c.
 172 # That probably simplifies things somewhat.
 173 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 174 gmx_configure_version_file(
 175     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 176     REMOTE_HASH
 177     EXTRA_VARS
 178         GMX_SOURCE_DOI
 179     )
 180 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE}
 181      $<TARGET_OBJECTS:libgromacs_external>
 182      $<TARGET_OBJECTS:libgromacs_generated>)
 183
 184 # Mark some shared GPU implementation files to compile with CUDA if needed
 185 if (GMX_USE_CUDA)
 186     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 187     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 188 endif()
 189
 190 # set up CUDA compilation with clang
 191 if (GMX_CLANG_CUDA)
 192     foreach (_file ${LIBGROMACS_SOURCES})
 193         get_filename_component(_ext ${_file} EXT)
 194         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 195         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 196             gmx_compile_cuda_file_with_clang(${_file})
 197         endif()
 198     endforeach()
 199 endif()
 200
 201 if (GMX_USE_CUDA)
 202     # Work around FindCUDA that prevents using target_link_libraries()
 203     # with keywords otherwise...
 204     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 205     if (NOT GMX_CLANG_CUDA)
 206         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 207     else()
 208         add_library(libgromacs ${LIBGROMACS_SOURCES})
 209     endif()
 210     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 211 else()
 212     add_library(libgromacs ${LIBGROMACS_SOURCES})
 213 endif()
 214
 215 if (GMX_USE_OPENCL)
 216     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 217     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 218
 219     # Default to using clFFT found on the system
 220     # switch to quiet at the second run.
 221     if (DEFINED clFFT_LIBRARY)
 222         set (clFFT_FIND_QUIETLY TRUE)
 223     endif()
 224     find_package(clFFT)
 225     if (NOT clFFT_FOUND)
 226         if (GMX_EXTERNAL_CLFFT)
 227             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 228         endif()
 229
 230         if(MSVC)
 231             message(FATAL_ERROR
 232 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 233 requires clFFT, which was not found on your system. GROMACS does bundle
 234 clFFT to help with building for OpenCL, but that clFFT has not yet been
 235 ported to the more recent versions of that compiler that GROMACS itself
 236 requires. Thus for now, OpenCL is not available with MSVC and the internal
 237 build of clFFT in GROMACS 2019. Either change compiler, try installing
 238 a clFFT package, or use the latest GROMACS 2018 point release.")
 239         endif()
 240
 241         # Fall back on the internal version
 242         set (_clFFT_dir ../external/clFFT/src)
 243         add_subdirectory(${_clFFT_dir} clFFT-build)
 244         target_sources(libgromacs PRIVATE
 245             $<TARGET_OBJECTS:clFFT>
 246         )
 247         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 248         # Use the magic variable for how to link any library needed for
 249         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 250         # (e.g. Windows, BSD, Mac).
 251         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 252     else()
 253         target_link_libraries(libgromacs PRIVATE clFFT)
 254     endif()
 255 endif()
 256
 257 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 258 # is a generated source file. These are awkward to suppress inline, so
 259 # we do it in the compilation command (after testing that the compiler
 260 # supports the suppressions). Same issue exists for nonbonded kernels
 261 # so we supress them for all generated files.
 262 include(CheckCXXCompilerFlag)
 263 check_cxx_compiler_flag("-Wno-unused -Wno-unused-parameter" HAS_NO_UNUSED)
 264 check_cxx_compiler_flag(-Wno-missing-declarations HAS_NO_MISSING_DECL)
 265 check_cxx_compiler_flag(-Wno-missing-prototypes HAS_NO_MISSING_PROTO)
 266 check_cxx_compiler_flag(/wd4101 HAS_NO_MSVC_UNUSED)
 267 if (NOT MSVC)
 268     check_cxx_compiler_flag(-wd1419 HAS_DECL_IN_SOURCE)
 269 endif()
 270 if (HAS_NO_UNUSED)
 271     target_compile_options(libgromacs_generated PRIVATE "-Wno-unused;-Wno-unused-parameter")
 272 endif()
 273 if (HAS_NO_MISSING_DECL)
 274     target_compile_options(libgromacs_generated PRIVATE "-Wno-missing-declarations")
 275 endif()
 276 # TODO The group scheme kernels don't use proper function prototype
 277 # declarations, and clang warns about such use, which we suppress
 278 # rather than fix. We would prefer to use no suppressions. However
 279 # other compilers do not support such a warning suppression for C++
 280 # source files, and issue warnings about that. Remove the use of
 281 # -Wno-missing-prototypes here and above when the group scheme is
 282 # removed.
 283 if (HAS_NO_MISSING_PROTO AND "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 284     target_compile_options(libgromacs_generated PRIVATE "-Wno-missing-prototypes")
 285 endif()
 286 if (HAS_NO_MSVC_UNUSED)
 287     target_compile_options(libgromacs_generated PRIVATE "/wd4101")
 288 endif()
 289 if (HAS_DECL_IN_SOURCE)
 290     target_compile_options(libgromacs_generated PRIVATE "-wd1419")
 291 endif()
 292
 293 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 294     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 295     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 296     # with the SIMD_AVX_512_CXX_FLAGS flags.
 297     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 298 endif()
 299
 300 gmx_setup_tng_for_libgromacs()
 301
 302 target_link_libraries(libgromacs
 303                       PRIVATE
 304                       ${EXTRAE_LIBRARIES}
 305                       ${GMX_EXTRA_LIBRARIES}
 306                       ${GMX_COMMON_LIBRARIES}
 307                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 308                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 309                       ${OpenCL_LIBRARIES}
 310                       ${GMX_STDLIB_LIBRARIES}
 311                       PUBLIC
 312                       ${GMX_PUBLIC_LIBRARIES}
 313                       )
 314 set_target_properties(libgromacs PROPERTIES
 315                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 316                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 317                       VERSION ${LIBRARY_VERSION}
 318                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 319
 320 gmx_manage_lmfit()
 321 target_link_libraries(libgromacs PRIVATE lmfit)
 322
 323 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^6\.0")
 324    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 325 endif()
 326 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 327    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 328      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 329      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 330      /wd6001  #unitialized memory
 331      /wd6011  #derefencing NULL
 332      /wd6053  #prior call not zero-terminate
 333      /wd6054  #might not be zero-terminated
 334      /wd6385  #reading invalid data
 335      /wd6386  #buffer overrun
 336      /wd6387  #could be '0'
 337      /wd28199 #uninitialized memory
 338      # For compile time constant (e.g. templates) the following warnings have flase postives
 339      /wd6239  #(<non-zero> && <expr>)
 340      /wd6240  #(<expr> && <non-zero>)
 341      /wd6294  #Ill-defined for-loop
 342      /wd6326  #comparison of constant with other constant
 343      /wd28020 #expression involving paramter is not true
 344      # Misc
 345      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 346      /wd6993  #OpenMP ignored
 347      #TODO
 348      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 349      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 350      /wd6246  #hides declaration
 351      >
 352    )
 353 endif()
 354
 355 if (GMX_CLANG_TIDY)
 356    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 357        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 358 endif()
 359
 360 gmx_write_installed_header_list()
 361
 362 # Only install the library in mdrun-only mode if it is actually necessary
 363 # for the binary
 364 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 365     install(TARGETS libgromacs
 366             EXPORT libgromacs
 367             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 368             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 369             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 370             COMPONENT libraries)
 371 endif()
 372
 373 if (NOT GMX_BUILD_MDRUN_ONLY)
 374     include(InstallLibInfo.cmake)
 375 endif()
 376
 377 # Technically, the user could want to do this for an OpenCL build
 378 # using the CUDA runtime, but currently there's no reason to want to
 379 # do that.
 380 if (INSTALL_CUDART_LIB) #can be set manual by user
 381     if (GMX_USE_CUDA)
 382         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 383             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 384             if(IS_CUDART) #libcuda should not be installed
 385                 #install also name-links (linker uses those)
 386                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 387                 install(FILES ${CUDA_LIBS} DESTINATION
 388                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 389             endif()
 390         endforeach()
 391     else()
 392         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 393     endif()
 394 endif()
 395
 396 if(GMX_USE_OPENCL)
 397     # Install the utility headers
 398     file(GLOB OPENCL_INSTALLED_FILES
 399         gpu_utils/vectype_ops.clh
 400         gpu_utils/device_utils.clh
 401         )
 402     install(FILES ${OPENCL_INSTALLED_FILES}
 403         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 404         COMPONENT libraries)
 405     file(GLOB OPENCL_INSTALLED_FILES
 406         pbcutil/ishift.h
 407         )
 408     install(FILES ${OPENCL_INSTALLED_FILES}
 409         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 410         COMPONENT libraries)
 411
 412     # Install the NB source and headers
 413     file(GLOB OPENCL_INSTALLED_FILES
 414         mdlib/nbnxn_consts.h
 415         )
 416     install(FILES ${OPENCL_INSTALLED_FILES}
 417         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/mdlib
 418         COMPONENT libraries)
 419     file(GLOB OPENCL_INSTALLED_FILES
 420         mdlib/nbnxn_ocl/nbnxn_ocl_kernels.cl
 421         mdlib/nbnxn_ocl/nbnxn_ocl_kernel.clh
 422         mdlib/nbnxn_ocl/nbnxn_ocl_kernel_pruneonly.clh
 423         mdlib/nbnxn_ocl/nbnxn_ocl_kernels.clh
 424         mdlib/nbnxn_ocl/nbnxn_ocl_kernels_fastgen.clh
 425         mdlib/nbnxn_ocl/nbnxn_ocl_kernels_fastgen_add_twincut.clh
 426         mdlib/nbnxn_ocl/nbnxn_ocl_kernel_utils.clh
 427         mdlib/nbnxn_ocl/nbnxn_ocl_consts.h
 428         )
 429     install(FILES ${OPENCL_INSTALLED_FILES}
 430         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/mdlib/nbnxn_ocl
 431         COMPONENT libraries)
 432
 433     # Install the PME source and headers
 434     file(GLOB OPENCL_INSTALLED_FILES
 435         ewald/pme-spread.clh
 436         ewald/pme-solve.clh
 437         ewald/pme-gather.clh
 438         ewald/pme-gpu-utils.clh
 439         ewald/pme-program.cl
 440         ewald/pme-gpu-types.h
 441         )
 442     install(FILES ${OPENCL_INSTALLED_FILES}
 443         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 444         COMPONENT libraries)
 445 endif()