src/gmxlib/CMakeLists.txt

   1 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   2
   3
   4 # add target that generates version.c every time a make is run
   5 # only do this if we generate the version
   6 if(USE_VERSION_H)
   7     add_custom_target(gmx_version ALL
   8             COMMAND ${CMAKE_COMMAND}
   9                 -D GIT_EXECUTABLE="${GIT_EXECUTABLE}"
  10                 -D GIT_VERSION="${GIT_VERSION}"
  11                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  12                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  13                 -D VERSION_C_CMAKEIN="${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein"
  14                 -D VERSION_C_OUT="${CMAKE_CURRENT_BINARY_DIR}/version.c"
  15                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  16             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src/gmxlib
  17             DEPENDS ${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein
  18             COMMENT "Generating version information")
  19 endif()
  20
  21 # The nonbonded directory contains subdirectories that are only
  22 # conditionally built, so we cannot use a GLOB_RECURSE here.
  23 file(GLOB GMXLIB_SOURCES *.c
  24      selection/*.c trajana/*.c
  25      statistics/*.c nonbonded/*.c nonbonded/nb_kernel_c/*.c
  26      nonbonded/nb_kernel_adress_c/*.c)
  27
  28 if(NOT GMX_USE_PLUGINS)
  29   list(REMOVE_ITEM GMXLIB_SOURCES vmdio.c vmddlopen.c)
  30 endif()
  31
  32 # This source file is generated
  33 file(GLOB VERSION_SOURCE version.c)
  34
  35 if(VERSION_SOURCE)
  36         list(REMOVE_ITEM GMXLIB_SOURCES ${VERSION_SOURCE})
  37 endif(VERSION_SOURCE)
  38
  39 # add version.c to the list of sources and tell cmake that it is generated
  40 if(USE_VERSION_H)
  41 LIST(APPEND GMXLIB_SOURCES ${CMAKE_CURRENT_BINARY_DIR}/version.c) # auto-generated
  42 set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/version.c
  43                 PROPERTIES GENERATED true)
  44 endif()
  45
  46 if(GMX_DOUBLE)
  47   set(SSETYPE sse2)
  48 else()
  49   set(SSETYPE sse)
  50 endif()
  51
  52 if(GMX_IA32_ASM)
  53   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_ia32_${SSETYPE}/*.c)
  54   if(GMX_ASM_USEASM_NASM)
  55     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*intel_syntax*.s)
  56   else()
  57     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_ia32_${SSETYPE}/*asm.s)
  58   endif()
  59 endif(GMX_IA32_ASM)
  60
  61 if(GMX_X86_64_ASM)
  62   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_x86_64_${SSETYPE}/*.c)
  63   if(GMX_ASM_USEASM_NASM)
  64     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*intel_syntax*.s)
  65   else()
  66     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_x86_64_${SSETYPE}/*asm.s)
  67   endif()
  68 endif(GMX_X86_64_ASM)
  69
  70 if(GMX_FORTRAN)
  71   if (GMX_DOUBLE)
  72     file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_f77_double/*.[cf])
  73   else(GMX_DOUBLE)
  74     file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_f77_single/*.[cf])
  75   endif(GMX_DOUBLE)
  76 endif(GMX_FORTRAN)
  77
  78 if(GMX_POWER6)
  79   file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_power6/*.[cF])
  80 endif(GMX_POWER6)
  81
  82 if(GMX_BLUEGENE)
  83   file(GLOB GMX_BLUEGENE_C_SRC nonbonded/nb_kernel_bluegene/*.c)
  84 endif(GMX_BLUEGENE)
  85
  86 if(GMX_PPC_ALTIVEC)
  87   file(GLOB GMX_PPC_ALTIVEC_SRC nonbonded/nb_kernel_ppc_altivec/*.c)
  88 endif(GMX_PPC_ALTIVEC)
  89
  90 if(NOT GMX_EXTERNAL_BLAS)
  91   file(GLOB BLAS_SOURCES gmx_blas/*.c)
  92 endif(NOT GMX_EXTERNAL_BLAS)
  93
  94 if(NOT GMX_EXTERNAL_LAPACK)
  95   file(GLOB LAPACK_SOURCES gmx_lapack/*.c)
  96 endif(NOT GMX_EXTERNAL_LAPACK)
  97
  98 # This would be the standard way to include thread_mpi, but we want libgmx
  99 # to link the functions directly
 100 #if(GMX_THREADS)
 101 #    add_subdirectory(thread_mpi)
 102 #endif(GMX_THREADS)
 103 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 104
 105 # Files called xxx_test.c are test drivers with a main() function for module xxx.c,
 106 # so they should not be included in the library
 107 file(GLOB_RECURSE NOT_GMXLIB_SOURCES *_test.c *\#*)
 108 list(REMOVE_ITEM GMXLIB_SOURCES ${NOT_GMXLIB_SOURCES})
 109 # Selection has test_ instead of _test.
 110 file(GLOB SELECTION_TEST selection/test*)
 111 list(REMOVE_ITEM GMXLIB_SOURCES ${SELECTION_TEST})
 112
 113 # only fiddle with assembly kernels if we're not doing OpenMM build
 114 if(NOT GMX_OPENMM)
 115 if(GMX_ASM_USEASM_NASM)
 116   enable_language(ASM_NASM)
 117
 118   # if NASM is used, we need a special build command for windows...
 119   FOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 120     GET_FILENAME_COMPONENT(FILE_BASE ${SRC} NAME_WE)
 121     SET(OBJ ${CMAKE_CURRENT_BINARY_DIR}/${FILE_BASE}${CMAKE_C_OUTPUT_EXTENSION})
 122
 123     ADD_CUSTOM_COMMAND(OUTPUT ${OBJ}
 124                        MAIN_DEPENDENCY ${SRC}
 125                        COMMAND ${CMAKE_ASM_NASM_COMPILER} -f ${CMAKE_ASM_NASM_OBJECT_FORMAT} -o ${OBJ} ${SRC})
 126
 127     SET(ALL_ASM_OBJS ${ALL_ASM_OBJS} ${OBJ})
 128   ENDFOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 129   set(GMX_SSEKERNEL_ASM_SRC ${ALL_ASM_OBJS})
 130
 131 else(GMX_ASM_USEASM_NASM)
 132
 133   enable_language(ASM-ATT)
 134   SET(CMAKE_ASM-ATT_COMPILER ${CMAKE_C_COMPILER})
 135   if(GMX_IA32_ASM)
 136     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m32")
 137   else()
 138     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m64")
 139   endif()
 140
 141 endif(GMX_ASM_USEASM_NASM)
 142 endif(NOT GMX_OPENMM)
 143
 144 add_library(gmx ${GMXLIB_SOURCES} ${BLAS_SOURCES} ${LAPACK_SOURCES} ${GMX_SSEKERNEL_C_SRC} ${GMX_SSEKERNEL_ASM_SRC} ${FORTRAN_SOURCES} ${GMX_BLUEGENE_C_SRC} ${GMX_PPC_ALTIVEC_SRC} ${THREAD_MPI_SRC})
 145 target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES}  ${THREAD_LIB})
 146 if(USE_VERSION_H)
 147         add_dependencies(gmx gmx_version)
 148 endif()
 149 set_target_properties(gmx PROPERTIES OUTPUT_NAME "gmx${GMX_LIBS_SUFFIX}" SOVERSION ${SOVERSION} INSTALL_NAME_DIR "${LIB_INSTALL_DIR}")
 150
 151 install(TARGETS gmx DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 152
 153 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgmx.pc.cmakein ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc @ONLY)
 154 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc
 155         DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 156         RENAME "libgmx${GMX_LIBS_SUFFIX}.pc"
 157         COMPONENT development)
 158