src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 add_subdirectory(legacyheaders)
  38 add_subdirectory(gmxlib)
  39 add_subdirectory(mdlib)
  40 add_subdirectory(gmxpreprocess)
  41 add_subdirectory(gmxana)
  42 add_subdirectory(analysisdata)
  43 add_subdirectory(commandline)
  44 add_subdirectory(linearalgebra)
  45 add_subdirectory(onlinehelp)
  46 add_subdirectory(options)
  47 add_subdirectory(selection)
  48 add_subdirectory(trajectoryanalysis)
  49 add_subdirectory(utility)
  50
  51 file(GLOB LIBGROMACS_HEADERS *.h)
  52 install(FILES ${LIBGROMACS_HEADERS} DESTINATION ${INCL_INSTALL_DIR}/gromacs
  53         COMPONENT development)
  54
  55 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  56
  57 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/version.h.cmakein ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  58 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/version.h
  59     DESTINATION ${INCL_INSTALL_DIR}/gromacs
  60     COMPONENT development)
  61
  62 # Add target that generates gitversion.c every time make is run
  63 # if git version info is requested
  64 # This code is here instead of utility/CMakeLists.txt because CMake
  65 # ignores set_source_file_properties from subdirectories.
  66 if (GMX_GIT_VERSION_INFO)
  67     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  68     add_custom_target(gmx_version ALL
  69             COMMAND ${CMAKE_COMMAND}
  70                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  71                 -D GIT_VERSION="${GIT_VERSION}"
  72                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  73                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  74                 -D VERSION_C_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  75                 -D VERSION_C_OUT=${GENERATED_VERSION_FILE}
  76                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  77             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  78             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  79             COMMENT "Generating git version information")
  80     set_source_files_properties(${GENERATED_VERSION_FILE}
  81                                 PROPERTIES GENERATED true)
  82     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
  83 endif()
  84
  85 # apply gcc 4.4.x bug workaround
  86 if(GMX_USE_GCC44_BUG_WORKAROUND)
  87    include(gmxGCC44O3BugWorkaround)
  88    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
  89    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
  90    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
  91 endif()
  92
  93 add_library(libgromacs ${LIBGROMACS_SOURCES})
  94 if (GMX_GIT_VERSION_INFO)
  95     add_dependencies(libgromacs gmx_version)
  96 endif ()
  97
  98 if(GMX_BUILD_OWN_FFTW)
  99     # This dependency has to be made here rather than the CMakeLists.txt that
 100     # does the FFTW build, because of the order in which
 101     # add_subdirectory() calls are made in the top-level CMakeLists.txt; the
 102     # md library target does not necessarily exist yet. Also enabling and
 103     # disabling GMX_BUILD_OWN_FFTW changes dependencies correctly.
 104     add_dependencies(libgromacs gmxfftw)
 105 endif()
 106
 107 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 108                       ${GMX_EXTRA_LIBRARIES}
 109                       ${FFT_LIBRARIES} ${XML_LIBRARIES} ${GSL_LIBRARIES}
 110                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 111 set_target_properties(libgromacs PROPERTIES
 112                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 113                       SOVERSION ${SOVERSION}
 114                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 115
 116 install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 117
 118 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 119                ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 120 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 121         DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 122         RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 123         COMPONENT development)
 124
 125 if (INSTALL_CUDART_LIB) #can be set manual by user
 126     if (GMX_GPU)
 127         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 128             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 129             if(IS_CUDART) #libcuda should not be installed
 130                 #install also name-links (linker uses those)
 131                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 132                 install(FILES ${CUDA_LIBS} DESTINATION
 133                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 134             endif()
 135         endforeach()
 136     else()
 137         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 138     endif()
 139 endif ()