src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 add_library(libgromacs_external OBJECT "")
  47 add_library(libgromacs_generated OBJECT "")
  48 if (BUILD_SHARED_LIBS)
  49     set_target_properties(libgromacs_external PROPERTIES POSITION_INDEPENDENT_CODE true)
  50     set_target_properties(libgromacs_generated PROPERTIES POSITION_INDEPENDENT_CODE true)
  51 endif()
  52
  53 function (_gmx_add_files_to_property PROPERTY)
  54     foreach (_file ${ARGN})
  55         if (IS_ABSOLUTE "${_file}")
  56             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  57         else()
  58             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  59                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  60         endif()
  61     endforeach()
  62 endfunction ()
  63
  64 function (gmx_add_libgromacs_sources)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  69 # approach, at least for the build system. See Redmine #2530
  70 function (gmx_compile_cpp_as_cuda)
  71     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  72 endfunction ()
  73
  74 function (gmx_install_headers)
  75     if (NOT GMX_BUILD_MDRUN_ONLY)
  76         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  77         install(FILES       ${ARGN}
  78                 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${_dest}"
  79                 COMPONENT   development)
  80     endif()
  81     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  82 endfunction ()
  83
  84 function (gmx_write_installed_header_list)
  85     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  86     string(REPLACE ";" "\n" _list "${_list}")
  87     # TODO: Make this only update the file timestamp if the contents actually change.
  88     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  89 endfunction()
  90
  91 add_subdirectory(gmxlib)
  92 add_subdirectory(mdlib)
  93 add_subdirectory(applied-forces)
  94 add_subdirectory(listed-forces)
  95 add_subdirectory(commandline)
  96 add_subdirectory(domdec)
  97 add_subdirectory(ewald)
  98 add_subdirectory(fft)
  99 add_subdirectory(gpu_utils)
 100 add_subdirectory(hardware)
 101 add_subdirectory(linearalgebra)
 102 add_subdirectory(math)
 103 add_subdirectory(mdrun)
 104 add_subdirectory(mdrunutility)
 105 add_subdirectory(mdtypes)
 106 add_subdirectory(onlinehelp)
 107 add_subdirectory(options)
 108 add_subdirectory(pbcutil)
 109 add_subdirectory(random)
 110 add_subdirectory(tables)
 111 add_subdirectory(taskassignment)
 112 add_subdirectory(timing)
 113 add_subdirectory(topology)
 114 add_subdirectory(trajectory)
 115 add_subdirectory(utility)
 116 add_subdirectory(fileio)
 117 add_subdirectory(swap)
 118 add_subdirectory(essentialdynamics)
 119 add_subdirectory(pulling)
 120 add_subdirectory(awh)
 121 add_subdirectory(simd)
 122 add_subdirectory(imd)
 123 add_subdirectory(compat)
 124 if (NOT GMX_BUILD_MDRUN_ONLY)
 125     add_subdirectory(gmxana)
 126     add_subdirectory(gmxpreprocess)
 127     add_subdirectory(correlationfunctions)
 128     add_subdirectory(statistics)
 129     add_subdirectory(analysisdata)
 130     add_subdirectory(selection)
 131     add_subdirectory(trajectoryanalysis)
 132     add_subdirectory(energyanalysis)
 133     add_subdirectory(tools)
 134 endif()
 135
 136 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 137 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 138
 139 # This would be the standard way to include thread_mpi, but
 140 # we want libgromacs to link the functions directly
 141 #if(GMX_THREAD_MPI)
 142 #    add_subdirectory(thread_mpi)
 143 #endif()
 144 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 145
 146 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 147 target_sources(libgromacs_external PRIVATE ${THREAD_MPI_SOURCES})
 148
 149 configure_file(version.h.cmakein version.h)
 150 gmx_install_headers(
 151     analysisdata.h
 152     commandline.h
 153     options.h
 154     random.h
 155     selection.h
 156     trajectoryanalysis.h
 157     utility.h
 158     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 159     )
 160
 161 # This code is here instead of utility/CMakeLists.txt, because CMake
 162 # custom commands and source file properties can only be set in the directory
 163 # that contains the target that uses them.
 164 # TODO: Generate a header instead that can be included from baseversion.c.
 165 # That probably simplifies things somewhat.
 166 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 167 gmx_configure_version_file(
 168     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 169     REMOTE_HASH)
 170 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE}
 171      $<TARGET_OBJECTS:libgromacs_external>
 172      $<TARGET_OBJECTS:libgromacs_generated>)
 173
 174 # Mark some shared GPU implementation files to compile with CUDA if needed
 175 if (GMX_USE_CUDA)
 176     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 177     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 178 endif()
 179
 180 # set up CUDA compilation with clang
 181 if (GMX_CLANG_CUDA)
 182     foreach (_file ${LIBGROMACS_SOURCES})
 183         get_filename_component(_ext ${_file} EXT)
 184         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 185         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 186             gmx_compile_cuda_file_with_clang(${_file})
 187         endif()
 188     endforeach()
 189 endif()
 190
 191 if (GMX_USE_CUDA)
 192     # Work around FindCUDA that prevents using target_link_libraries()
 193     # with keywords otherwise...
 194     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 195     if (NOT GMX_CLANG_CUDA)
 196         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 197     else()
 198         add_library(libgromacs ${LIBGROMACS_SOURCES})
 199     endif()
 200     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 201 else()
 202     add_library(libgromacs ${LIBGROMACS_SOURCES})
 203 endif()
 204
 205 if (GMX_USE_OPENCL)
 206     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 207     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 208
 209     # Default to using clFFT found on the system
 210     # switch to quiet at the second run.
 211     if (DEFINED clFFT_LIBRARY)
 212         set (clFFT_FIND_QUIETLY TRUE)
 213     endif()
 214     find_package(clFFT)
 215     if (NOT clFFT_FOUND)
 216         if (GMX_EXTERNAL_CLFFT)
 217             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 218         endif()
 219
 220         # Fall back on the internal version
 221         set (_clFFT_dir ../external/clFFT/src)
 222         add_subdirectory(${_clFFT_dir} clFFT-build)
 223         target_sources(libgromacs PRIVATE
 224             $<TARGET_OBJECTS:clFFT>
 225         )
 226         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 227         # Use the magic variable for how to link any library needed for
 228         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 229         # (e.g. Windows, BSD, Mac).
 230         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 231     else()
 232         target_link_libraries(libgromacs PRIVATE clFFT)
 233     endif()
 234 endif()
 235
 236 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 237 # is a generated source file. These are awkward to suppress inline, so
 238 # we do it in the compilation command (after testing that the compiler
 239 # supports the suppressions). Same issue exists for nonbonded kernels
 240 # so we supress them for all generated files.
 241 include(CheckCXXCompilerFlag)
 242 check_cxx_compiler_flag("-Wno-unused -Wno-unused-parameter" HAS_NO_UNUSED)
 243 check_cxx_compiler_flag(-Wno-missing-declarations HAS_NO_MISSING_DECL)
 244 check_cxx_compiler_flag(-Wno-missing-prototypes HAS_NO_MISSING_PROTO)
 245 check_cxx_compiler_flag(/wd4101 HAS_NO_MSVC_UNUSED)
 246 check_cxx_compiler_flag(-wd1419 HAS_DECL_IN_SOURCE)
 247 if (HAS_NO_UNUSED)
 248     target_compile_options(libgromacs_generated PRIVATE "-Wno-unused;-Wno-unused-parameter")
 249 endif()
 250 if (HAS_NO_MISSING_DECL)
 251     target_compile_options(libgromacs_generated PRIVATE "-Wno-missing-declarations")
 252 endif()
 253 if (HAS_NO_MISSING_PROTO)
 254     target_compile_options(libgromacs_generated PRIVATE "-Wno-missing-prototypes")
 255 endif()
 256 if (HAS_NO_MSVC_UNUSED)
 257     target_compile_options(libgromacs_generated PRIVATE "/wd4101")
 258 endif()
 259 if (HAS_DECL_IN_SOURCE)
 260     target_compile_options(libgromacs_generated PRIVATE "-wd1419")
 261 endif()
 262
 263 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 264     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 265     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 266     # with the SIMD_AVX_512_CXX_FLAGS flags.
 267     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 268 endif()
 269
 270 gmx_setup_tng_for_libgromacs()
 271
 272 target_link_libraries(libgromacs
 273                       PRIVATE
 274                       ${EXTRAE_LIBRARIES}
 275                       ${GMX_EXTRA_LIBRARIES}
 276                       ${GMX_COMMON_LIBRARIES}
 277                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 278                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 279                       ${OpenCL_LIBRARIES}
 280                       ${GMX_STDLIB_LIBRARIES}
 281                       PUBLIC
 282                       ${GMX_PUBLIC_LIBRARIES}
 283                       )
 284 set_target_properties(libgromacs PROPERTIES
 285                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 286                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 287                       VERSION ${LIBRARY_VERSION}
 288                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 289
 290 gmx_manage_lmfit()
 291 target_link_libraries(libgromacs PRIVATE lmfit)
 292
 293 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^6\.0")
 294    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 295 endif()
 296 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 297    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 298      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 299      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 300      /wd6001  #unitialized memory
 301      /wd6011  #derefencing NULL
 302      /wd6053  #prior call not zero-terminate
 303      /wd6054  #might not be zero-terminated
 304      /wd6385  #reading invalid data
 305      /wd6386  #buffer overrun
 306      /wd6387  #could be '0'
 307      /wd28199 #uninitialized memory
 308      # For compile time constant (e.g. templates) the following warnings have flase postives
 309      /wd6239  #(<non-zero> && <expr>)
 310      /wd6294  #Ill-defined for-loop
 311      /wd6326  #comparison of constant with other constant
 312      /wd28020 #expression involving paramter is not true
 313      # Misc
 314      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 315      /wd6993  #OpenMP ignored
 316      #TODO
 317      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 318      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 319      /wd6246  #hides declaration
 320      >
 321    )
 322 endif()
 323
 324 if (GMX_CLANG_TIDY)
 325    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 326        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 327 endif()
 328
 329 gmx_write_installed_header_list()
 330
 331 # Only install the library in mdrun-only mode if it is actually necessary
 332 # for the binary
 333 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 334     install(TARGETS libgromacs
 335             EXPORT libgromacs
 336             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 337             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 338             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 339             COMPONENT libraries)
 340 endif()
 341
 342 if (NOT GMX_BUILD_MDRUN_ONLY)
 343     include(InstallLibInfo.cmake)
 344 endif()
 345
 346 # Technically, the user could want to do this for an OpenCL build
 347 # using the CUDA runtime, but currently there's no reason to want to
 348 # do that.
 349 if (INSTALL_CUDART_LIB) #can be set manual by user
 350     if (GMX_USE_CUDA)
 351         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 352             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 353             if(IS_CUDART) #libcuda should not be installed
 354                 #install also name-links (linker uses those)
 355                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 356                 install(FILES ${CUDA_LIBS} DESTINATION
 357                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 358             endif()
 359         endforeach()
 360     else()
 361         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 362     endif()
 363 endif()
 364
 365 if(GMX_USE_OPENCL)
 366     set(OPENCL_KERNELS ${MDLIB_OPENCL_KERNELS})
 367
 368     install(FILES ${OPENCL_KERNELS} DESTINATION
 369         ${GMX_INSTALL_OCLDIR} COMPONENT libraries)
 370 endif()