src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 add_library(libgromacs_external OBJECT "")
  47 if(CMAKE_COMPILER_IS_GNUCXX)
  48     # Keep quiet about e.g. linearalgebra module
  49     target_compile_options(libgromacs_external PRIVATE ${CXXFLAGS_NO_STRINGOP_TRUNCATION})
  50 endif()
  51
  52 add_library(libgromacs_generated OBJECT "")
  53 if (BUILD_SHARED_LIBS)
  54     set_target_properties(libgromacs_external PROPERTIES POSITION_INDEPENDENT_CODE true)
  55     set_target_properties(libgromacs_generated PROPERTIES POSITION_INDEPENDENT_CODE true)
  56 endif()
  57
  58 function (_gmx_add_files_to_property PROPERTY)
  59     foreach (_file ${ARGN})
  60         if (IS_ABSOLUTE "${_file}")
  61             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  62         else()
  63             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  64                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  65         endif()
  66     endforeach()
  67 endfunction ()
  68
  69 function (gmx_add_libgromacs_sources)
  70     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  71 endfunction ()
  72
  73 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  74 # approach, at least for the build system. See Redmine #2530
  75 function (gmx_compile_cpp_as_cuda)
  76     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  77 endfunction ()
  78
  79 function (gmx_install_headers)
  80     if (NOT GMX_BUILD_MDRUN_ONLY)
  81         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  82         install(FILES       ${ARGN}
  83                 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${_dest}"
  84                 COMPONENT   development)
  85     endif()
  86     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  87 endfunction ()
  88
  89 function (gmx_write_installed_header_list)
  90     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  91     string(REPLACE ";" "\n" _list "${_list}")
  92     # TODO: Make this only update the file timestamp if the contents actually change.
  93     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  94 endfunction()
  95
  96 add_subdirectory(gmxlib)
  97 add_subdirectory(mdlib)
  98 add_subdirectory(applied-forces)
  99 add_subdirectory(listed-forces)
 100 add_subdirectory(commandline)
 101 add_subdirectory(domdec)
 102 add_subdirectory(ewald)
 103 add_subdirectory(fft)
 104 add_subdirectory(gpu_utils)
 105 add_subdirectory(hardware)
 106 add_subdirectory(linearalgebra)
 107 add_subdirectory(math)
 108 add_subdirectory(mdrun)
 109 add_subdirectory(mdrunutility)
 110 add_subdirectory(mdspan)
 111 add_subdirectory(mdtypes)
 112 add_subdirectory(onlinehelp)
 113 add_subdirectory(options)
 114 add_subdirectory(pbcutil)
 115 add_subdirectory(random)
 116 add_subdirectory(restraint)
 117 add_subdirectory(tables)
 118 add_subdirectory(taskassignment)
 119 add_subdirectory(timing)
 120 add_subdirectory(topology)
 121 add_subdirectory(trajectory)
 122 add_subdirectory(utility)
 123 add_subdirectory(fileio)
 124 add_subdirectory(swap)
 125 add_subdirectory(essentialdynamics)
 126 add_subdirectory(pulling)
 127 add_subdirectory(awh)
 128 add_subdirectory(simd)
 129 add_subdirectory(imd)
 130 add_subdirectory(compat)
 131 add_subdirectory(mimic)
 132 if (NOT GMX_BUILD_MDRUN_ONLY)
 133     add_subdirectory(gmxana)
 134     add_subdirectory(gmxpreprocess)
 135     add_subdirectory(correlationfunctions)
 136     add_subdirectory(statistics)
 137     add_subdirectory(analysisdata)
 138     add_subdirectory(selection)
 139     add_subdirectory(trajectoryanalysis)
 140     add_subdirectory(energyanalysis)
 141     add_subdirectory(tools)
 142 endif()
 143
 144 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 145 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 146
 147 # This would be the standard way to include thread_mpi, but
 148 # we want libgromacs to link the functions directly
 149 #if(GMX_THREAD_MPI)
 150 #    add_subdirectory(thread_mpi)
 151 #endif()
 152 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 153
 154 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 155 target_sources(libgromacs_external PRIVATE ${THREAD_MPI_SOURCES})
 156
 157 configure_file(version.h.cmakein version.h)
 158 gmx_install_headers(
 159     analysisdata.h
 160     commandline.h
 161     options.h
 162     random.h
 163     selection.h
 164     trajectoryanalysis.h
 165     utility.h
 166     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 167     )
 168
 169 # This code is here instead of utility/CMakeLists.txt, because CMake
 170 # custom commands and source file properties can only be set in the directory
 171 # that contains the target that uses them.
 172 # TODO: Generate a header instead that can be included from baseversion.c.
 173 # That probably simplifies things somewhat.
 174 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 175 gmx_configure_version_file(
 176     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 177     REMOTE_HASH
 178     EXTRA_VARS
 179         GMX_SOURCE_DOI
 180     )
 181 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE}
 182      $<TARGET_OBJECTS:libgromacs_external>
 183      $<TARGET_OBJECTS:libgromacs_generated>)
 184
 185 # Mark some shared GPU implementation files to compile with CUDA if needed
 186 if (GMX_USE_CUDA)
 187     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 188     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 189 endif()
 190
 191 # set up CUDA compilation with clang
 192 if (GMX_CLANG_CUDA)
 193     foreach (_file ${LIBGROMACS_SOURCES})
 194         get_filename_component(_ext ${_file} EXT)
 195         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 196         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 197             gmx_compile_cuda_file_with_clang(${_file})
 198         endif()
 199     endforeach()
 200 endif()
 201
 202 if (GMX_USE_CUDA)
 203     # Work around FindCUDA that prevents using target_link_libraries()
 204     # with keywords otherwise...
 205     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 206     if (NOT GMX_CLANG_CUDA)
 207         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 208     else()
 209         add_library(libgromacs ${LIBGROMACS_SOURCES})
 210     endif()
 211     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 212 else()
 213     add_library(libgromacs ${LIBGROMACS_SOURCES})
 214 endif()
 215
 216 if (GMX_USE_OPENCL)
 217     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 218     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 219
 220     # Default to using clFFT found on the system
 221     # switch to quiet at the second run.
 222     if (DEFINED clFFT_LIBRARY)
 223         set (clFFT_FIND_QUIETLY TRUE)
 224     endif()
 225     find_package(clFFT)
 226     if (NOT clFFT_FOUND)
 227         if (GMX_EXTERNAL_CLFFT)
 228             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 229         endif()
 230
 231         if(MSVC)
 232             message(FATAL_ERROR
 233 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 234 requires clFFT, which was not found on your system. GROMACS does bundle
 235 clFFT to help with building for OpenCL, but that clFFT has not yet been
 236 ported to the more recent versions of that compiler that GROMACS itself
 237 requires. Thus for now, OpenCL is not available with MSVC and the internal
 238 build of clFFT in GROMACS 2019. Either change compiler, try installing
 239 a clFFT package, or use the latest GROMACS 2018 point release.")
 240         endif()
 241
 242         # Fall back on the internal version
 243         set (_clFFT_dir ../external/clFFT/src)
 244         add_subdirectory(${_clFFT_dir} clFFT-build)
 245         target_sources(libgromacs PRIVATE
 246             $<TARGET_OBJECTS:clFFT>
 247         )
 248         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 249         # Use the magic variable for how to link any library needed for
 250         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 251         # (e.g. Windows, BSD, Mac).
 252         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 253     else()
 254         target_link_libraries(libgromacs PRIVATE clFFT)
 255     endif()
 256 endif()
 257
 258 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 259 # is a generated source file. These are awkward to suppress inline, so
 260 # we do it in the compilation command (after testing that the compiler
 261 # supports the suppressions). Same issue exists for nonbonded kernels
 262 # so we supress them for all generated files.
 263 include(CheckCXXCompilerFlag)
 264 check_cxx_compiler_flag("-Wno-unused -Wno-unused-parameter" HAS_NO_UNUSED)
 265 check_cxx_compiler_flag(-Wno-missing-declarations HAS_NO_MISSING_DECL)
 266 check_cxx_compiler_flag(-Wno-missing-prototypes HAS_NO_MISSING_PROTO)
 267 check_cxx_compiler_flag(/wd4101 HAS_NO_MSVC_UNUSED)
 268 if (NOT MSVC)
 269     check_cxx_compiler_flag(-wd1419 HAS_DECL_IN_SOURCE)
 270 endif()
 271 if (HAS_NO_UNUSED)
 272     target_compile_options(libgromacs_generated PRIVATE "-Wno-unused;-Wno-unused-parameter")
 273 endif()
 274 if (HAS_NO_MISSING_DECL)
 275     target_compile_options(libgromacs_generated PRIVATE "-Wno-missing-declarations")
 276 endif()
 277 # TODO The group scheme kernels don't use proper function prototype
 278 # declarations, and clang warns about such use, which we suppress
 279 # rather than fix. We would prefer to use no suppressions. However
 280 # other compilers do not support such a warning suppression for C++
 281 # source files, and issue warnings about that. Remove the use of
 282 # -Wno-missing-prototypes here and above when the group scheme is
 283 # removed.
 284 if (HAS_NO_MISSING_PROTO AND "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
 285     target_compile_options(libgromacs_generated PRIVATE "-Wno-missing-prototypes")
 286 endif()
 287 if (HAS_NO_MSVC_UNUSED)
 288     target_compile_options(libgromacs_generated PRIVATE "/wd4101")
 289 endif()
 290 if (HAS_DECL_IN_SOURCE)
 291     target_compile_options(libgromacs_generated PRIVATE "-wd1419")
 292 endif()
 293
 294 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 295     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 296     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 297     # with the SIMD_AVX_512_CXX_FLAGS flags.
 298     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 299 endif()
 300
 301 gmx_setup_tng_for_libgromacs()
 302
 303 target_link_libraries(libgromacs
 304                       PRIVATE
 305                       ${EXTRAE_LIBRARIES}
 306                       ${GMX_EXTRA_LIBRARIES}
 307                       ${GMX_COMMON_LIBRARIES}
 308                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 309                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 310                       ${OpenCL_LIBRARIES}
 311                       ${GMX_STDLIB_LIBRARIES}
 312                       PUBLIC
 313                       ${GMX_PUBLIC_LIBRARIES}
 314                       )
 315 if (GMX_OPENMP)
 316     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 317 endif()
 318 set_target_properties(libgromacs PROPERTIES
 319                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 320                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 321                       VERSION ${LIBRARY_VERSION}
 322                       )
 323
 324 gmx_manage_lmfit()
 325 target_link_libraries(libgromacs PRIVATE lmfit)
 326
 327 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^6\.0")
 328    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 329 endif()
 330 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 331    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 332      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 333      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 334      /wd6001  #unitialized memory
 335      /wd6011  #derefencing NULL
 336      /wd6053  #prior call not zero-terminate
 337      /wd6054  #might not be zero-terminated
 338      /wd6385  #reading invalid data
 339      /wd6386  #buffer overrun
 340      /wd6387  #could be '0'
 341      /wd28199 #uninitialized memory
 342      # For compile time constant (e.g. templates) the following warnings have flase postives
 343      /wd6239  #(<non-zero> && <expr>)
 344      /wd6240  #(<expr> && <non-zero>)
 345      /wd6294  #Ill-defined for-loop
 346      /wd6326  #comparison of constant with other constant
 347      /wd28020 #expression involving paramter is not true
 348      # Misc
 349      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 350      /wd6993  #OpenMP ignored
 351      #TODO
 352      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 353      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 354      /wd6246  #hides declaration
 355      >
 356    )
 357 endif()
 358
 359 if (GMX_CLANG_TIDY)
 360    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 361        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 362 endif()
 363
 364 gmx_write_installed_header_list()
 365
 366 # Only install the library in mdrun-only mode if it is actually necessary
 367 # for the binary
 368 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 369     install(TARGETS libgromacs
 370             EXPORT libgromacs
 371             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 372             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 373             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 374             COMPONENT libraries)
 375 endif()
 376
 377 if (NOT GMX_BUILD_MDRUN_ONLY)
 378     include(InstallLibInfo.cmake)
 379 endif()
 380
 381 # Technically, the user could want to do this for an OpenCL build
 382 # using the CUDA runtime, but currently there's no reason to want to
 383 # do that.
 384 if (INSTALL_CUDART_LIB) #can be set manual by user
 385     if (GMX_USE_CUDA)
 386         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 387             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 388             if(IS_CUDART) #libcuda should not be installed
 389                 #install also name-links (linker uses those)
 390                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 391                 install(FILES ${CUDA_LIBS} DESTINATION
 392                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 393             endif()
 394         endforeach()
 395     else()
 396         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 397     endif()
 398 endif()
 399
 400 if(GMX_USE_OPENCL)
 401     # Install the utility headers
 402     file(GLOB OPENCL_INSTALLED_FILES
 403         gpu_utils/vectype_ops.clh
 404         gpu_utils/device_utils.clh
 405         )
 406     install(FILES ${OPENCL_INSTALLED_FILES}
 407         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 408         COMPONENT libraries)
 409     file(GLOB OPENCL_INSTALLED_FILES
 410         pbcutil/ishift.h
 411         )
 412     install(FILES ${OPENCL_INSTALLED_FILES}
 413         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 414         COMPONENT libraries)
 415
 416     # Install the NB source and headers
 417     file(GLOB OPENCL_INSTALLED_FILES
 418         mdlib/nbnxn_consts.h
 419         )
 420     install(FILES ${OPENCL_INSTALLED_FILES}
 421         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/mdlib
 422         COMPONENT libraries)
 423     file(GLOB OPENCL_INSTALLED_FILES
 424         mdlib/nbnxn_ocl/nbnxn_ocl_kernels.cl
 425         mdlib/nbnxn_ocl/nbnxn_ocl_kernel.clh
 426         mdlib/nbnxn_ocl/nbnxn_ocl_kernel_pruneonly.clh
 427         mdlib/nbnxn_ocl/nbnxn_ocl_kernels.clh
 428         mdlib/nbnxn_ocl/nbnxn_ocl_kernels_fastgen.clh
 429         mdlib/nbnxn_ocl/nbnxn_ocl_kernels_fastgen_add_twincut.clh
 430         mdlib/nbnxn_ocl/nbnxn_ocl_kernel_utils.clh
 431         mdlib/nbnxn_ocl/nbnxn_ocl_consts.h
 432         )
 433     install(FILES ${OPENCL_INSTALLED_FILES}
 434         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/mdlib/nbnxn_ocl
 435         COMPONENT libraries)
 436
 437     # Install the PME source and headers
 438     file(GLOB OPENCL_INSTALLED_FILES
 439         ewald/pme-spread.clh
 440         ewald/pme-solve.clh
 441         ewald/pme-gather.clh
 442         ewald/pme-gpu-utils.clh
 443         ewald/pme-program.cl
 444         ewald/pme-gpu-types.h
 445         )
 446     install(FILES ${OPENCL_INSTALLED_FILES}
 447         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 448         COMPONENT libraries)
 449 endif()