src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY CUDA_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # Permit the configuration to disable compiling the many nbnxm kernels
  64 # and others involved in force calculations. Currently only
  65 # short-ranged and bonded kernels are disabled this way, but in future
  66 # others may be appropriate. Thus the cmake option is not specific to
  67 # nbnxm module.
  68 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  69 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  70
  71 # Add these contents first because linking their tests can take a lot
  72 # of time, so we want lots of parallel work still available after
  73 # linking starts.
  74 add_subdirectory(utility)
  75 # Add normal contents
  76 add_subdirectory(gmxlib)
  77 add_subdirectory(mdlib)
  78 add_subdirectory(applied_forces)
  79 add_subdirectory(listed_forces)
  80 add_subdirectory(nbnxm)
  81 add_subdirectory(commandline)
  82 add_subdirectory(domdec)
  83 add_subdirectory(ewald)
  84 add_subdirectory(fft)
  85 add_subdirectory(gpu_utils)
  86 add_subdirectory(hardware)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(mdrun)
  90 add_subdirectory(mdrunutility)
  91 add_subdirectory(mdspan)
  92 add_subdirectory(mdtypes)
  93 add_subdirectory(onlinehelp)
  94 add_subdirectory(options)
  95 add_subdirectory(pbcutil)
  96 add_subdirectory(random)
  97 add_subdirectory(restraint)
  98 add_subdirectory(tables)
  99 add_subdirectory(taskassignment)
 100 add_subdirectory(timing)
 101 add_subdirectory(topology)
 102 add_subdirectory(trajectory)
 103 add_subdirectory(swap)
 104 add_subdirectory(essentialdynamics)
 105 add_subdirectory(pulling)
 106 add_subdirectory(simd)
 107 add_subdirectory(imd)
 108 add_subdirectory(compat)
 109 add_subdirectory(mimic)
 110 add_subdirectory(modularsimulator)
 111 if (NOT GMX_BUILD_MDRUN_ONLY)
 112     add_subdirectory(gmxana)
 113     add_subdirectory(gmxpreprocess)
 114     add_subdirectory(correlationfunctions)
 115     add_subdirectory(statistics)
 116     add_subdirectory(analysisdata)
 117     add_subdirectory(coordinateio)
 118     add_subdirectory(trajectoryanalysis)
 119     add_subdirectory(energyanalysis)
 120     add_subdirectory(tools)
 121 endif()
 122
 123 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 124 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 125
 126 # This would be the standard way to include thread_mpi, but
 127 # we want libgromacs to link the functions directly
 128 #if(GMX_THREAD_MPI)
 129 #    add_subdirectory(thread_mpi)
 130 #endif()
 131 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 132 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 133 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 134 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 135 if(CYGWIN)
 136     # Needs POSIX-isms for strdup, not just std-isms
 137     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 138 endif()
 139 gmx_target_compile_options(thread_mpi)
 140 if (WIN32)
 141     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 142 endif()
 143 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 144
 145 if(GMX_INSTALL_LEGACY_API)
 146   install(FILES
 147           analysisdata.h
 148           options.h
 149           selection.h
 150           trajectoryanalysis.h
 151           DESTINATION include/gromacs)
 152 endif()
 153
 154 # This code is here instead of utility/CMakeLists.txt, because CMake
 155 # custom commands and source file properties can only be set in the directory
 156 # that contains the target that uses them.
 157 # TODO: Generate a header instead that can be included from baseversion.cpp.
 158 # That probably simplifies things somewhat.
 159 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 160 gmx_configure_version_file(
 161     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 162     REMOTE_HASH
 163     EXTRA_VARS
 164         GMX_SOURCE_DOI
 165         GMX_RELEASE_HASH
 166         GMX_SOURCE_HASH
 167         )
 168 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 169
 170 # Mark some shared GPU implementation files to compile with CUDA if needed
 171 if (GMX_GPU_CUDA)
 172     get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 173     set_source_files_properties(${CUDA_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 174 endif()
 175
 176 if (GMX_GPU_CUDA)
 177     # Work around FindCUDA that prevents using target_link_libraries()
 178     # with keywords otherwise...
 179     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 180     if (NOT GMX_CLANG_CUDA)
 181         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 182     else()
 183         add_library(libgromacs ${LIBGROMACS_SOURCES})
 184     endif()
 185     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 186 else()
 187     add_library(libgromacs ${LIBGROMACS_SOURCES})
 188 endif()
 189
 190 # Add these contents first because linking their tests can take a lot
 191 # of time, so we want lots of parallel work still available after
 192 # linking starts.
 193 add_subdirectory(fileio)
 194 add_subdirectory(selection)
 195
 196 # Suppress a warning about our abuse of t_inputrec
 197 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 198
 199 # Handle the object libraries that contain the source file
 200 # dependencies that need special handling because they are generated
 201 # or external code.
 202 foreach(object_library ${libgromacs_object_library_dependencies})
 203     if (BUILD_SHARED_LIBS)
 204         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 205     endif()
 206     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 207
 208     # Add the sources from the object libraries to the main library.
 209     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 210 endforeach()
 211 gmx_target_compile_options(libgromacs)
 212 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 213 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 214
 215 if (GMX_GPU_OPENCL)
 216     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 217     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 218
 219     # Default to using clFFT found on the system
 220     # switch to quiet at the second run.
 221     if (DEFINED clFFT_LIBRARY)
 222         set (clFFT_FIND_QUIETLY TRUE)
 223     endif()
 224     find_package(clFFT)
 225     if (NOT clFFT_FOUND)
 226         if (GMX_EXTERNAL_CLFFT)
 227             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 228         endif()
 229
 230         if(MSVC)
 231             message(FATAL_ERROR
 232 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 233 requires clFFT, which was not found on your system. GROMACS does bundle
 234 clFFT to help with building for OpenCL, but that clFFT has not yet been
 235 ported to the more recent versions of that compiler that GROMACS itself
 236 requires. Thus for now, OpenCL is not available with MSVC and the internal
 237 build of clFFT in GROMACS 2019. Either change compiler, try installing
 238 a clFFT package, or use the latest GROMACS 2018 point release.")
 239         endif()
 240
 241         # Fall back on the internal version
 242         set (_clFFT_dir ../external/clFFT/src)
 243         add_subdirectory(${_clFFT_dir} clFFT-build)
 244         target_sources(libgromacs PRIVATE
 245             $<TARGET_OBJECTS:clFFT>
 246         )
 247         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 248         # Use the magic variable for how to link any library needed for
 249         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 250         # (e.g. Windows, BSD, Mac).
 251         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 252     else()
 253         target_link_libraries(libgromacs PRIVATE clFFT)
 254     endif()
 255 endif()
 256
 257 # Permit GROMACS code to include externally developed headers, such as
 258 # the functionality from the nonstd project that we use for
 259 # gmx::compat::optional. These are included as system headers so that
 260 # no warnings are issued from them.
 261 #
 262 # TODO Perhaps generalize this for all headers from src/external
 263 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 264
 265 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 266     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 267     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 268     # with the SIMD_AVX_512_CXX_FLAGS flags.
 269     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 270 endif()
 271
 272 # Do any special handling needed for .cpp files that use
 273 # CUDA runtime headers
 274 if (GMX_GPU_CUDA AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 275     # CUDA header cuda_runtime_api.h in at least CUDA 10.1 uses 0
 276     # where nullptr would be preferable. GROMACS can't fix these, so
 277     # must suppress them.
 278     GMX_TEST_CXXFLAG(CXXFLAGS_NO_ZERO_AS_NULL_POINTER_CONSTANT "-Wno-zero-as-null-pointer-constant" NVCC_CLANG_SUPPRESSIONS_CXXFLAGS)
 279
 280     foreach(_compile_flag ${NVCC_CLANG_SUPPRESSIONS_CXXFLAGS})
 281         set(GMX_CUDA_CLANG_FLAGS "${GMX_CUDA_CLANG_FLAGS} ${_compile_flag}")
 282     endforeach()
 283     if (GMX_CLANG_CUDA)
 284         foreach (_file ${LIBGROMACS_SOURCES})
 285             get_filename_component(_ext ${_file} EXT)
 286             get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 287             if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 288                 gmx_compile_cuda_file_with_clang(${_file})
 289             endif()
 290         endforeach()
 291     else()
 292         get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 293         set_source_files_properties(${CUDA_SOURCES} PROPERTIES COMPILE_FLAGS ${GMX_CUDA_CLANG_FLAGS})
 294     endif()
 295 endif()
 296
 297 # Only add the -fsycl flag to sources that really need it
 298 if (GMX_GPU_SYCL)
 299     get_property(SYCL_SOURCES GLOBAL PROPERTY SYCL_SOURCES)
 300     set_source_files_properties(${SYCL_SOURCES} PROPERTIES COMPILE_FLAGS "${SYCL_CXX_FLAGS}")
 301 endif()
 302
 303 gmx_setup_tng_for_libgromacs()
 304
 305 # We apply the SYCL flag explicitly just for libgromacs, since bugs in the beta versions of
 306 # icpx/dpcpp leads to crashes if we try to link an library without any SYCL code with the
 307 # -fsycl flag enabled. Once that bug is fixed, we should change it to simply add
 308 # SYCL_CXX_FLAGS to GMX_SHARED_LINKER_FLAGS.
 309 target_link_libraries(libgromacs
 310                       PRIVATE
 311                       ${EXTRAE_LIBRARIES}
 312                       ${GMX_EXTRA_LIBRARIES}
 313                       ${GMX_COMMON_LIBRARIES}
 314                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 315                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 316                       ${SYCL_CXX_FLAGS}
 317                       ${OpenCL_LIBRARIES}
 318                       $<$<PLATFORM_ID:SunOS>:socket>
 319                       PUBLIC
 320                       ${GMX_PUBLIC_LIBRARIES}
 321                       )
 322 target_link_libraries(libgromacs PUBLIC legacy_api)
 323
 324 if (GMX_OPENMP)
 325     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 326 endif()
 327 set_target_properties(libgromacs PROPERTIES
 328                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 329                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 330                       VERSION ${LIBRARY_VERSION}
 331                       )
 332
 333 gmx_manage_lmfit()
 334 target_link_libraries(libgromacs PRIVATE lmfit)
 335
 336 # Make sure we fix "everything" found by more recent versions of clang.
 337 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 338    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 339 endif()
 340 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 341    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 342      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 343      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 344      /wd6001  #unitialized memory
 345      /wd6011  #derefencing NULL
 346      /wd6053  #prior call not zero-terminate
 347      /wd6054  #might not be zero-terminated
 348      /wd6385  #reading invalid data
 349      /wd6386  #buffer overrun
 350      /wd6387  #could be '0'
 351      /wd28199 #uninitialized memory
 352      # For compile time constant (e.g. templates) the following warnings have flase postives
 353      /wd6239  #(<non-zero> && <expr>)
 354      /wd6240  #(<expr> && <non-zero>)
 355      /wd6294  #Ill-defined for-loop
 356      /wd6326  #comparison of constant with other constant
 357      /wd28020 #expression involving paramter is not true
 358      # Misc
 359      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 360      /wd6993  #OpenMP ignored
 361      #TODO
 362      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 363      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 364      /wd6246  #hides declaration
 365      >
 366    )
 367 endif()
 368
 369 if (GMX_CLANG_TIDY)
 370    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 371        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 372 endif()
 373
 374 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 375 # and we know they are not real issues. So we only check that it can compile without error
 376 # but ignore all warnings.
 377 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 378     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 379 endif()
 380
 381 # Only install the library in mdrun-only mode if it is actually necessary
 382 # for the binary
 383 # TODO: Stop installing libgromacs. Possibly allow installation during deprecation period with GMX_INSTALL_LEGACY_API.
 384 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 385     install(TARGETS libgromacs
 386             EXPORT libgromacs
 387             LIBRARY
 388                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 389                 COMPONENT libraries
 390             RUNTIME
 391                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 392                 COMPONENT libraries
 393             ARCHIVE
 394                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 395                 COMPONENT libraries
 396             INCLUDES DESTINATION include)
 397     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 398     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 399     if(GMX_INSTALL_LEGACY_API)
 400         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 401     endif()
 402 endif()
 403 add_library(Gromacs::libgromacs ALIAS libgromacs)
 404
 405 if (NOT GMX_BUILD_MDRUN_ONLY)
 406     include(InstallLibInfo.cmake)
 407 endif()
 408
 409 # Technically, the user could want to do this for an OpenCL build
 410 # using the CUDA runtime, but currently there's no reason to want to
 411 # do that.
 412 if (INSTALL_CUDART_LIB) #can be set manual by user
 413     if (GMX_GPU_CUDA)
 414         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 415             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 416             if(IS_CUDART) #libcuda should not be installed
 417                 #install also name-links (linker uses those)
 418                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 419                 install(FILES ${CUDA_LIBS} DESTINATION
 420                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 421             endif()
 422         endforeach()
 423     else()
 424         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 425     endif()
 426 endif()
 427
 428 if(GMX_GPU_OPENCL)
 429     # Install the utility headers
 430     file(GLOB OPENCL_INSTALLED_FILES
 431         gpu_utils/vectype_ops.clh
 432         gpu_utils/device_utils.clh
 433         )
 434     install(FILES ${OPENCL_INSTALLED_FILES}
 435         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 436         COMPONENT libraries)
 437     file(GLOB OPENCL_INSTALLED_FILES
 438         pbcutil/ishift.h
 439         )
 440     install(FILES ${OPENCL_INSTALLED_FILES}
 441         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 442         COMPONENT libraries)
 443
 444     # Install the NBNXM source and headers
 445     file(GLOB OPENCL_INSTALLED_FILES
 446         nbnxm/constants.h
 447         )
 448     install(FILES ${OPENCL_INSTALLED_FILES}
 449         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 450         COMPONENT libraries)
 451     file(GLOB OPENCL_INSTALLED_FILES
 452         nbnxm/opencl/nbnxm_ocl_kernels.cl
 453         nbnxm/opencl/nbnxm_ocl_kernel.clh
 454         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 455         nbnxm/opencl/nbnxm_ocl_kernels.clh
 456         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 457         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 458         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 459         nbnxm/opencl/nbnxm_ocl_consts.h
 460         )
 461     install(FILES ${OPENCL_INSTALLED_FILES}
 462         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 463         COMPONENT libraries)
 464
 465     # Install the PME source and headers
 466     file(GLOB OPENCL_INSTALLED_FILES
 467         ewald/pme_spread.clh
 468         ewald/pme_solve.clh
 469         ewald/pme_gather.clh
 470         ewald/pme_gpu_calculate_splines.clh
 471         ewald/pme_program.cl
 472         ewald/pme_gpu_types.h
 473         )
 474     install(FILES ${OPENCL_INSTALLED_FILES}
 475         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 476         COMPONENT libraries)
 477 endif()