src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 add_library(libgromacs_external OBJECT "")
  47 add_library(libgromacs_generated OBJECT "")
  48 if (BUILD_SHARED_LIBS)
  49     set_target_properties(libgromacs_external PROPERTIES POSITION_INDEPENDENT_CODE true)
  50     set_target_properties(libgromacs_generated PROPERTIES POSITION_INDEPENDENT_CODE true)
  51 endif()
  52
  53 function (_gmx_add_files_to_property PROPERTY)
  54     foreach (_file ${ARGN})
  55         if (IS_ABSOLUTE "${_file}")
  56             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  57         else()
  58             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  59                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  60         endif()
  61     endforeach()
  62 endfunction ()
  63
  64 function (gmx_add_libgromacs_sources)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  69 # approach, at least for the build system. See Redmine #2530
  70 function (gmx_compile_cpp_as_cuda)
  71     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  72 endfunction ()
  73
  74 function (gmx_install_headers)
  75     if (NOT GMX_BUILD_MDRUN_ONLY)
  76         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  77         install(FILES       ${ARGN}
  78                 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${_dest}"
  79                 COMPONENT   development)
  80     endif()
  81     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  82 endfunction ()
  83
  84 function (gmx_write_installed_header_list)
  85     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  86     string(REPLACE ";" "\n" _list "${_list}")
  87     # TODO: Make this only update the file timestamp if the contents actually change.
  88     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  89 endfunction()
  90
  91 add_subdirectory(gmxlib)
  92 add_subdirectory(mdlib)
  93 add_subdirectory(applied-forces)
  94 add_subdirectory(listed-forces)
  95 add_subdirectory(commandline)
  96 add_subdirectory(domdec)
  97 add_subdirectory(ewald)
  98 add_subdirectory(fft)
  99 add_subdirectory(gpu_utils)
 100 add_subdirectory(hardware)
 101 add_subdirectory(linearalgebra)
 102 add_subdirectory(math)
 103 add_subdirectory(mdrun)
 104 add_subdirectory(mdrunutility)
 105 add_subdirectory(mdtypes)
 106 add_subdirectory(onlinehelp)
 107 add_subdirectory(options)
 108 add_subdirectory(pbcutil)
 109 add_subdirectory(random)
 110 add_subdirectory(tables)
 111 add_subdirectory(taskassignment)
 112 add_subdirectory(timing)
 113 add_subdirectory(topology)
 114 add_subdirectory(trajectory)
 115 add_subdirectory(utility)
 116 add_subdirectory(fileio)
 117 add_subdirectory(swap)
 118 add_subdirectory(essentialdynamics)
 119 add_subdirectory(pulling)
 120 add_subdirectory(awh)
 121 add_subdirectory(simd)
 122 add_subdirectory(imd)
 123 add_subdirectory(compat)
 124 if (NOT GMX_BUILD_MDRUN_ONLY)
 125     add_subdirectory(gmxana)
 126     add_subdirectory(gmxpreprocess)
 127     add_subdirectory(correlationfunctions)
 128     add_subdirectory(statistics)
 129     add_subdirectory(analysisdata)
 130     add_subdirectory(selection)
 131     add_subdirectory(trajectoryanalysis)
 132     add_subdirectory(energyanalysis)
 133     add_subdirectory(tools)
 134 endif()
 135
 136 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 137 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 138
 139 # This would be the standard way to include thread_mpi, but
 140 # we want libgromacs to link the functions directly
 141 #if(GMX_THREAD_MPI)
 142 #    add_subdirectory(thread_mpi)
 143 #endif()
 144 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 145
 146 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 147 target_sources(libgromacs_external PRIVATE ${THREAD_MPI_SOURCES})
 148
 149 configure_file(version.h.cmakein version.h)
 150 gmx_install_headers(
 151     analysisdata.h
 152     commandline.h
 153     options.h
 154     random.h
 155     selection.h
 156     trajectoryanalysis.h
 157     utility.h
 158     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 159     )
 160
 161 # This code is here instead of utility/CMakeLists.txt, because CMake
 162 # custom commands and source file properties can only be set in the directory
 163 # that contains the target that uses them.
 164 # TODO: Generate a header instead that can be included from baseversion.c.
 165 # That probably simplifies things somewhat.
 166 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 167 gmx_configure_version_file(
 168     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 169     REMOTE_HASH)
 170 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE}
 171      $<TARGET_OBJECTS:libgromacs_external>
 172      $<TARGET_OBJECTS:libgromacs_generated>)
 173
 174 # Mark some shared GPU implementation files to compile with CUDA if needed
 175 if (GMX_USE_CUDA)
 176     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 177     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 178 endif()
 179
 180 # set up CUDA compilation with clang
 181 if (GMX_CLANG_CUDA)
 182     foreach (_file ${LIBGROMACS_SOURCES})
 183         get_filename_component(_ext ${_file} EXT)
 184         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 185         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 186             gmx_compile_cuda_file_with_clang(${_file})
 187         endif()
 188     endforeach()
 189 endif()
 190
 191 if (GMX_USE_CUDA)
 192     # Work around FindCUDA that prevents using target_link_libraries()
 193     # with keywords otherwise...
 194     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 195     if (NOT GMX_CLANG_CUDA)
 196         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 197     else()
 198         add_library(libgromacs ${LIBGROMACS_SOURCES})
 199     endif()
 200     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 201 else()
 202     add_library(libgromacs ${LIBGROMACS_SOURCES})
 203 endif()
 204
 205 if (GMX_USE_OPENCL)
 206     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 207     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 208
 209     # Default to using clFFT found on the system
 210     find_package(clFFT)
 211     if (NOT clFFT_FOUND)
 212         if (GMX_EXTERNAL_CLFFT)
 213             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 214         endif()
 215
 216         # Fall back on the internal version
 217         set (_clFFT_dir ../external/clFFT/src)
 218         add_subdirectory(${_clFFT_dir} clFFT-build)
 219         target_sources(libgromacs PRIVATE
 220             $<TARGET_OBJECTS:clFFT>
 221         )
 222         target_include_directories(libgromacs PRIVATE ${_clFFT_dir}/include)
 223         # Use the magic variable for how to link any library needed for
 224         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 225         # (e.g. Windows, BSD, Mac).
 226         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 227     else()
 228         target_link_libraries(libgromacs PRIVATE clFFT)
 229     endif()
 230 endif()
 231
 232 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 233 # is a generated source file. These are awkward to suppress inline, so
 234 # we do it in the compilation command (after testing that the compiler
 235 # supports the suppressions).
 236 include(CheckCXXCompilerFlag)
 237 check_cxx_compiler_flag(-Wno-unused HAS_NO_UNUSED)
 238 if (HAS_NO_UNUSED)
 239     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter -Wno-unused-function")
 240 endif()
 241 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 242
 243 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 244     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 245     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 246     # with the SIMD_AVX_512_CXX_FLAGS flags.
 247     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 248 endif()
 249
 250 gmx_setup_tng_for_libgromacs()
 251
 252 target_link_libraries(libgromacs
 253                       PRIVATE
 254                       ${EXTRAE_LIBRARIES}
 255                       ${GMX_EXTRA_LIBRARIES}
 256                       ${GMX_COMMON_LIBRARIES}
 257                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 258                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 259                       ${OpenCL_LIBRARIES}
 260                       ${GMX_STDLIB_LIBRARIES}
 261                       PUBLIC
 262                       ${GMX_PUBLIC_LIBRARIES}
 263                       )
 264 set_target_properties(libgromacs PROPERTIES
 265                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 266                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 267                       VERSION ${LIBRARY_VERSION}
 268                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 269
 270 gmx_manage_lmfit()
 271 target_link_libraries(libgromacs PRIVATE lmfit)
 272
 273 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^6\.0")
 274    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 275 endif()
 276 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 277    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 278      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 279      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 280      /wd6001  #unitialized memory
 281      /wd6011  #derefencing NULL
 282      /wd6053  #prior call not zero-terminate
 283      /wd6054  #might not be zero-terminated
 284      /wd6385  #reading invalid data
 285      /wd6386  #buffer overrun
 286      /wd6387  #could be '0'
 287      /wd28199 #uninitialized memory
 288      # For compile time constant (e.g. templates) the following warnings have flase postives
 289      /wd6239  #(<non-zero> && <expr>)
 290      /wd6294  #Ill-defined for-loop
 291      /wd6326  #comparison of constant with other constant
 292      /wd28020 #expression involving paramter is not true
 293      # Misc
 294      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 295      /wd6993  #OpenMP ignored
 296      #TODO
 297      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 298      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 299      /wd6246  #hides declaration
 300      >
 301    )
 302 endif()
 303
 304 if (GMX_CLANG_TIDY)
 305    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 306        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 307 endif()
 308
 309 gmx_write_installed_header_list()
 310
 311 # Only install the library in mdrun-only mode if it is actually necessary
 312 # for the binary
 313 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 314     install(TARGETS libgromacs
 315             EXPORT libgromacs
 316             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 317             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 318             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 319             COMPONENT libraries)
 320 endif()
 321
 322 if (NOT GMX_BUILD_MDRUN_ONLY)
 323     include(InstallLibInfo.cmake)
 324 endif()
 325
 326 # Technically, the user could want to do this for an OpenCL build
 327 # using the CUDA runtime, but currently there's no reason to want to
 328 # do that.
 329 if (INSTALL_CUDART_LIB) #can be set manual by user
 330     if (GMX_USE_CUDA)
 331         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 332             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 333             if(IS_CUDART) #libcuda should not be installed
 334                 #install also name-links (linker uses those)
 335                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 336                 install(FILES ${CUDA_LIBS} DESTINATION
 337                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 338             endif()
 339         endforeach()
 340     else()
 341         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 342     endif()
 343 endif()
 344
 345 if(GMX_USE_OPENCL)
 346     set(OPENCL_KERNELS ${MDLIB_OPENCL_KERNELS})
 347
 348     install(FILES ${OPENCL_KERNELS} DESTINATION
 349         ${GMX_INSTALL_OCLDIR} COMPONENT libraries)
 350 endif()