src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  64 # approach, at least for the build system. See Issue #2530
  65 function (gmx_compile_cpp_as_cuda)
  66     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  67 endfunction ()
  68
  69 # Permit the configuration to disable compiling the many nbnxm kernels
  70 # and others involved in force calculations. Currently only
  71 # short-ranged and bonded kernels are disabled this way, but in future
  72 # others may be appropriate. Thus the cmake option is not specific to
  73 # nbnxm module.
  74 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  75 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  76
  77 # Add these contents first because linking their tests can take a lot
  78 # of time, so we want lots of parallel work still available after
  79 # linking starts.
  80 add_subdirectory(utility)
  81 # Add normal contents
  82 add_subdirectory(gmxlib)
  83 add_subdirectory(mdlib)
  84 add_subdirectory(applied_forces)
  85 add_subdirectory(listed_forces)
  86 add_subdirectory(nbnxm)
  87 add_subdirectory(commandline)
  88 add_subdirectory(domdec)
  89 add_subdirectory(ewald)
  90 add_subdirectory(fft)
  91 add_subdirectory(gpu_utils)
  92 add_subdirectory(hardware)
  93 add_subdirectory(linearalgebra)
  94 add_subdirectory(math)
  95 add_subdirectory(mdrun)
  96 add_subdirectory(mdrunutility)
  97 add_subdirectory(mdspan)
  98 add_subdirectory(mdtypes)
  99 add_subdirectory(onlinehelp)
 100 add_subdirectory(options)
 101 add_subdirectory(pbcutil)
 102 add_subdirectory(random)
 103 add_subdirectory(restraint)
 104 add_subdirectory(tables)
 105 add_subdirectory(taskassignment)
 106 add_subdirectory(timing)
 107 add_subdirectory(topology)
 108 add_subdirectory(trajectory)
 109 add_subdirectory(swap)
 110 add_subdirectory(essentialdynamics)
 111 add_subdirectory(pulling)
 112 add_subdirectory(awh)
 113 add_subdirectory(simd)
 114 add_subdirectory(imd)
 115 add_subdirectory(compat)
 116 add_subdirectory(mimic)
 117 add_subdirectory(modularsimulator)
 118 if (NOT GMX_BUILD_MDRUN_ONLY)
 119     add_subdirectory(gmxana)
 120     add_subdirectory(gmxpreprocess)
 121     add_subdirectory(correlationfunctions)
 122     add_subdirectory(statistics)
 123     add_subdirectory(analysisdata)
 124     add_subdirectory(coordinateio)
 125     add_subdirectory(trajectoryanalysis)
 126     add_subdirectory(energyanalysis)
 127     add_subdirectory(tools)
 128 endif()
 129
 130 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 131 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 132
 133 # This would be the standard way to include thread_mpi, but
 134 # we want libgromacs to link the functions directly
 135 #if(GMX_THREAD_MPI)
 136 #    add_subdirectory(thread_mpi)
 137 #endif()
 138 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 139 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 140 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 141 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 142 if(CYGWIN)
 143     # Needs POSIX-isms for strdup, not just std-isms
 144     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 145 endif()
 146 gmx_target_compile_options(thread_mpi)
 147 if (WIN32)
 148     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 149 endif()
 150 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 151
 152 configure_file(version.h.cmakein version.h)
 153 if(GMX_INSTALL_LEGACY_API)
 154   install(FILES
 155           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 156           DESTINATION include/gromacs)
 157 endif()
 158
 159 # This code is here instead of utility/CMakeLists.txt, because CMake
 160 # custom commands and source file properties can only be set in the directory
 161 # that contains the target that uses them.
 162 # TODO: Generate a header instead that can be included from baseversion.cpp.
 163 # That probably simplifies things somewhat.
 164 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 165 gmx_configure_version_file(
 166     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 167     REMOTE_HASH
 168     EXTRA_VARS
 169         GMX_SOURCE_DOI
 170         GMX_RELEASE_HASH
 171         GMX_SOURCE_HASH
 172         )
 173 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 174
 175 # Mark some shared GPU implementation files to compile with CUDA if needed
 176 if (GMX_USE_CUDA)
 177     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 178     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 179 endif()
 180
 181 # set up CUDA compilation with clang
 182 if (GMX_CLANG_CUDA)
 183     foreach (_file ${LIBGROMACS_SOURCES})
 184         get_filename_component(_ext ${_file} EXT)
 185         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 186         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 187             gmx_compile_cuda_file_with_clang(${_file})
 188         endif()
 189     endforeach()
 190 endif()
 191
 192 if (GMX_USE_CUDA)
 193     # Work around FindCUDA that prevents using target_link_libraries()
 194     # with keywords otherwise...
 195     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 196     if (NOT GMX_CLANG_CUDA)
 197         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 198     else()
 199         add_library(libgromacs ${LIBGROMACS_SOURCES})
 200     endif()
 201     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 202 else()
 203     add_library(libgromacs ${LIBGROMACS_SOURCES})
 204 endif()
 205
 206 # Add these contents first because linking their tests can take a lot
 207 # of time, so we want lots of parallel work still available after
 208 # linking starts.
 209 add_subdirectory(fileio)
 210 add_subdirectory(selection)
 211
 212 # Suppress a warning about our abuse of t_inputrec
 213 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 214
 215 # Handle the object libraries that contain the source file
 216 # dependencies that need special handling because they are generated
 217 # or external code.
 218 foreach(object_library ${libgromacs_object_library_dependencies})
 219     if (BUILD_SHARED_LIBS)
 220         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 221     endif()
 222     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 223
 224     # Add the sources from the object libraries to the main library.
 225     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 226 endforeach()
 227 gmx_target_compile_options(libgromacs)
 228 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 229 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 230
 231 if (GMX_USE_OPENCL)
 232     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 233     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 234
 235     # Default to using clFFT found on the system
 236     # switch to quiet at the second run.
 237     if (DEFINED clFFT_LIBRARY)
 238         set (clFFT_FIND_QUIETLY TRUE)
 239     endif()
 240     find_package(clFFT)
 241     if (NOT clFFT_FOUND)
 242         if (GMX_EXTERNAL_CLFFT)
 243             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 244         endif()
 245
 246         if(MSVC)
 247             message(FATAL_ERROR
 248 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 249 requires clFFT, which was not found on your system. GROMACS does bundle
 250 clFFT to help with building for OpenCL, but that clFFT has not yet been
 251 ported to the more recent versions of that compiler that GROMACS itself
 252 requires. Thus for now, OpenCL is not available with MSVC and the internal
 253 build of clFFT in GROMACS 2019. Either change compiler, try installing
 254 a clFFT package, or use the latest GROMACS 2018 point release.")
 255         endif()
 256
 257         # Fall back on the internal version
 258         set (_clFFT_dir ../external/clFFT/src)
 259         add_subdirectory(${_clFFT_dir} clFFT-build)
 260         target_sources(libgromacs PRIVATE
 261             $<TARGET_OBJECTS:clFFT>
 262         )
 263         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 264         # Use the magic variable for how to link any library needed for
 265         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 266         # (e.g. Windows, BSD, Mac).
 267         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 268     else()
 269         target_link_libraries(libgromacs PRIVATE clFFT)
 270     endif()
 271 endif()
 272
 273 # Permit GROMACS code to include externally developed headers, such as
 274 # the functionality from the nonstd project that we use for
 275 # gmx::compat::optional. These are included as system headers so that
 276 # no warnings are issued from them.
 277 #
 278 # TODO Perhaps generalize this for all headers from src/external
 279 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 280
 281 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 282     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 283     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 284     # with the SIMD_AVX_512_CXX_FLAGS flags.
 285     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 286 endif()
 287
 288 gmx_setup_tng_for_libgromacs()
 289
 290 target_link_libraries(libgromacs
 291                       PRIVATE
 292                       ${EXTRAE_LIBRARIES}
 293                       ${GMX_EXTRA_LIBRARIES}
 294                       ${GMX_COMMON_LIBRARIES}
 295                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 296                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 297                       ${OpenCL_LIBRARIES}
 298                       $<$<PLATFORM_ID:SunOS>:socket>
 299                       PUBLIC
 300                       ${GMX_PUBLIC_LIBRARIES}
 301                       )
 302 if (GMX_OPENMP)
 303     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 304 endif()
 305 set_target_properties(libgromacs PROPERTIES
 306                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 307                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 308                       VERSION ${LIBRARY_VERSION}
 309                       )
 310
 311 gmx_manage_lmfit()
 312 target_link_libraries(libgromacs PRIVATE lmfit)
 313
 314 # Make sure we fix "everything" found by more recent versions of clang.
 315 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 316    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 317 endif()
 318 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 319    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 320      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 321      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 322      /wd6001  #unitialized memory
 323      /wd6011  #derefencing NULL
 324      /wd6053  #prior call not zero-terminate
 325      /wd6054  #might not be zero-terminated
 326      /wd6385  #reading invalid data
 327      /wd6386  #buffer overrun
 328      /wd6387  #could be '0'
 329      /wd28199 #uninitialized memory
 330      # For compile time constant (e.g. templates) the following warnings have flase postives
 331      /wd6239  #(<non-zero> && <expr>)
 332      /wd6240  #(<expr> && <non-zero>)
 333      /wd6294  #Ill-defined for-loop
 334      /wd6326  #comparison of constant with other constant
 335      /wd28020 #expression involving paramter is not true
 336      # Misc
 337      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 338      /wd6993  #OpenMP ignored
 339      #TODO
 340      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 341      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 342      /wd6246  #hides declaration
 343      >
 344    )
 345 endif()
 346
 347 if (GMX_CLANG_TIDY)
 348    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 349        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 350 endif()
 351
 352 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 353 # and we know they are not real issues. So we only check that it can compile without error
 354 # but ignore all warnings.
 355 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 356     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 357 endif()
 358
 359 # Only install the library in mdrun-only mode if it is actually necessary
 360 # for the binary
 361 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 362     install(TARGETS libgromacs
 363             COMPONENT libraries
 364             EXPORT libgromacs
 365             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 366             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 367             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 368             INCLUDES DESTINATION include)
 369     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 370     add_library(Gromacs::libgromacs ALIAS libgromacs)
 371 endif()
 372
 373 if (NOT GMX_BUILD_MDRUN_ONLY)
 374     include(InstallLibInfo.cmake)
 375 endif()
 376
 377 # Technically, the user could want to do this for an OpenCL build
 378 # using the CUDA runtime, but currently there's no reason to want to
 379 # do that.
 380 if (INSTALL_CUDART_LIB) #can be set manual by user
 381     if (GMX_USE_CUDA)
 382         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 383             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 384             if(IS_CUDART) #libcuda should not be installed
 385                 #install also name-links (linker uses those)
 386                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 387                 install(FILES ${CUDA_LIBS} DESTINATION
 388                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 389             endif()
 390         endforeach()
 391     else()
 392         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 393     endif()
 394 endif()
 395
 396 if(GMX_USE_OPENCL)
 397     # Install the utility headers
 398     file(GLOB OPENCL_INSTALLED_FILES
 399         gpu_utils/vectype_ops.clh
 400         gpu_utils/device_utils.clh
 401         )
 402     install(FILES ${OPENCL_INSTALLED_FILES}
 403         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 404         COMPONENT libraries)
 405     file(GLOB OPENCL_INSTALLED_FILES
 406         pbcutil/ishift.h
 407         )
 408     install(FILES ${OPENCL_INSTALLED_FILES}
 409         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 410         COMPONENT libraries)
 411
 412     # Install the NBNXM source and headers
 413     file(GLOB OPENCL_INSTALLED_FILES
 414         nbnxm/constants.h
 415         )
 416     install(FILES ${OPENCL_INSTALLED_FILES}
 417         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 418         COMPONENT libraries)
 419     file(GLOB OPENCL_INSTALLED_FILES
 420         nbnxm/opencl/nbnxm_ocl_kernels.cl
 421         nbnxm/opencl/nbnxm_ocl_kernel.clh
 422         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 423         nbnxm/opencl/nbnxm_ocl_kernels.clh
 424         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 425         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 426         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 427         nbnxm/opencl/nbnxm_ocl_consts.h
 428         )
 429     install(FILES ${OPENCL_INSTALLED_FILES}
 430         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 431         COMPONENT libraries)
 432
 433     # Install the PME source and headers
 434     file(GLOB OPENCL_INSTALLED_FILES
 435         ewald/pme_spread.clh
 436         ewald/pme_solve.clh
 437         ewald/pme_gather.clh
 438         ewald/pme_gpu_utils.clh
 439         ewald/pme_program.cl
 440         ewald/pme_gpu_types.h
 441         )
 442     install(FILES ${OPENCL_INSTALLED_FILES}
 443         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 444         COMPONENT libraries)
 445 endif()