src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 add_subdirectory(gmxlib)
  49 add_subdirectory(mdlib)
  50 add_subdirectory(gmxpreprocess)
  51 add_subdirectory(commandline)
  52 add_subdirectory(fft)
  53 add_subdirectory(linearalgebra)
  54 add_subdirectory(math)
  55 add_subdirectory(random)
  56 add_subdirectory(onlinehelp)
  57 add_subdirectory(options)
  58 add_subdirectory(timing)
  59 add_subdirectory(utility)
  60 add_subdirectory(fileio)
  61 add_subdirectory(swap)
  62 add_subdirectory(essentialdynamics)
  63 add_subdirectory(pulling)
  64 add_subdirectory(simd)
  65 add_subdirectory(imd)
  66 if (NOT GMX_BUILD_MDRUN_ONLY)
  67     add_subdirectory(legacyheaders)
  68     add_subdirectory(gmxana)
  69     add_subdirectory(statistics)
  70     add_subdirectory(analysisdata)
  71     add_subdirectory(selection)
  72     add_subdirectory(trajectoryanalysis)
  73     add_subdirectory(tools)
  74 endif()
  75
  76 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  77
  78 # This would be the standard way to include thread_mpi, but
  79 # we want libgromacs to link the functions directly
  80 #if(GMX_THREAD_MPI)
  81 #    add_subdirectory(thread_mpi)
  82 #endif()
  83 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
  84
  85 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
  86 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
  87
  88 file(GLOB LIBGROMACS_HEADERS *.h)
  89 configure_file(version.h.cmakein version.h)
  90 gmx_install_headers("" ${LIBGROMACS_HEADERS})
  91 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  92
  93 # Add target that generates baseversion-gen.c every time make is run
  94 # if git version info is requested, or create it statically.
  95 # This code is here instead of utility/CMakeLists.txt because CMake
  96 # ignores set_source_file_properties from subdirectories.
  97 set(GENERATED_VERSION_FILE
  98     ${CMAKE_CURRENT_BINARY_DIR}/utility/baseversion-gen.c)
  99 set(GENERATED_VERSION_FILE_SOURCE
 100     ${CMAKE_CURRENT_SOURCE_DIR}/utility/baseversion-gen.c.cmakein)
 101 if (GMX_GIT_VERSION_INFO)
 102     add_custom_target(gmx-version ALL
 103             COMMAND ${CMAKE_COMMAND}
 104                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
 105                 -D PROJECT_VERSION="${PROJECT_VERSION}"
 106                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
 107                 -D VERSION_CMAKEIN=${GENERATED_VERSION_FILE_SOURCE}
 108                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
 109                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
 110             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 111             DEPENDS ${GENERATED_VERSION_FILE_SOURCE}
 112             COMMENT "Generating git version information")
 113     set_source_files_properties(${GENERATED_VERSION_FILE}
 114                                 PROPERTIES GENERATED true)
 115 else()
 116     set(GMX_PROJECT_VERSION_STR ${PROJECT_VERSION})
 117     configure_file(${GENERATED_VERSION_FILE_SOURCE} ${GENERATED_VERSION_FILE})
 118 endif()
 119 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 120
 121 # apply gcc 4.4.x bug workaround
 122 if(GMX_USE_GCC44_BUG_WORKAROUND)
 123    include(gmxGCC44O3BugWorkaround)
 124    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 125    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 126    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 127 endif()
 128
 129 add_library(libgromacs ${LIBGROMACS_SOURCES})
 130 if (GMX_GIT_VERSION_INFO)
 131     add_dependencies(libgromacs gmx-version)
 132 endif()
 133
 134 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 135 # is a generated source file. These are awkward to suppress inline, so
 136 # we do it in the compilation command (after testing that the compiler
 137 # supports the suppressions). Setting the properties only works after
 138 # the related target has been created, e.g. after when the file is
 139 # used with add_library().
 140 include(CheckCXXCompilerFlag)
 141 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 142 if (HAS_NO_UNUSED_PARAMETER)
 143     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 144 endif()
 145 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 146 if (HAS_NO_DEPRECATED_REGISTER)
 147     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 148 else()
 149     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 150     if (HAS_NO_DEPRECATED)
 151         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 152     endif()
 153 endif()
 154 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 155
 156 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 157                       ${GMX_EXTRA_LIBRARIES}
 158                       ${GMX_TNG_LIBRARIES}
 159                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 160                       ${XML_LIBRARIES} ${GSL_LIBRARIES}
 161                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 162 set_target_properties(libgromacs PROPERTIES
 163                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 164                       SOVERSION ${LIBRARY_SOVERSION}
 165                       VERSION ${LIBRARY_VERSION}
 166                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 167
 168 # Only install the library in mdrun-only mode if it is actually necessary
 169 # for the binary
 170 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 171     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 172 endif()
 173
 174 if (NOT GMX_BUILD_MDRUN_ONLY)
 175     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 176                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 177     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 178             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 179             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 180             COMPONENT development)
 181 endif()
 182
 183 if (INSTALL_CUDART_LIB) #can be set manual by user
 184     if (GMX_GPU)
 185         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 186             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 187             if(IS_CUDART) #libcuda should not be installed
 188                 #install also name-links (linker uses those)
 189                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 190                 install(FILES ${CUDA_LIBS} DESTINATION
 191                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 192             endif()
 193         endforeach()
 194     else()
 195         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 196     endif()
 197 endif()