src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 set(libgromacs_object_library_dependencies "")
  47 function (_gmx_add_files_to_property PROPERTY)
  48     foreach (_file ${ARGN})
  49         if (IS_ABSOLUTE "${_file}")
  50             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  51         else()
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  53                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  54         endif()
  55     endforeach()
  56 endfunction ()
  57
  58 function (gmx_add_libgromacs_sources)
  59     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  60 endfunction ()
  61
  62 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  63 # approach, at least for the build system. See Redmine #2530
  64 function (gmx_compile_cpp_as_cuda)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 function (gmx_install_headers)
  69     if (NOT GMX_BUILD_MDRUN_ONLY)
  70         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  71         install(FILES       ${ARGN}
  72                 DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${_dest}"
  73                 COMPONENT   development)
  74     endif()
  75     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  76 endfunction ()
  77
  78 function (gmx_write_installed_header_list)
  79     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  80     string(REPLACE ";" "\n" _list "${_list}")
  81     # TODO: Make this only update the file timestamp if the contents actually change.
  82     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  83 endfunction()
  84
  85 add_subdirectory(gmxlib)
  86 add_subdirectory(mdlib)
  87 add_subdirectory(applied_forces)
  88 add_subdirectory(listed_forces)
  89 add_subdirectory(nbnxm)
  90 add_subdirectory(commandline)
  91 add_subdirectory(domdec)
  92 add_subdirectory(ewald)
  93 add_subdirectory(fft)
  94 add_subdirectory(gpu_utils)
  95 add_subdirectory(hardware)
  96 add_subdirectory(linearalgebra)
  97 add_subdirectory(math)
  98 add_subdirectory(mdrun)
  99 add_subdirectory(mdrunutility)
 100 add_subdirectory(mdspan)
 101 add_subdirectory(mdtypes)
 102 add_subdirectory(onlinehelp)
 103 add_subdirectory(options)
 104 add_subdirectory(pbcutil)
 105 add_subdirectory(random)
 106 add_subdirectory(restraint)
 107 add_subdirectory(tables)
 108 add_subdirectory(taskassignment)
 109 add_subdirectory(timing)
 110 add_subdirectory(topology)
 111 add_subdirectory(trajectory)
 112 add_subdirectory(utility)
 113 add_subdirectory(fileio)
 114 add_subdirectory(swap)
 115 add_subdirectory(essentialdynamics)
 116 add_subdirectory(pulling)
 117 add_subdirectory(awh)
 118 add_subdirectory(simd)
 119 add_subdirectory(imd)
 120 add_subdirectory(compat)
 121 add_subdirectory(mimic)
 122 if (NOT GMX_BUILD_MDRUN_ONLY)
 123     add_subdirectory(gmxana)
 124     add_subdirectory(gmxpreprocess)
 125     add_subdirectory(correlationfunctions)
 126     add_subdirectory(statistics)
 127     add_subdirectory(analysisdata)
 128     add_subdirectory(coordinateio)
 129     add_subdirectory(selection)
 130     add_subdirectory(trajectoryanalysis)
 131     add_subdirectory(energyanalysis)
 132     add_subdirectory(tools)
 133 endif()
 134
 135 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 136 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 137
 138 # This would be the standard way to include thread_mpi, but
 139 # we want libgromacs to link the functions directly
 140 #if(GMX_THREAD_MPI)
 141 #    add_subdirectory(thread_mpi)
 142 #endif()
 143 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 144 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 145 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 146 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 147
 148 configure_file(version.h.cmakein version.h)
 149 gmx_install_headers(
 150     analysisdata.h
 151     commandline.h
 152     options.h
 153     random.h
 154     selection.h
 155     trajectoryanalysis.h
 156     utility.h
 157     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 158     )
 159
 160 # This code is here instead of utility/CMakeLists.txt, because CMake
 161 # custom commands and source file properties can only be set in the directory
 162 # that contains the target that uses them.
 163 # TODO: Generate a header instead that can be included from baseversion.c.
 164 # That probably simplifies things somewhat.
 165 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 166 gmx_configure_version_file(
 167     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 168     REMOTE_HASH
 169     EXTRA_VARS
 170         GMX_SOURCE_DOI
 171         )
 172 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 173
 174 # Mark some shared GPU implementation files to compile with CUDA if needed
 175 if (GMX_USE_CUDA)
 176     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 177     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 178 endif()
 179
 180 # set up CUDA compilation with clang
 181 if (GMX_CLANG_CUDA)
 182     foreach (_file ${LIBGROMACS_SOURCES})
 183         get_filename_component(_ext ${_file} EXT)
 184         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 185         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 186             gmx_compile_cuda_file_with_clang(${_file})
 187         endif()
 188     endforeach()
 189 endif()
 190
 191 if (GMX_USE_CUDA)
 192     # Work around FindCUDA that prevents using target_link_libraries()
 193     # with keywords otherwise...
 194     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 195     if (NOT GMX_CLANG_CUDA)
 196         # FindCUDA.cmake expects this library to already exist, so we
 197         # create it here.
 198         add_library(libgromacs_generated OBJECT "")
 199         set_target_properties(libgromacs_generated PROPERTIES LINKER_LANGUAGE CXX)
 200         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 201         list(APPEND libgromacs_object_library_dependencies libgromacs_generated)
 202     else()
 203         add_library(libgromacs ${LIBGROMACS_SOURCES})
 204     endif()
 205     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 206 else()
 207     add_library(libgromacs ${LIBGROMACS_SOURCES})
 208 endif()
 209
 210 # Handle the object libraries that contain the source file
 211 # dependencies that need special handling because they are generated
 212 # or external code.
 213 foreach(object_library ${libgromacs_object_library_dependencies})
 214     if (BUILD_SHARED_LIBS)
 215         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 216     endif()
 217     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 218
 219     # Add the sources from the object libraries to the main library.
 220     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 221 endforeach()
 222
 223 if (GMX_USE_OPENCL)
 224     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 225     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 226
 227     # Default to using clFFT found on the system
 228     # switch to quiet at the second run.
 229     if (DEFINED clFFT_LIBRARY)
 230         set (clFFT_FIND_QUIETLY TRUE)
 231     endif()
 232     find_package(clFFT)
 233     if (NOT clFFT_FOUND)
 234         if (GMX_EXTERNAL_CLFFT)
 235             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 236         endif()
 237
 238         if(MSVC)
 239             message(FATAL_ERROR
 240 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 241 requires clFFT, which was not found on your system. GROMACS does bundle
 242 clFFT to help with building for OpenCL, but that clFFT has not yet been
 243 ported to the more recent versions of that compiler that GROMACS itself
 244 requires. Thus for now, OpenCL is not available with MSVC and the internal
 245 build of clFFT in GROMACS 2019. Either change compiler, try installing
 246 a clFFT package, or use the latest GROMACS 2018 point release.")
 247         endif()
 248
 249         # Fall back on the internal version
 250         set (_clFFT_dir ../external/clFFT/src)
 251         add_subdirectory(${_clFFT_dir} clFFT-build)
 252         target_sources(libgromacs PRIVATE
 253             $<TARGET_OBJECTS:clFFT>
 254         )
 255         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 256         # Use the magic variable for how to link any library needed for
 257         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 258         # (e.g. Windows, BSD, Mac).
 259         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 260     else()
 261         target_link_libraries(libgromacs PRIVATE clFFT)
 262     endif()
 263 endif()
 264
 265 # Permit GROMACS code to include externally developed headers, such as
 266 # the functionality from the nonstd project that we use for
 267 # gmx::compat::optional. These are included as system headers so that
 268 # no warnings are issued from them.
 269 #
 270 # TODO Perhaps generalize this for all headers from src/external
 271 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 272
 273 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 274     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 275     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 276     # with the SIMD_AVX_512_CXX_FLAGS flags.
 277     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 278 endif()
 279
 280 gmx_setup_tng_for_libgromacs()
 281
 282 target_link_libraries(libgromacs
 283                       PRIVATE
 284                       ${EXTRAE_LIBRARIES}
 285                       ${GMX_EXTRA_LIBRARIES}
 286                       ${GMX_COMMON_LIBRARIES}
 287                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 288                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 289                       ${OpenCL_LIBRARIES}
 290                       PUBLIC
 291                       ${GMX_PUBLIC_LIBRARIES}
 292                       )
 293 if (GMX_OPENMP)
 294     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 295 endif()
 296 set_target_properties(libgromacs PROPERTIES
 297                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 298                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 299                       VERSION ${LIBRARY_VERSION}
 300                       )
 301
 302 gmx_manage_lmfit()
 303 target_link_libraries(libgromacs PRIVATE lmfit)
 304
 305 # Fix everything found by the latest version of clang that we use in
 306 # Jenkins testing. This should be updated when we update the latest
 307 # tested version of clang.
 308 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^7\.0")
 309    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 310 endif()
 311 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 312    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 313      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 314      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 315      /wd6001  #unitialized memory
 316      /wd6011  #derefencing NULL
 317      /wd6053  #prior call not zero-terminate
 318      /wd6054  #might not be zero-terminated
 319      /wd6385  #reading invalid data
 320      /wd6386  #buffer overrun
 321      /wd6387  #could be '0'
 322      /wd28199 #uninitialized memory
 323      # For compile time constant (e.g. templates) the following warnings have flase postives
 324      /wd6239  #(<non-zero> && <expr>)
 325      /wd6240  #(<expr> && <non-zero>)
 326      /wd6294  #Ill-defined for-loop
 327      /wd6326  #comparison of constant with other constant
 328      /wd28020 #expression involving paramter is not true
 329      # Misc
 330      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 331      /wd6993  #OpenMP ignored
 332      #TODO
 333      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 334      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 335      /wd6246  #hides declaration
 336      >
 337    )
 338 endif()
 339
 340 if (GMX_CLANG_TIDY)
 341    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 342        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 343 endif()
 344
 345 gmx_write_installed_header_list()
 346
 347 # Only install the library in mdrun-only mode if it is actually necessary
 348 # for the binary
 349 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 350     install(TARGETS libgromacs
 351             EXPORT libgromacs
 352             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 353             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 354             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 355             COMPONENT libraries)
 356 endif()
 357
 358 if (NOT GMX_BUILD_MDRUN_ONLY)
 359     include(InstallLibInfo.cmake)
 360 endif()
 361
 362 # Technically, the user could want to do this for an OpenCL build
 363 # using the CUDA runtime, but currently there's no reason to want to
 364 # do that.
 365 if (INSTALL_CUDART_LIB) #can be set manual by user
 366     if (GMX_USE_CUDA)
 367         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 368             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 369             if(IS_CUDART) #libcuda should not be installed
 370                 #install also name-links (linker uses those)
 371                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 372                 install(FILES ${CUDA_LIBS} DESTINATION
 373                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 374             endif()
 375         endforeach()
 376     else()
 377         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 378     endif()
 379 endif()
 380
 381 if(GMX_USE_OPENCL)
 382     # Install the utility headers
 383     file(GLOB OPENCL_INSTALLED_FILES
 384         gpu_utils/vectype_ops.clh
 385         gpu_utils/device_utils.clh
 386         )
 387     install(FILES ${OPENCL_INSTALLED_FILES}
 388         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 389         COMPONENT libraries)
 390     file(GLOB OPENCL_INSTALLED_FILES
 391         pbcutil/ishift.h
 392         )
 393     install(FILES ${OPENCL_INSTALLED_FILES}
 394         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 395         COMPONENT libraries)
 396
 397     # Install the NBNXM source and headers
 398     file(GLOB OPENCL_INSTALLED_FILES
 399         nbnxm/constants.h
 400         )
 401     install(FILES ${OPENCL_INSTALLED_FILES}
 402         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 403         COMPONENT libraries)
 404     file(GLOB OPENCL_INSTALLED_FILES
 405         nbnxm/opencl/nbnxm_ocl_kernels.cl
 406         nbnxm/opencl/nbnxm_ocl_kernel.clh
 407         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 408         nbnxm/opencl/nbnxm_ocl_kernels.clh
 409         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 410         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 411         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 412         nbnxm/opencl/nbnxm_ocl_consts.h
 413         )
 414     install(FILES ${OPENCL_INSTALLED_FILES}
 415         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 416         COMPONENT libraries)
 417
 418     # Install the PME source and headers
 419     file(GLOB OPENCL_INSTALLED_FILES
 420         ewald/pme_spread.clh
 421         ewald/pme_solve.clh
 422         ewald/pme_gather.clh
 423         ewald/pme_gpu_utils.clh
 424         ewald/pme_program.cl
 425         ewald/pme_gpu_types.h
 426         )
 427     install(FILES ${OPENCL_INSTALLED_FILES}
 428         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 429         COMPONENT libraries)
 430 endif()