src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # Permit the configuration to disable compiling the many nbnxm kernels
  64 # and others involved in force calculations. Currently only
  65 # short-ranged and bonded kernels are disabled this way, but in future
  66 # others may be appropriate. Thus the cmake option is not specific to
  67 # nbnxm module.
  68 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  69 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  70
  71 # Add these contents first because linking their tests can take a lot
  72 # of time, so we want lots of parallel work still available after
  73 # linking starts.
  74 add_subdirectory(utility)
  75 # Add normal contents
  76 add_subdirectory(gmxlib)
  77 add_subdirectory(mdlib)
  78 add_subdirectory(applied_forces)
  79 add_subdirectory(listed_forces)
  80 add_subdirectory(nbnxm)
  81 add_subdirectory(commandline)
  82 add_subdirectory(domdec)
  83 add_subdirectory(ewald)
  84 add_subdirectory(fft)
  85 add_subdirectory(gpu_utils)
  86 add_subdirectory(hardware)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(mdrun)
  90 add_subdirectory(mdrunutility)
  91 add_subdirectory(mdspan)
  92 add_subdirectory(mdtypes)
  93 add_subdirectory(onlinehelp)
  94 add_subdirectory(options)
  95 add_subdirectory(pbcutil)
  96 add_subdirectory(random)
  97 add_subdirectory(restraint)
  98 add_subdirectory(tables)
  99 add_subdirectory(taskassignment)
 100 add_subdirectory(timing)
 101 add_subdirectory(topology)
 102 add_subdirectory(trajectory)
 103 add_subdirectory(swap)
 104 add_subdirectory(essentialdynamics)
 105 add_subdirectory(pulling)
 106 add_subdirectory(awh)
 107 add_subdirectory(simd)
 108 add_subdirectory(imd)
 109 add_subdirectory(compat)
 110 add_subdirectory(mimic)
 111 add_subdirectory(modularsimulator)
 112 if (NOT GMX_BUILD_MDRUN_ONLY)
 113     add_subdirectory(gmxana)
 114     add_subdirectory(gmxpreprocess)
 115     add_subdirectory(correlationfunctions)
 116     add_subdirectory(statistics)
 117     add_subdirectory(analysisdata)
 118     add_subdirectory(coordinateio)
 119     add_subdirectory(trajectoryanalysis)
 120     add_subdirectory(energyanalysis)
 121     add_subdirectory(tools)
 122 endif()
 123
 124 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 125 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 126
 127 # This would be the standard way to include thread_mpi, but
 128 # we want libgromacs to link the functions directly
 129 #if(GMX_THREAD_MPI)
 130 #    add_subdirectory(thread_mpi)
 131 #endif()
 132 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 133 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 134 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 135 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 136 if(CYGWIN)
 137     # Needs POSIX-isms for strdup, not just std-isms
 138     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 139 endif()
 140 gmx_target_compile_options(thread_mpi)
 141 if (WIN32)
 142     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 143 endif()
 144 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 145
 146 configure_file(version.h.cmakein version.h)
 147 if(GMX_INSTALL_LEGACY_API)
 148   install(FILES
 149           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 150           analysisdata.h
 151           options.h
 152           selection.h
 153           trajectoryanalysis.h
 154           DESTINATION include/gromacs)
 155 endif()
 156
 157 # This code is here instead of utility/CMakeLists.txt, because CMake
 158 # custom commands and source file properties can only be set in the directory
 159 # that contains the target that uses them.
 160 # TODO: Generate a header instead that can be included from baseversion.cpp.
 161 # That probably simplifies things somewhat.
 162 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 163 gmx_configure_version_file(
 164     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 165     REMOTE_HASH
 166     EXTRA_VARS
 167         GMX_SOURCE_DOI
 168         GMX_RELEASE_HASH
 169         GMX_SOURCE_HASH
 170         )
 171 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 172
 173 # Mark some shared GPU implementation files to compile with CUDA if needed
 174 if (GMX_GPU_CUDA)
 175     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 176     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 177 endif()
 178
 179 # set up CUDA compilation with clang
 180 if (GMX_CLANG_CUDA)
 181     foreach (_file ${LIBGROMACS_SOURCES})
 182         get_filename_component(_ext ${_file} EXT)
 183         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 184         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 185             gmx_compile_cuda_file_with_clang(${_file})
 186         endif()
 187     endforeach()
 188 endif()
 189
 190 if (GMX_GPU_CUDA)
 191     # Work around FindCUDA that prevents using target_link_libraries()
 192     # with keywords otherwise...
 193     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 194     if (NOT GMX_CLANG_CUDA)
 195         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 196     else()
 197         add_library(libgromacs ${LIBGROMACS_SOURCES})
 198     endif()
 199     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 200 else()
 201     add_library(libgromacs ${LIBGROMACS_SOURCES})
 202 endif()
 203
 204 # Add these contents first because linking their tests can take a lot
 205 # of time, so we want lots of parallel work still available after
 206 # linking starts.
 207 add_subdirectory(fileio)
 208 add_subdirectory(selection)
 209
 210 # Suppress a warning about our abuse of t_inputrec
 211 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 212
 213 # Handle the object libraries that contain the source file
 214 # dependencies that need special handling because they are generated
 215 # or external code.
 216 foreach(object_library ${libgromacs_object_library_dependencies})
 217     if (BUILD_SHARED_LIBS)
 218         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 219     endif()
 220     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 221
 222     # Add the sources from the object libraries to the main library.
 223     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 224 endforeach()
 225 gmx_target_compile_options(libgromacs)
 226 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 227 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 228
 229 if (GMX_GPU_OPENCL)
 230     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 231     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 232
 233     # Default to using clFFT found on the system
 234     # switch to quiet at the second run.
 235     if (DEFINED clFFT_LIBRARY)
 236         set (clFFT_FIND_QUIETLY TRUE)
 237     endif()
 238     find_package(clFFT)
 239     if (NOT clFFT_FOUND)
 240         if (GMX_EXTERNAL_CLFFT)
 241             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 242         endif()
 243
 244         if(MSVC)
 245             message(FATAL_ERROR
 246 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 247 requires clFFT, which was not found on your system. GROMACS does bundle
 248 clFFT to help with building for OpenCL, but that clFFT has not yet been
 249 ported to the more recent versions of that compiler that GROMACS itself
 250 requires. Thus for now, OpenCL is not available with MSVC and the internal
 251 build of clFFT in GROMACS 2019. Either change compiler, try installing
 252 a clFFT package, or use the latest GROMACS 2018 point release.")
 253         endif()
 254
 255         # Fall back on the internal version
 256         set (_clFFT_dir ../external/clFFT/src)
 257         add_subdirectory(${_clFFT_dir} clFFT-build)
 258         target_sources(libgromacs PRIVATE
 259             $<TARGET_OBJECTS:clFFT>
 260         )
 261         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 262         # Use the magic variable for how to link any library needed for
 263         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 264         # (e.g. Windows, BSD, Mac).
 265         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 266     else()
 267         target_link_libraries(libgromacs PRIVATE clFFT)
 268     endif()
 269 endif()
 270
 271 # Permit GROMACS code to include externally developed headers, such as
 272 # the functionality from the nonstd project that we use for
 273 # gmx::compat::optional. These are included as system headers so that
 274 # no warnings are issued from them.
 275 #
 276 # TODO Perhaps generalize this for all headers from src/external
 277 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 278
 279 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 280     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 281     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 282     # with the SIMD_AVX_512_CXX_FLAGS flags.
 283     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 284 endif()
 285
 286 gmx_setup_tng_for_libgromacs()
 287
 288 target_link_libraries(libgromacs
 289                       PRIVATE
 290                       ${EXTRAE_LIBRARIES}
 291                       ${GMX_EXTRA_LIBRARIES}
 292                       ${GMX_COMMON_LIBRARIES}
 293                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 294                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 295                       ${OpenCL_LIBRARIES}
 296                       $<$<PLATFORM_ID:SunOS>:socket>
 297                       PUBLIC
 298                       ${GMX_PUBLIC_LIBRARIES}
 299                       )
 300 if (GMX_OPENMP)
 301     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 302 endif()
 303 set_target_properties(libgromacs PROPERTIES
 304                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 305                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 306                       VERSION ${LIBRARY_VERSION}
 307                       )
 308
 309 gmx_manage_lmfit()
 310 target_link_libraries(libgromacs PRIVATE lmfit)
 311
 312 # Make sure we fix "everything" found by more recent versions of clang.
 313 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 314    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 315 endif()
 316 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 317    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 318      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 319      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 320      /wd6001  #unitialized memory
 321      /wd6011  #derefencing NULL
 322      /wd6053  #prior call not zero-terminate
 323      /wd6054  #might not be zero-terminated
 324      /wd6385  #reading invalid data
 325      /wd6386  #buffer overrun
 326      /wd6387  #could be '0'
 327      /wd28199 #uninitialized memory
 328      # For compile time constant (e.g. templates) the following warnings have flase postives
 329      /wd6239  #(<non-zero> && <expr>)
 330      /wd6240  #(<expr> && <non-zero>)
 331      /wd6294  #Ill-defined for-loop
 332      /wd6326  #comparison of constant with other constant
 333      /wd28020 #expression involving paramter is not true
 334      # Misc
 335      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 336      /wd6993  #OpenMP ignored
 337      #TODO
 338      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 339      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 340      /wd6246  #hides declaration
 341      >
 342    )
 343 endif()
 344
 345 if (GMX_CLANG_TIDY)
 346    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 347        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 348 endif()
 349
 350 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 351 # and we know they are not real issues. So we only check that it can compile without error
 352 # but ignore all warnings.
 353 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 354     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 355 endif()
 356
 357 # Only install the library in mdrun-only mode if it is actually necessary
 358 # for the binary
 359 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 360     install(TARGETS libgromacs
 361             EXPORT libgromacs
 362             LIBRARY
 363                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 364                 COMPONENT libraries
 365             RUNTIME
 366                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 367                 COMPONENT libraries
 368             ARCHIVE
 369                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 370                 COMPONENT libraries
 371             INCLUDES DESTINATION include)
 372     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 373     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 374     if(GMX_INSTALL_LEGACY_API)
 375         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 376     endif()
 377     add_library(Gromacs::libgromacs ALIAS libgromacs)
 378 endif()
 379
 380 if (NOT GMX_BUILD_MDRUN_ONLY)
 381     include(InstallLibInfo.cmake)
 382 endif()
 383
 384 # Technically, the user could want to do this for an OpenCL build
 385 # using the CUDA runtime, but currently there's no reason to want to
 386 # do that.
 387 if (INSTALL_CUDART_LIB) #can be set manual by user
 388     if (GMX_GPU_CUDA)
 389         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 390             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 391             if(IS_CUDART) #libcuda should not be installed
 392                 #install also name-links (linker uses those)
 393                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 394                 install(FILES ${CUDA_LIBS} DESTINATION
 395                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 396             endif()
 397         endforeach()
 398     else()
 399         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 400     endif()
 401 endif()
 402
 403 if(GMX_GPU_OPENCL)
 404     # Install the utility headers
 405     file(GLOB OPENCL_INSTALLED_FILES
 406         gpu_utils/vectype_ops.clh
 407         gpu_utils/device_utils.clh
 408         )
 409     install(FILES ${OPENCL_INSTALLED_FILES}
 410         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 411         COMPONENT libraries)
 412     file(GLOB OPENCL_INSTALLED_FILES
 413         pbcutil/ishift.h
 414         )
 415     install(FILES ${OPENCL_INSTALLED_FILES}
 416         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 417         COMPONENT libraries)
 418
 419     # Install the NBNXM source and headers
 420     file(GLOB OPENCL_INSTALLED_FILES
 421         nbnxm/constants.h
 422         )
 423     install(FILES ${OPENCL_INSTALLED_FILES}
 424         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 425         COMPONENT libraries)
 426     file(GLOB OPENCL_INSTALLED_FILES
 427         nbnxm/opencl/nbnxm_ocl_kernels.cl
 428         nbnxm/opencl/nbnxm_ocl_kernel.clh
 429         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 430         nbnxm/opencl/nbnxm_ocl_kernels.clh
 431         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 432         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 433         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 434         nbnxm/opencl/nbnxm_ocl_consts.h
 435         )
 436     install(FILES ${OPENCL_INSTALLED_FILES}
 437         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 438         COMPONENT libraries)
 439
 440     # Install the PME source and headers
 441     file(GLOB OPENCL_INSTALLED_FILES
 442         ewald/pme_spread.clh
 443         ewald/pme_solve.clh
 444         ewald/pme_gather.clh
 445         ewald/pme_gpu_utils.clh
 446         ewald/pme_program.cl
 447         ewald/pme_gpu_types.h
 448         )
 449     install(FILES ${OPENCL_INSTALLED_FILES}
 450         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 451         COMPONENT libraries)
 452 endif()