src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  64 # approach, at least for the build system. See Issue #2530
  65 function (gmx_compile_cpp_as_cuda)
  66     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  67 endfunction ()
  68
  69 # Permit the configuration to disable compiling the many nbnxm kernels
  70 # and others involved in force calculations. Currently only
  71 # short-ranged and bonded kernels are disabled this way, but in future
  72 # others may be appropriate. Thus the cmake option is not specific to
  73 # nbnxm module.
  74 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  75 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  76
  77 # Add these contents first because linking their tests can take a lot
  78 # of time, so we want lots of parallel work still available after
  79 # linking starts.
  80 add_subdirectory(utility)
  81 # Add normal contents
  82 add_subdirectory(gmxlib)
  83 add_subdirectory(mdlib)
  84 add_subdirectory(applied_forces)
  85 add_subdirectory(listed_forces)
  86 add_subdirectory(nbnxm)
  87 add_subdirectory(commandline)
  88 add_subdirectory(domdec)
  89 add_subdirectory(ewald)
  90 add_subdirectory(fft)
  91 add_subdirectory(gpu_utils)
  92 add_subdirectory(hardware)
  93 add_subdirectory(linearalgebra)
  94 add_subdirectory(math)
  95 add_subdirectory(mdrun)
  96 add_subdirectory(mdrunutility)
  97 add_subdirectory(mdspan)
  98 add_subdirectory(mdtypes)
  99 add_subdirectory(onlinehelp)
 100 add_subdirectory(options)
 101 add_subdirectory(pbcutil)
 102 add_subdirectory(random)
 103 add_subdirectory(restraint)
 104 add_subdirectory(tables)
 105 add_subdirectory(taskassignment)
 106 add_subdirectory(timing)
 107 add_subdirectory(topology)
 108 add_subdirectory(trajectory)
 109 add_subdirectory(swap)
 110 add_subdirectory(essentialdynamics)
 111 add_subdirectory(pulling)
 112 add_subdirectory(awh)
 113 add_subdirectory(simd)
 114 add_subdirectory(imd)
 115 add_subdirectory(compat)
 116 add_subdirectory(mimic)
 117 add_subdirectory(modularsimulator)
 118 if (NOT GMX_BUILD_MDRUN_ONLY)
 119     add_subdirectory(gmxana)
 120     add_subdirectory(gmxpreprocess)
 121     add_subdirectory(correlationfunctions)
 122     add_subdirectory(statistics)
 123     add_subdirectory(analysisdata)
 124     add_subdirectory(coordinateio)
 125     add_subdirectory(trajectoryanalysis)
 126     add_subdirectory(energyanalysis)
 127     add_subdirectory(tools)
 128 endif()
 129
 130 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 131 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 132
 133 # This would be the standard way to include thread_mpi, but
 134 # we want libgromacs to link the functions directly
 135 #if(GMX_THREAD_MPI)
 136 #    add_subdirectory(thread_mpi)
 137 #endif()
 138 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 139 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 140 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 141 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 142 gmx_target_compile_options(thread_mpi)
 143 if (WIN32)
 144     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 145 endif()
 146 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 147
 148 configure_file(version.h.cmakein version.h)
 149 if(GMX_INSTALL_LEGACY_API)
 150   install(FILES
 151           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 152           DESTINATION include/gromacs)
 153 endif()
 154
 155 # This code is here instead of utility/CMakeLists.txt, because CMake
 156 # custom commands and source file properties can only be set in the directory
 157 # that contains the target that uses them.
 158 # TODO: Generate a header instead that can be included from baseversion.cpp.
 159 # That probably simplifies things somewhat.
 160 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 161 gmx_configure_version_file(
 162     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 163     REMOTE_HASH
 164     EXTRA_VARS
 165         GMX_SOURCE_DOI
 166         GMX_RELEASE_HASH
 167         GMX_SOURCE_HASH
 168         )
 169 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 170
 171 # Mark some shared GPU implementation files to compile with CUDA if needed
 172 if (GMX_USE_CUDA)
 173     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 174     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 175 endif()
 176
 177 # set up CUDA compilation with clang
 178 if (GMX_CLANG_CUDA)
 179     foreach (_file ${LIBGROMACS_SOURCES})
 180         get_filename_component(_ext ${_file} EXT)
 181         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 182         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 183             gmx_compile_cuda_file_with_clang(${_file})
 184         endif()
 185     endforeach()
 186 endif()
 187
 188 if (GMX_USE_CUDA)
 189     # Work around FindCUDA that prevents using target_link_libraries()
 190     # with keywords otherwise...
 191     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 192     if (NOT GMX_CLANG_CUDA)
 193         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 194     else()
 195         add_library(libgromacs ${LIBGROMACS_SOURCES})
 196     endif()
 197     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 198 else()
 199     add_library(libgromacs ${LIBGROMACS_SOURCES})
 200 endif()
 201
 202 # Add these contents first because linking their tests can take a lot
 203 # of time, so we want lots of parallel work still available after
 204 # linking starts.
 205 add_subdirectory(fileio)
 206 add_subdirectory(selection)
 207
 208 # Suppress a warning about our abuse of t_inputrec
 209 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 210
 211 # Handle the object libraries that contain the source file
 212 # dependencies that need special handling because they are generated
 213 # or external code.
 214 foreach(object_library ${libgromacs_object_library_dependencies})
 215     if (BUILD_SHARED_LIBS)
 216         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 217     endif()
 218     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 219
 220     # Add the sources from the object libraries to the main library.
 221     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 222 endforeach()
 223 gmx_target_compile_options(libgromacs)
 224 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 225 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 226
 227 if (GMX_USE_OPENCL)
 228     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 229     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 230
 231     # Default to using clFFT found on the system
 232     # switch to quiet at the second run.
 233     if (DEFINED clFFT_LIBRARY)
 234         set (clFFT_FIND_QUIETLY TRUE)
 235     endif()
 236     find_package(clFFT)
 237     if (NOT clFFT_FOUND)
 238         if (GMX_EXTERNAL_CLFFT)
 239             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 240         endif()
 241
 242         if(MSVC)
 243             message(FATAL_ERROR
 244 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 245 requires clFFT, which was not found on your system. GROMACS does bundle
 246 clFFT to help with building for OpenCL, but that clFFT has not yet been
 247 ported to the more recent versions of that compiler that GROMACS itself
 248 requires. Thus for now, OpenCL is not available with MSVC and the internal
 249 build of clFFT in GROMACS 2019. Either change compiler, try installing
 250 a clFFT package, or use the latest GROMACS 2018 point release.")
 251         endif()
 252
 253         # Fall back on the internal version
 254         set (_clFFT_dir ../external/clFFT/src)
 255         add_subdirectory(${_clFFT_dir} clFFT-build)
 256         target_sources(libgromacs PRIVATE
 257             $<TARGET_OBJECTS:clFFT>
 258         )
 259         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 260         # Use the magic variable for how to link any library needed for
 261         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 262         # (e.g. Windows, BSD, Mac).
 263         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 264     else()
 265         target_link_libraries(libgromacs PRIVATE clFFT)
 266     endif()
 267 endif()
 268
 269 # Permit GROMACS code to include externally developed headers, such as
 270 # the functionality from the nonstd project that we use for
 271 # gmx::compat::optional. These are included as system headers so that
 272 # no warnings are issued from them.
 273 #
 274 # TODO Perhaps generalize this for all headers from src/external
 275 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 276
 277 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 278     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 279     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 280     # with the SIMD_AVX_512_CXX_FLAGS flags.
 281     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 282 endif()
 283
 284 gmx_setup_tng_for_libgromacs()
 285
 286 target_link_libraries(libgromacs
 287                       PRIVATE
 288                       ${EXTRAE_LIBRARIES}
 289                       ${GMX_EXTRA_LIBRARIES}
 290                       ${GMX_COMMON_LIBRARIES}
 291                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 292                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 293                       ${OpenCL_LIBRARIES}
 294                       $<$<PLATFORM_ID:SunOS>:socket>
 295                       PUBLIC
 296                       ${GMX_PUBLIC_LIBRARIES}
 297                       )
 298 if (GMX_OPENMP)
 299     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 300 endif()
 301 set_target_properties(libgromacs PROPERTIES
 302                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 303                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 304                       VERSION ${LIBRARY_VERSION}
 305                       )
 306
 307 gmx_manage_lmfit()
 308 target_link_libraries(libgromacs PRIVATE lmfit)
 309
 310 # Make sure we fix "everything" found by more recent versions of clang.
 311 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 312    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 313 endif()
 314 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 315    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 316      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 317      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 318      /wd6001  #unitialized memory
 319      /wd6011  #derefencing NULL
 320      /wd6053  #prior call not zero-terminate
 321      /wd6054  #might not be zero-terminated
 322      /wd6385  #reading invalid data
 323      /wd6386  #buffer overrun
 324      /wd6387  #could be '0'
 325      /wd28199 #uninitialized memory
 326      # For compile time constant (e.g. templates) the following warnings have flase postives
 327      /wd6239  #(<non-zero> && <expr>)
 328      /wd6240  #(<expr> && <non-zero>)
 329      /wd6294  #Ill-defined for-loop
 330      /wd6326  #comparison of constant with other constant
 331      /wd28020 #expression involving paramter is not true
 332      # Misc
 333      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 334      /wd6993  #OpenMP ignored
 335      #TODO
 336      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 337      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 338      /wd6246  #hides declaration
 339      >
 340    )
 341 endif()
 342
 343 if (GMX_CLANG_TIDY)
 344    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 345        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 346 endif()
 347
 348 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 349 # and we know they are not real issues. So we only check that it can compile without error
 350 # but ignore all warnings.
 351 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 352     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 353 endif()
 354
 355 # Only install the library in mdrun-only mode if it is actually necessary
 356 # for the binary
 357 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 358     install(TARGETS libgromacs
 359             COMPONENT libraries
 360             EXPORT libgromacs
 361             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 362             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 363             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 364             INCLUDES DESTINATION include)
 365     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 366     add_library(Gromacs::libgromacs ALIAS libgromacs)
 367 endif()
 368
 369 if (NOT GMX_BUILD_MDRUN_ONLY)
 370     include(InstallLibInfo.cmake)
 371 endif()
 372
 373 # Technically, the user could want to do this for an OpenCL build
 374 # using the CUDA runtime, but currently there's no reason to want to
 375 # do that.
 376 if (INSTALL_CUDART_LIB) #can be set manual by user
 377     if (GMX_USE_CUDA)
 378         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 379             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 380             if(IS_CUDART) #libcuda should not be installed
 381                 #install also name-links (linker uses those)
 382                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 383                 install(FILES ${CUDA_LIBS} DESTINATION
 384                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 385             endif()
 386         endforeach()
 387     else()
 388         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 389     endif()
 390 endif()
 391
 392 if(GMX_USE_OPENCL)
 393     # Install the utility headers
 394     file(GLOB OPENCL_INSTALLED_FILES
 395         gpu_utils/vectype_ops.clh
 396         gpu_utils/device_utils.clh
 397         )
 398     install(FILES ${OPENCL_INSTALLED_FILES}
 399         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 400         COMPONENT libraries)
 401     file(GLOB OPENCL_INSTALLED_FILES
 402         pbcutil/ishift.h
 403         )
 404     install(FILES ${OPENCL_INSTALLED_FILES}
 405         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 406         COMPONENT libraries)
 407
 408     # Install the NBNXM source and headers
 409     file(GLOB OPENCL_INSTALLED_FILES
 410         nbnxm/constants.h
 411         )
 412     install(FILES ${OPENCL_INSTALLED_FILES}
 413         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 414         COMPONENT libraries)
 415     file(GLOB OPENCL_INSTALLED_FILES
 416         nbnxm/opencl/nbnxm_ocl_kernels.cl
 417         nbnxm/opencl/nbnxm_ocl_kernel.clh
 418         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 419         nbnxm/opencl/nbnxm_ocl_kernels.clh
 420         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 421         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 422         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 423         nbnxm/opencl/nbnxm_ocl_consts.h
 424         )
 425     install(FILES ${OPENCL_INSTALLED_FILES}
 426         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 427         COMPONENT libraries)
 428
 429     # Install the PME source and headers
 430     file(GLOB OPENCL_INSTALLED_FILES
 431         ewald/pme_spread.clh
 432         ewald/pme_solve.clh
 433         ewald/pme_gather.clh
 434         ewald/pme_gpu_utils.clh
 435         ewald/pme_program.cl
 436         ewald/pme_gpu_types.h
 437         )
 438     install(FILES ${OPENCL_INSTALLED_FILES}
 439         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 440         COMPONENT libraries)
 441 endif()