src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 function (gmx_install_headers DESTINATION)
  38     if (NOT GMX_BUILD_MDRUN_ONLY)
  39         if (DESTINATION)
  40             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs/${DESTINATION})
  41         else()
  42             set(DESTINATION ${INCL_INSTALL_DIR}/gromacs)
  43         endif()
  44         install(FILES ${ARGN} DESTINATION ${DESTINATION} COMPONENT development)
  45     endif()
  46 endfunction ()
  47
  48 if(GMX_USE_TNG)
  49     option(GMX_EXTERNAL_TNG "Use external TNG instead of compiling the version shipped with GROMACS."
  50            OFF)
  51     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  52     if(GMX_EXTERNAL_TNG)
  53         find_package(TNG_IO 1.6.0)
  54         if(NOT TNG_IO_FOUND)
  55             message(FATAL_ERROR
  56                 "TNG >= 1.6.0 not found. "
  57                 "You can set GMX_EXTERNAL_TNG=OFF to compile TNG.")
  58         endif()
  59         include_directories(${TNG_IO_INCLUDE_DIRS})
  60     endif()
  61     if(NOT GMX_EXTERNAL_TNG)
  62         # TNG wants zlib if it is available
  63         find_package(ZLIB QUIET)
  64         include(gmxTestZLib)
  65         gmx_test_zlib(HAVE_ZLIB)
  66
  67         include(${CMAKE_SOURCE_DIR}/src/external/tng_io/BuildTNG.cmake)
  68         tng_get_source_list(TNG_SOURCES TNG_IO_DEFINITIONS)
  69         list(APPEND LIBGROMACS_SOURCES ${TNG_SOURCES})
  70         tng_set_source_properties(WITH_ZLIB ${HAVE_ZLIB})
  71
  72         if (HAVE_ZLIB)
  73             list(APPEND GMX_EXTRA_LIBRARIES ${ZLIB_LIBRARIES})
  74         endif()
  75     endif()
  76 else()
  77     # We still need to get tng/tng_io_fwd.h from somewhere!
  78     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/tng_io/include)
  79 endif()
  80
  81 add_subdirectory(gmxlib)
  82 add_subdirectory(mdlib)
  83 add_subdirectory(gmxpreprocess)
  84 add_subdirectory(commandline)
  85 add_subdirectory(fft)
  86 add_subdirectory(linearalgebra)
  87 add_subdirectory(math)
  88 add_subdirectory(random)
  89 add_subdirectory(onlinehelp)
  90 add_subdirectory(options)
  91 add_subdirectory(pbcutil)
  92 add_subdirectory(timing)
  93 add_subdirectory(topology)
  94 add_subdirectory(utility)
  95 add_subdirectory(fileio)
  96 add_subdirectory(swap)
  97 add_subdirectory(essentialdynamics)
  98 add_subdirectory(pulling)
  99 add_subdirectory(simd)
 100 add_subdirectory(imd)
 101 if (NOT GMX_BUILD_MDRUN_ONLY)
 102     add_subdirectory(legacyheaders)
 103     add_subdirectory(gmxana)
 104     add_subdirectory(statistics)
 105     add_subdirectory(analysisdata)
 106     add_subdirectory(selection)
 107     add_subdirectory(trajectoryanalysis)
 108     add_subdirectory(tools)
 109 endif()
 110
 111 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES})
 112
 113 # This would be the standard way to include thread_mpi, but
 114 # we want libgromacs to link the functions directly
 115 #if(GMX_THREAD_MPI)
 116 #    add_subdirectory(thread_mpi)
 117 #endif()
 118 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 119
 120 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 121 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 122
 123 set(LIBGROMACS_HEADERS
 124     analysisdata.h
 125     commandline.h
 126     options.h
 127     selection.h
 128     trajectoryanalysis.h
 129     utility.h)
 130 configure_file(version.h.cmakein version.h)
 131 gmx_install_headers("" ${LIBGROMACS_HEADERS})
 132 gmx_install_headers("" ${CMAKE_CURRENT_BINARY_DIR}/version.h)
 133
 134 # This code is here instead of utility/CMakeLists.txt, because CMake
 135 # custom commands and source file properties can only be set in the directory
 136 # that contains the target that uses them.
 137 # TODO: Generate a header instead that can be included from baseversion.c.
 138 # That probably simplifies things somewhat.
 139 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 140 gmx_configure_version_file(
 141     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 142     REMOTE_HASH SOURCE_FILE)
 143 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 144
 145 # apply gcc 4.4.x bug workaround
 146 if(GMX_USE_GCC44_BUG_WORKAROUND)
 147    include(gmxGCC44O3BugWorkaround)
 148    gmx_apply_gcc44_bug_workaround("gmxlib/bondfree.c")
 149    gmx_apply_gcc44_bug_workaround("mdlib/force.c")
 150    gmx_apply_gcc44_bug_workaround("mdlib/constr.c")
 151 endif()
 152
 153 if (GMX_GPU)
 154     cuda_add_library(libgromacs ${LIBGROMACS_SOURCES}
 155             OPTIONS
 156             RELWITHDEBINFO -g
 157             DEBUG -g -D_DEBUG_=1)
 158 else()
 159     add_library(libgromacs ${LIBGROMACS_SOURCES})
 160 endif()
 161
 162 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 163 # is a generated source file. These are awkward to suppress inline, so
 164 # we do it in the compilation command (after testing that the compiler
 165 # supports the suppressions). Setting the properties only works after
 166 # the related target has been created, e.g. after when the file is
 167 # used with add_library().
 168 include(CheckCXXCompilerFlag)
 169 check_cxx_compiler_flag(-Wno-unused-parameter HAS_NO_UNUSED_PARAMETER)
 170 if (HAS_NO_UNUSED_PARAMETER)
 171     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter")
 172 endif()
 173 check_cxx_compiler_flag(-Wno-deprecated-register HAS_NO_DEPRECATED_REGISTER)
 174 if (HAS_NO_DEPRECATED_REGISTER)
 175     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated-register")
 176 else()
 177     check_cxx_compiler_flag(-Wno-deprecated HAS_NO_DEPRECATED)
 178     if (HAS_NO_DEPRECATED)
 179         set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-deprecated")
 180     endif()
 181 endif()
 182 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 183
 184 target_link_libraries(libgromacs
 185                       ${EXTRAE_LIBRARIES}
 186                       ${GMX_EXTRA_LIBRARIES}
 187                       ${TNG_IO_LIBRARIES}
 188                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 189                       ${XML_LIBRARIES}
 190                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS})
 191 set_target_properties(libgromacs PROPERTIES
 192                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 193                       SOVERSION ${LIBRARY_SOVERSION}
 194                       VERSION ${LIBRARY_VERSION}
 195                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 196
 197 # Only install the library in mdrun-only mode if it is actually necessary
 198 # for the binary
 199 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 200     install(TARGETS libgromacs
 201             EXPORT libgromacs
 202             DESTINATION ${LIB_INSTALL_DIR}
 203             COMPONENT libraries)
 204 endif()
 205
 206 if (NOT GMX_BUILD_MDRUN_ONLY)
 207     include(InstallLibInfo.cmake)
 208 endif()
 209
 210 if (INSTALL_CUDART_LIB) #can be set manual by user
 211     if (GMX_GPU)
 212         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 213             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 214             if(IS_CUDART) #libcuda should not be installed
 215                 #install also name-links (linker uses those)
 216                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 217                 install(FILES ${CUDA_LIBS} DESTINATION
 218                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 219             endif()
 220         endforeach()
 221     else()
 222         message(WARNING "INSTALL_CUDART_LIB only makes sense with GMX_GPU")
 223     endif()
 224 endif()