src/gromacs/CMakeLists.txt

   1 set(LIBGROMACS_SOURCES)
   2
   3 add_subdirectory(legacyheaders)
   4 add_subdirectory(gmxlib)
   5 add_subdirectory(mdlib)
   6 add_subdirectory(gmxpreprocess)
   7 add_subdirectory(analysisdata)
   8 add_subdirectory(commandline)
   9 add_subdirectory(linearalgebra)
  10 add_subdirectory(onlinehelp)
  11 add_subdirectory(options)
  12 add_subdirectory(selection)
  13 add_subdirectory(trajectoryanalysis)
  14 add_subdirectory(utility)
  15
  16 file(GLOB LIBGROMACS_HEADERS *.h)
  17 install(FILES ${LIBGROMACS_HEADERS} DESTINATION ${INCL_INSTALL_DIR}/gromacs
  18         COMPONENT development)
  19
  20 # only fiddle with assembly kernels if we're not doing OpenMM build
  21 if(GMX_SSEKERNEL_ASM_SRC AND NOT GMX_OPENMM)
  22 if(GMX_ASM_USEASM_NASM)
  23   enable_language(ASM_NASM)
  24   # if NASM is used, we need a special build command for windows...
  25   FOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
  26     GET_FILENAME_COMPONENT(FILE_BASE ${SRC} NAME_WE)
  27     SET(OBJ ${CMAKE_CURRENT_BINARY_DIR}/${FILE_BASE}${CMAKE_C_OUTPUT_EXTENSION})
  28
  29     ADD_CUSTOM_COMMAND(OUTPUT ${OBJ}
  30                        MAIN_DEPENDENCY ${SRC}
  31                        COMMAND ${CMAKE_ASM_NASM_COMPILER} -f ${CMAKE_ASM_NASM_OBJECT_FORMAT} -o ${OBJ} ${SRC})
  32
  33     SET(ALL_ASM_OBJS ${ALL_ASM_OBJS} ${OBJ})
  34   ENDFOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
  35   set(GMX_SSEKERNEL_ASM_SRC ${ALL_ASM_OBJS})
  36 else(GMX_ASM_USEASM_NASM)
  37   enable_language(ASM-ATT)
  38   SET(CMAKE_ASM-ATT_COMPILER ${CMAKE_C_COMPILER})
  39   if(GMX_IA32_ASM)
  40     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m32")
  41   else()
  42     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m64")
  43   endif()
  44 endif(GMX_ASM_USEASM_NASM)
  45 endif(GMX_SSEKERNEL_ASM_SRC AND NOT GMX_OPENMM)
  46
  47 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${GMX_SSEKERNEL_ASM_SRC} ${MDLIB_SOURCES})
  48
  49 # add target that generates version.c every time a make is run
  50 # only do this if we generate the version
  51 if (USE_VERSION_H)
  52     add_custom_target(gmx_version ALL
  53             COMMAND ${CMAKE_COMMAND}
  54                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  55                 -D GIT_VERSION="${GIT_VERSION}"
  56                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  57                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  58                 -D VERSION_C_CMAKEIN="${CMAKE_CURRENT_SOURCE_DIR}/version.c.cmakein"
  59                 -D VERSION_C_OUT="${CMAKE_CURRENT_BINARY_DIR}/version.c"
  60                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  61             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src/gmxlib
  62             DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/version.c.cmakein
  63             COMMENT "Generating version information")
  64     list(APPEND LIBGROMACS_SOURCES ${CMAKE_CURRENT_BINARY_DIR}/version.c) # auto-generated
  65     set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/version.c
  66                                 PROPERTIES GENERATED true)
  67 endif (USE_VERSION_H)
  68
  69 add_library(libgromacs ${LIBGROMACS_SOURCES})
  70 if (USE_VERSION_H)
  71     add_dependencies(libgromacs gmx_version)
  72 endif (USE_VERSION_H)
  73 target_link_libraries(libgromacs
  74                       ${GMX_EXTRA_LIBRARIES} ${FFT_LIBRARIES} ${XML_LIBRARIES}
  75                       ${THREAD_LIB})
  76 set_target_properties(libgromacs PROPERTIES
  77                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
  78                       SOVERSION ${SOVERSION}
  79                       INSTALL_NAME_DIR "${LIB_INSTALL_DIR}")
  80
  81 install(TARGETS libgromacs DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
  82
  83 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgromacs.pc.cmakein
  84                ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc @ONLY)
  85 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgromacs.pc
  86         DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
  87         RENAME "libgromacs${GMX_LIBS_SUFFIX}.pc"
  88         COMPONENT development)