src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # Permit the configuration to disable compiling the many nbnxm kernels
  64 # and others involved in force calculations. Currently only
  65 # short-ranged and bonded kernels are disabled this way, but in future
  66 # others may be appropriate. Thus the cmake option is not specific to
  67 # nbnxm module.
  68 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  69 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  70
  71 # Add these contents first because linking their tests can take a lot
  72 # of time, so we want lots of parallel work still available after
  73 # linking starts.
  74 add_subdirectory(utility)
  75 # Add normal contents
  76 add_subdirectory(gmxlib)
  77 add_subdirectory(mdlib)
  78 add_subdirectory(applied_forces)
  79 add_subdirectory(listed_forces)
  80 add_subdirectory(nbnxm)
  81 add_subdirectory(commandline)
  82 add_subdirectory(domdec)
  83 add_subdirectory(ewald)
  84 add_subdirectory(fft)
  85 add_subdirectory(gpu_utils)
  86 add_subdirectory(hardware)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(mdrun)
  90 add_subdirectory(mdrunutility)
  91 add_subdirectory(mdspan)
  92 add_subdirectory(mdtypes)
  93 add_subdirectory(onlinehelp)
  94 add_subdirectory(options)
  95 add_subdirectory(pbcutil)
  96 add_subdirectory(random)
  97 add_subdirectory(restraint)
  98 add_subdirectory(tables)
  99 add_subdirectory(taskassignment)
 100 add_subdirectory(timing)
 101 add_subdirectory(topology)
 102 add_subdirectory(trajectory)
 103 add_subdirectory(swap)
 104 add_subdirectory(essentialdynamics)
 105 add_subdirectory(pulling)
 106 add_subdirectory(simd)
 107 add_subdirectory(imd)
 108 add_subdirectory(compat)
 109 add_subdirectory(mimic)
 110 add_subdirectory(modularsimulator)
 111 if (NOT GMX_BUILD_MDRUN_ONLY)
 112     add_subdirectory(gmxana)
 113     add_subdirectory(gmxpreprocess)
 114     add_subdirectory(correlationfunctions)
 115     add_subdirectory(statistics)
 116     add_subdirectory(analysisdata)
 117     add_subdirectory(coordinateio)
 118     add_subdirectory(trajectoryanalysis)
 119     add_subdirectory(energyanalysis)
 120     add_subdirectory(tools)
 121 endif()
 122
 123 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 124 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 125
 126 # This would be the standard way to include thread_mpi, but
 127 # we want libgromacs to link the functions directly
 128 #if(GMX_THREAD_MPI)
 129 #    add_subdirectory(thread_mpi)
 130 #endif()
 131 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 132 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 133 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 134 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 135 if(CYGWIN)
 136     # Needs POSIX-isms for strdup, not just std-isms
 137     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 138 endif()
 139 gmx_target_compile_options(thread_mpi)
 140 if (WIN32)
 141     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 142 endif()
 143 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 144
 145 configure_file(version.h.cmakein version.h)
 146 if(GMX_INSTALL_LEGACY_API)
 147   install(FILES
 148           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 149           analysisdata.h
 150           options.h
 151           selection.h
 152           trajectoryanalysis.h
 153           DESTINATION include/gromacs)
 154 endif()
 155
 156 # This code is here instead of utility/CMakeLists.txt, because CMake
 157 # custom commands and source file properties can only be set in the directory
 158 # that contains the target that uses them.
 159 # TODO: Generate a header instead that can be included from baseversion.cpp.
 160 # That probably simplifies things somewhat.
 161 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 162 gmx_configure_version_file(
 163     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 164     REMOTE_HASH
 165     EXTRA_VARS
 166         GMX_SOURCE_DOI
 167         GMX_RELEASE_HASH
 168         GMX_SOURCE_HASH
 169         )
 170 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 171
 172 # Mark some shared GPU implementation files to compile with CUDA if needed
 173 if (GMX_GPU_CUDA)
 174     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 175     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 176 endif()
 177
 178 # set up CUDA compilation with clang
 179 if (GMX_CLANG_CUDA)
 180     foreach (_file ${LIBGROMACS_SOURCES})
 181         get_filename_component(_ext ${_file} EXT)
 182         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 183         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 184             gmx_compile_cuda_file_with_clang(${_file})
 185         endif()
 186     endforeach()
 187 endif()
 188
 189 if (GMX_GPU_CUDA)
 190     # Work around FindCUDA that prevents using target_link_libraries()
 191     # with keywords otherwise...
 192     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 193     if (NOT GMX_CLANG_CUDA)
 194         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 195     else()
 196         add_library(libgromacs ${LIBGROMACS_SOURCES})
 197     endif()
 198     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 199 else()
 200     add_library(libgromacs ${LIBGROMACS_SOURCES})
 201 endif()
 202
 203 # Add these contents first because linking their tests can take a lot
 204 # of time, so we want lots of parallel work still available after
 205 # linking starts.
 206 add_subdirectory(fileio)
 207 add_subdirectory(selection)
 208
 209 # Suppress a warning about our abuse of t_inputrec
 210 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 211
 212 # Handle the object libraries that contain the source file
 213 # dependencies that need special handling because they are generated
 214 # or external code.
 215 foreach(object_library ${libgromacs_object_library_dependencies})
 216     if (BUILD_SHARED_LIBS)
 217         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 218     endif()
 219     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 220
 221     # Add the sources from the object libraries to the main library.
 222     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 223 endforeach()
 224 gmx_target_compile_options(libgromacs)
 225 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 226 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 227
 228 if (GMX_GPU_OPENCL)
 229     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 230     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 231
 232     # Default to using clFFT found on the system
 233     # switch to quiet at the second run.
 234     if (DEFINED clFFT_LIBRARY)
 235         set (clFFT_FIND_QUIETLY TRUE)
 236     endif()
 237     find_package(clFFT)
 238     if (NOT clFFT_FOUND)
 239         if (GMX_EXTERNAL_CLFFT)
 240             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 241         endif()
 242
 243         if(MSVC)
 244             message(FATAL_ERROR
 245 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 246 requires clFFT, which was not found on your system. GROMACS does bundle
 247 clFFT to help with building for OpenCL, but that clFFT has not yet been
 248 ported to the more recent versions of that compiler that GROMACS itself
 249 requires. Thus for now, OpenCL is not available with MSVC and the internal
 250 build of clFFT in GROMACS 2019. Either change compiler, try installing
 251 a clFFT package, or use the latest GROMACS 2018 point release.")
 252         endif()
 253
 254         # Fall back on the internal version
 255         set (_clFFT_dir ../external/clFFT/src)
 256         add_subdirectory(${_clFFT_dir} clFFT-build)
 257         target_sources(libgromacs PRIVATE
 258             $<TARGET_OBJECTS:clFFT>
 259         )
 260         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 261         # Use the magic variable for how to link any library needed for
 262         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 263         # (e.g. Windows, BSD, Mac).
 264         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 265     else()
 266         target_link_libraries(libgromacs PRIVATE clFFT)
 267     endif()
 268 endif()
 269
 270 # Permit GROMACS code to include externally developed headers, such as
 271 # the functionality from the nonstd project that we use for
 272 # gmx::compat::optional. These are included as system headers so that
 273 # no warnings are issued from them.
 274 #
 275 # TODO Perhaps generalize this for all headers from src/external
 276 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 277
 278 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 279     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 280     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 281     # with the SIMD_AVX_512_CXX_FLAGS flags.
 282     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 283 endif()
 284
 285 gmx_setup_tng_for_libgromacs()
 286
 287 target_link_libraries(libgromacs
 288                       PRIVATE
 289                       ${EXTRAE_LIBRARIES}
 290                       ${GMX_EXTRA_LIBRARIES}
 291                       ${GMX_COMMON_LIBRARIES}
 292                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 293                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 294                       ${OpenCL_LIBRARIES}
 295                       $<$<PLATFORM_ID:SunOS>:socket>
 296                       PUBLIC
 297                       ${GMX_PUBLIC_LIBRARIES}
 298                       )
 299 if (GMX_OPENMP)
 300     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 301 endif()
 302 set_target_properties(libgromacs PROPERTIES
 303                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 304                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 305                       VERSION ${LIBRARY_VERSION}
 306                       )
 307
 308 gmx_manage_lmfit()
 309 target_link_libraries(libgromacs PRIVATE lmfit)
 310
 311 # Make sure we fix "everything" found by more recent versions of clang.
 312 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 313    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 314 endif()
 315 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 316    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 317      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 318      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 319      /wd6001  #unitialized memory
 320      /wd6011  #derefencing NULL
 321      /wd6053  #prior call not zero-terminate
 322      /wd6054  #might not be zero-terminated
 323      /wd6385  #reading invalid data
 324      /wd6386  #buffer overrun
 325      /wd6387  #could be '0'
 326      /wd28199 #uninitialized memory
 327      # For compile time constant (e.g. templates) the following warnings have flase postives
 328      /wd6239  #(<non-zero> && <expr>)
 329      /wd6240  #(<expr> && <non-zero>)
 330      /wd6294  #Ill-defined for-loop
 331      /wd6326  #comparison of constant with other constant
 332      /wd28020 #expression involving paramter is not true
 333      # Misc
 334      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 335      /wd6993  #OpenMP ignored
 336      #TODO
 337      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 338      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 339      /wd6246  #hides declaration
 340      >
 341    )
 342 endif()
 343
 344 if (GMX_CLANG_TIDY)
 345    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 346        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 347 endif()
 348
 349 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 350 # and we know they are not real issues. So we only check that it can compile without error
 351 # but ignore all warnings.
 352 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 353     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 354 endif()
 355
 356 # Only install the library in mdrun-only mode if it is actually necessary
 357 # for the binary
 358 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 359     install(TARGETS libgromacs
 360             EXPORT libgromacs
 361             LIBRARY
 362                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 363                 COMPONENT libraries
 364             RUNTIME
 365                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 366                 COMPONENT libraries
 367             ARCHIVE
 368                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 369                 COMPONENT libraries
 370             INCLUDES DESTINATION include)
 371     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 372     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 373     if(GMX_INSTALL_LEGACY_API)
 374         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 375     endif()
 376     add_library(Gromacs::libgromacs ALIAS libgromacs)
 377 endif()
 378
 379 if (NOT GMX_BUILD_MDRUN_ONLY)
 380     include(InstallLibInfo.cmake)
 381 endif()
 382
 383 # Technically, the user could want to do this for an OpenCL build
 384 # using the CUDA runtime, but currently there's no reason to want to
 385 # do that.
 386 if (INSTALL_CUDART_LIB) #can be set manual by user
 387     if (GMX_GPU_CUDA)
 388         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 389             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 390             if(IS_CUDART) #libcuda should not be installed
 391                 #install also name-links (linker uses those)
 392                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 393                 install(FILES ${CUDA_LIBS} DESTINATION
 394                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 395             endif()
 396         endforeach()
 397     else()
 398         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 399     endif()
 400 endif()
 401
 402 if(GMX_GPU_OPENCL)
 403     # Install the utility headers
 404     file(GLOB OPENCL_INSTALLED_FILES
 405         gpu_utils/vectype_ops.clh
 406         gpu_utils/device_utils.clh
 407         )
 408     install(FILES ${OPENCL_INSTALLED_FILES}
 409         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 410         COMPONENT libraries)
 411     file(GLOB OPENCL_INSTALLED_FILES
 412         pbcutil/ishift.h
 413         )
 414     install(FILES ${OPENCL_INSTALLED_FILES}
 415         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 416         COMPONENT libraries)
 417
 418     # Install the NBNXM source and headers
 419     file(GLOB OPENCL_INSTALLED_FILES
 420         nbnxm/constants.h
 421         )
 422     install(FILES ${OPENCL_INSTALLED_FILES}
 423         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 424         COMPONENT libraries)
 425     file(GLOB OPENCL_INSTALLED_FILES
 426         nbnxm/opencl/nbnxm_ocl_kernels.cl
 427         nbnxm/opencl/nbnxm_ocl_kernel.clh
 428         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 429         nbnxm/opencl/nbnxm_ocl_kernels.clh
 430         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 431         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 432         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 433         nbnxm/opencl/nbnxm_ocl_consts.h
 434         )
 435     install(FILES ${OPENCL_INSTALLED_FILES}
 436         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 437         COMPONENT libraries)
 438
 439     # Install the PME source and headers
 440     file(GLOB OPENCL_INSTALLED_FILES
 441         ewald/pme_spread.clh
 442         ewald/pme_solve.clh
 443         ewald/pme_gather.clh
 444         ewald/pme_gpu_utils.clh
 445         ewald/pme_program.cl
 446         ewald/pme_gpu_types.h
 447         )
 448     install(FILES ${OPENCL_INSTALLED_FILES}
 449         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 450         COMPONENT libraries)
 451 endif()