src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 add_subdirectory(gmxlib)
  49 add_subdirectory(mdlib)
  50 add_subdirectory(gmxpreprocess)
  51 add_subdirectory(commandline)
  52 add_subdirectory(fft)
  53 add_subdirectory(linearalgebra)
  54 add_subdirectory(onlinehelp)
  55 add_subdirectory(options)
  56 add_subdirectory(utility)
  57 if (NOT GMX_BUILD_MDRUN_ONLY)
  58     add_subdirectory(legacyheaders)
  59     add_subdirectory(gmxana)
  60     add_subdirectory(analysisdata)
  61     add_subdirectory(selection)
  62     add_subdirectory(trajectoryanalysis)
  63 endif ()
  64
  65 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  66
  67 file(GLOB LIBGROMACS_HEADERS *.h)
  68 configure_file(version.h.cmakein version.h)
  69 gmx_install_headers("" ${LIBGROMACS_HEADERS})
  70 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  71
  72 # Add target that generates gitversion.c every time make is run
  73 # if git version info is requested
  74 # This code is here instead of utility/CMakeLists.txt because CMake
  75 # ignores set_source_file_properties from subdirectories.
  76 if (GMX_GIT_VERSION_INFO)
  77     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  78     add_custom_target(gmx-version ALL
  79             COMMAND ${CMAKE_COMMAND}
  80                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  81                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  82                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  83                 -D VERSION_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  84                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
  85                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  86             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  87             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  88             COMMENT "Generating git version information")
  89     set_source_files_properties(${GENERATED_VERSION_FILE}
  90                                 PROPERTIES GENERATED true)
  91     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
  92 endif()
  93
  94 # apply gcc 4.4.x bug workaround
  95 if(GMX_USE_GCC44_BUG_WORKAROUND)
  96    include(gmxGCC44O3BugWorkaround)
  97    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
  98    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
  99    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 100 endif()
 101
 102 add_library(libgromacs ${LIBGROMACS_SOURCES})
 103 if (GMX_GIT_VERSION_INFO)
 104     add_dependencies(libgromacs gmx-version)
 105 endif ()
 106
 107 if(GMX_BUILD_OWN_FFTW)
 108     # This dependency has to be made here rather than the CMakeLists.txt that
 109     # does the FFTW build, because of the order in which
 110     # add_subdirectory() calls are made in the top-level CMakeLists.txt; the
 111     # md library target does not necessarily exist yet. Also enabling and
 112     # disabling GMX_BUILD_OWN_FFTW changes dependencies correctly.
 113     add_dependencies(libgromacs gmxfftw)
 114 endif()
 115
 116 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 117                       ${GMX_EXTRA_LIBRARIES}
 118                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 119                       ${XML_LIBRARIES} ${GSL_LIBRARIES}
 120                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 121 set_target_properties(libgromacs PROPERTIES
 122                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 123                       SOVERSION ${SOVERSION}
 124                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 125
 126 # Only install the library in mdrun-only mode if it is actually necessary
 127 # for the binary
 128 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 129     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 130 endif()
 131
 132 if (NOT GMX_BUILD_MDRUN_ONLY)
 133     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 134                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 135     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 136             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 137             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 138             COMPONENT development)
 139 endif()
 140
 141 if (INSTALL_CUDART_LIB) #can be set manual by user
 142     if (GMX_GPU)
 143         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 144             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 145             if(IS_CUDART) #libcuda should not be installed
 146                 #install also name-links (linker uses those)
 147                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 148                 install(FILES ${CUDA_LIBS} DESTINATION
 149                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 150             endif()
 151         endforeach()
 152     else()
 153         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 154     endif()
 155 endif ()