src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 add_subdirectory(gmxlib)
  49 add_subdirectory(mdlib)
  50 add_subdirectory(gmxpreprocess)
  51 add_subdirectory(commandline)
  52 add_subdirectory(fft)
  53 add_subdirectory(linearalgebra)
  54 add_subdirectory(math)
  55 add_subdirectory(random)
  56 add_subdirectory(onlinehelp)
  57 add_subdirectory(options)
  58 add_subdirectory(timing)
  59 add_subdirectory(utility)
  60 add_subdirectory(fileio)
  61 add_subdirectory(swap)
  62 add_subdirectory(essentialdynamics)
  63 add_subdirectory(pulling)
  64 add_subdirectory(simd)
  65 if (NOT GMX_BUILD_MDRUN_ONLY)
  66     add_subdirectory(legacyheaders)
  67     add_subdirectory(gmxana)
  68     add_subdirectory(statistics)
  69     add_subdirectory(analysisdata)
  70     add_subdirectory(selection)
  71     add_subdirectory(trajectoryanalysis)
  72     add_subdirectory(tools)
  73 endif()
  74
  75 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
  76
  77 file(GLOB LIBGROMACS_HEADERS *.h)
  78 configure_file(version.h.cmakein version.h)
  79 gmx_install_headers("" ${LIBGROMACS_HEADERS})
  80 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
  81
  82 # Add target that generates gitversion.c every time make is run
  83 # if git version info is requested
  84 # This code is here instead of utility/CMakeLists.txt because CMake
  85 # ignores set_source_file_properties from subdirectories.
  86 if (GMX_GIT_VERSION_INFO)
  87     set(GENERATED_VERSION_FILE ${CMAKE_CURRENT_BINARY_DIR}/utility/gitversion.c)
  88     add_custom_target(gmx-version ALL
  89             COMMAND ${CMAKE_COMMAND}
  90                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  91                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  92                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  93                 -D VERSION_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein"
  94                 -D VERSION_OUT=${GENERATED_VERSION_FILE}
  95                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  96             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  97             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/utility/gitversion.c.cmakein
  98             COMMENT "Generating git version information")
  99     set_source_files_properties(${GENERATED_VERSION_FILE}
 100                                 PROPERTIES GENERATED true)
 101     list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 102 endif()
 103
 104 # apply gcc 4.4.x bug workaround
 105 if(GMX_USE_GCC44_BUG_WORKAROUND)
 106    include(gmxGCC44O3BugWorkaround)
 107    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 108    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 109    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 110 endif()
 111
 112 add_library(libgromacs ${LIBGROMACS_SOURCES})
 113 if (GMX_GIT_VERSION_INFO)
 114     add_dependencies(libgromacs gmx-version)
 115 endif()
 116
 117 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 118 # is a generated source file. These are awkward to suppress inline, so
 119 # we do it in the compilation command (after testing that the compiler
 120 # supports the suppressions). Setting the properties only works after
 121 # the related target has been created, e.g. after when the file is
 122 # used with add_library().
 123 include(CheckCXXCompilerFlag)
 124 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 125 if (HAS_NO_UNUSED_PARAMETER)
 126     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 127 endif()
 128 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 129 if (HAS_NO_DEPRECATED_REGISTER)
 130     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 131 else()
 132     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 133     if (HAS_NO_DEPRECATED)
 134         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 135     endif()
 136 endif()
 137 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 138
 139 target_link_libraries(libgromacs ${GMX_GPU_LIBRARIES}
 140                       ${GMX_EXTRA_LIBRARIES}
 141                       ${GMX_TNG_LIBRARIES}
 142                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 143                       ${XML_LIBRARIES} ${GSL_LIBRARIES}
 144                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 145 set_target_properties(libgromacs PROPERTIES
 146                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 147                       SOVERSION ${LIBRARY_SOVERSION}
 148                       VERSION ${LIBRARY_VERSION}
 149                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 150
 151 # Only install the library in mdrun-only mode if it is actually necessary
 152 # for the binary
 153 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 154     install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 155 endif()
 156
 157 if (NOT GMX_BUILD_MDRUN_ONLY)
 158     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
 159                    ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
 160     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
 161             DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 162             RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
 163             COMPONENT development)
 164 endif()
 165
 166 if (INSTALL_CUDART_LIB) #can be set manual by user
 167     if (GMX_GPU)
 168         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 169             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 170             if(IS_CUDART) #libcuda should not be installed
 171                 #install also name-links (linker uses those)
 172                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 173                 install(FILES ${CUDA_LIBS} DESTINATION
 174                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 175             endif()
 176         endforeach()
 177     else()
 178         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 179     endif()
 180 endif()