src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  38 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  39
  40 function (_gmx_add_files_to_property PROPERTY)
  41     foreach (_file ${ARGN})
  42         if (IS_ABSOLUTE "${_file}")
  43             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  44         else()
  45             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  46                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  47         endif()
  48     endforeach()
  49 endfunction ()
  50
  51 function (gmx_add_libgromacs_sources)
  52     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  53 endfunction ()
  54
  55 function (gmx_install_headers)
  56     if (NOT GMX_BUILD_MDRUN_ONLY)
  57         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  58         install(FILES       ${ARGN}
  59                 DESTINATION "${INCL_INSTALL_DIR}/${_dest}"
  60                 COMPONENT   development)
  61     endif()
  62     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  63 endfunction ()
  64
  65 function (gmx_write_installed_header_list)
  66     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  67     string(REPLACE ";" "\n" _list "${_list}")
  68     # TODO: Make this only update the file timestamp if the contents actually change.
  69     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  70 endfunction()
  71
  72 add_subdirectory(gmxlib)
  73 add_subdirectory(mdlib)
  74 add_subdirectory(listed-forces)
  75 add_subdirectory(commandline)
  76 add_subdirectory(domdec)
  77 add_subdirectory(ewald)
  78 add_subdirectory(fft)
  79 add_subdirectory(gpu_utils)
  80 add_subdirectory(hardware)
  81 add_subdirectory(linearalgebra)
  82 add_subdirectory(math)
  83 add_subdirectory(mdrunutility)
  84 add_subdirectory(mdtypes)
  85 add_subdirectory(onlinehelp)
  86 add_subdirectory(options)
  87 add_subdirectory(pbcutil)
  88 add_subdirectory(random)
  89 add_subdirectory(tables)
  90 add_subdirectory(timing)
  91 add_subdirectory(topology)
  92 add_subdirectory(trajectory)
  93 add_subdirectory(utility)
  94 add_subdirectory(fileio)
  95 add_subdirectory(swap)
  96 add_subdirectory(essentialdynamics)
  97 add_subdirectory(pulling)
  98 add_subdirectory(simd)
  99 add_subdirectory(imd)
 100 if (NOT GMX_BUILD_MDRUN_ONLY)
 101     add_subdirectory(gmxana)
 102     add_subdirectory(gmxpreprocess)
 103     add_subdirectory(correlationfunctions)
 104     add_subdirectory(statistics)
 105     add_subdirectory(analysisdata)
 106     add_subdirectory(selection)
 107     add_subdirectory(trajectoryanalysis)
 108     add_subdirectory(tools)
 109 endif()
 110
 111 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 112 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 113
 114 # This would be the standard way to include thread_mpi, but
 115 # we want libgromacs to link the functions directly
 116 #if(GMX_THREAD_MPI)
 117 #    add_subdirectory(thread_mpi)
 118 #endif()
 119 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 120
 121 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 122 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 123
 124 if(GMX_USE_TNG)
 125     list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
 126     if (NOT GMX_EXTERNAL_TNG)
 127         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
 128     endif()
 129 endif()
 130
 131 get_lmfit_properties(LMFIT_SOURCES LMFIT_LIBRARIES_TO_LINK LMFIT_INCLUDE_DIRECTORY LMFIT_INCLUDE_DIR_ORDER)
 132 include_directories(${LMFIT_INCLUDE_DIR_ORDER} SYSTEM "${LMFIT_INCLUDE_DIRECTORY}")
 133 list(APPEND LIBGROMACS_SOURCES ${LMFIT_SOURCES})
 134
 135 configure_file(version.h.cmakein version.h)
 136 gmx_install_headers(
 137     analysisdata.h
 138     commandline.h
 139     options.h
 140     random.h
 141     selection.h
 142     trajectoryanalysis.h
 143     utility.h
 144     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 145     )
 146
 147 # This code is here instead of utility/CMakeLists.txt, because CMake
 148 # custom commands and source file properties can only be set in the directory
 149 # that contains the target that uses them.
 150 # TODO: Generate a header instead that can be included from baseversion.c.
 151 # That probably simplifies things somewhat.
 152 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 153 gmx_configure_version_file(
 154     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 155     REMOTE_HASH SOURCE_FILE)
 156 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 157
 158 if (GMX_USE_CUDA)
 159     cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 160 else()
 161     add_library(libgromacs ${LIBGROMACS_SOURCES})
 162 endif()
 163
 164 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 165 # is a generated source file. These are awkward to suppress inline, so
 166 # we do it in the compilation command (after testing that the compiler
 167 # supports the suppressions).
 168 include(CheckCXXCompilerFlag)
 169 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 170 if (HAS_NO_UNUSED_PARAMETER)
 171     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 172 endif()
 173 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 174
 175 target_link_libraries(libgromacs
 176                       ${EXTRAE_LIBRARIES}
 177                       ${GMX_EXTRA_LIBRARIES}
 178                       ${TNG_IO_LIBRARIES}
 179                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 180                       ${XML_LIBRARIES}
 181                       ${LMFIT_LIBRARIES_TO_LINK}
 182                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS} ${OPENCL_LIBRARIES}
 183                       ${GMX_STDLIB_LIBRARIES})
 184 set_target_properties(libgromacs PROPERTIES
 185                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 186                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 187                       VERSION ${LIBRARY_VERSION}
 188                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 189
 190 gmx_write_installed_header_list()
 191
 192 # Only install the library in mdrun-only mode if it is actually necessary
 193 # for the binary
 194 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 195     install(TARGETS libgromacs
 196             EXPORT libgromacs
 197             LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 198             RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 199             ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 200             COMPONENT libraries)
 201 endif()
 202
 203 if (NOT GMX_BUILD_MDRUN_ONLY)
 204     include(InstallLibInfo.cmake)
 205 endif()
 206
 207 # Technically, the user could want to do this for an OpenCL build
 208 # using the CUDA runtime, but currently there's no reason to want to
 209 # do that.
 210 if (INSTALL_CUDART_LIB) #can be set manual by user
 211     if (GMX_USE_CUDA)
 212         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 213             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 214             if(IS_CUDART) #libcuda should not be installed
 215                 #install also name-links (linker uses those)
 216                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 217                 install(FILES ${CUDA_LIBS} DESTINATION
 218                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 219             endif()
 220         endforeach()
 221     else()
 222         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 223     endif()
 224 endif()
 225
 226 if(GMX_USE_OPENCL)
 227     set(OPENCL_KERNELS ${MDLIB_OPENCL_KERNELS})
 228
 229     install(FILES ${OPENCL_KERNELS} DESTINATION
 230         ${OCL_INSTALL_DIR} COMPONENT libraries)
 231 endif()