src/gmxlib/CMakeLists.txt

   1 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   2
   3
   4 # add target that generates version.c every time a make is run
   5 # only do this if we generate the version
   6 if(USE_VERSION_H)
   7     add_custom_target(gmx_version ALL
   8             COMMAND ${CMAKE_COMMAND}
   9                 -D Git_EXECUTABLE="${Git_EXECUTABLE}"
  10                 -D Git_VERSION="${Git_VERSION}"
  11                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  12                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  13                 -D VERSION_C_CMAKEIN="${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein"
  14                 -D VERSION_C_OUT="${CMAKE_CURRENT_BINARY_DIR}/version.c"
  15                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  16             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src/gmxlib
  17             DEPENDS ${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein
  18             COMMENT "Generating version information")
  19 endif()
  20
  21 # The nonbonded directory contains subdirectories that are only
  22 # conditionally built, so we cannot use a GLOB_RECURSE here.
  23 file(GLOB GMXLIB_SOURCES *.c
  24      selection/*.c trajana/*.c
  25      statistics/*.c nonbonded/*.c nonbonded/nb_kernel_c/*.c)
  26
  27 # This source file is generated
  28 file(GLOB VERSION_SOURCE version.c)
  29
  30 if(VERSION_SOURCE)
  31         list(REMOVE_ITEM GMXLIB_SOURCES ${VERSION_SOURCE})
  32 endif(VERSION_SOURCE)
  33
  34 # add version.c to the list of sources and tell cmake that it is generated
  35 if(USE_VERSION_H)
  36 LIST(APPEND GMXLIB_SOURCES ${CMAKE_CURRENT_BINARY_DIR}/version.c) # auto-generated
  37 set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/version.c
  38                 PROPERTIES GENERATED true)
  39 endif()
  40
  41 if(GMX_DOUBLE)
  42   set(SSETYPE sse2)
  43 else()
  44   set(SSETYPE sse)
  45 endif()
  46
  47 if(GMX_IA32_ASM)
  48   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_ia32_${SSETYPE}/*.c)
  49   if(GMX_ASM_USEASM-NASM)
  50     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*intel_syntax*.s)
  51   else()
  52     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_ia32_${SSETYPE}/*asm.s)
  53   endif()
  54 endif(GMX_IA32_ASM)
  55
  56 if(GMX_X86_64_ASM)
  57   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_x86_64_${SSETYPE}/*.c)
  58   if(GMX_ASM_USEASM-NASM)
  59     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*intel_syntax*.s)
  60   else()
  61     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_x86_64_${SSETYPE}/*asm.s)
  62   endif()
  63 endif(GMX_X86_64_ASM)
  64
  65 if(GMX_FORTRAN)
  66   if (GMX_DOUBLE)
  67     file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_f77_double/*.[cf])
  68   else(GMX_DOUBLE)
  69     file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_f77_single/*.[cf])
  70   endif(GMX_DOUBLE)
  71 endif(GMX_FORTRAN)
  72
  73 if(GMX_POWER6)
  74   file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_power6/*.[cF])
  75 endif(GMX_POWER6)
  76
  77 if(GMX_BLUEGENE)
  78   file(GLOB GMX_BLUEGENE_C_SRC nonbonded/nb_kernel_bluegene/*.c)
  79 endif(GMX_BLUEGENE)
  80
  81 if(NOT GMX_EXTERNAL_BLAS)
  82   file(GLOB BLAS_SOURCES gmx_blas/*.c)
  83 endif(NOT GMX_EXTERNAL_BLAS)
  84
  85 if(NOT GMX_EXTERNAL_LAPACK)
  86   file(GLOB LAPACK_SOURCES gmx_lapack/*.c)
  87 endif(NOT GMX_EXTERNAL_LAPACK)
  88
  89 # This would be the standard way to include thread_mpi, but we want libgmx
  90 # to link the functions directly
  91 #if(GMX_THREADS)
  92 #    add_subdirectory(thread_mpi)
  93 #endif(GMX_THREADS)
  94 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
  95
  96 # Files called xxx_test.c are test drivers with a main() function for module xxx.c,
  97 # so they should not be included in the library
  98 file(GLOB_RECURSE NOT_GMXLIB_SOURCES *_test.c *\#*)
  99 list(REMOVE_ITEM GMXLIB_SOURCES ${NOT_GMXLIB_SOURCES})
 100 # Selection has test_ instead of _test.  Removing here for special case, perhaps make general?
 101 if(GMX_FAHCORE)
 102     file(GLOB SELECTION_TEST selection/test*)
 103     list(REMOVE_ITEM GMXLIB_SOURCES ${SELECTION_TEST})
 104 endif(GMX_FAHCORE)
 105
 106 # only fiddle with assembly kernels if we're not doing OpenMM build
 107 if(NOT GMX_OPENMM)
 108 if(GMX_ASM_USEASM-NASM)
 109   enable_language(ASM-NASM)
 110
 111   # if NASM is used, we need a special build command for windows...
 112   FOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 113     GET_FILENAME_COMPONENT(FILE_BASE ${SRC} NAME_WE)
 114     SET(OBJ ${CMAKE_CURRENT_BINARY_DIR}/${FILE_BASE}${CMAKE_C_OUTPUT_EXTENSION})
 115
 116     ADD_CUSTOM_COMMAND(OUTPUT ${OBJ}
 117                        MAIN_DEPENDENCY ${SRC}
 118                        COMMAND ${CMAKE_ASM-NASM_COMPILER} -f ${CMAKE_ASM-NASM_OBJECT_FORMAT} -o ${OBJ} ${SRC})
 119
 120     SET(ALL_ASM_OBJS ${ALL_ASM_OBJS} ${OBJ})
 121   ENDFOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 122   set(GMX_SSEKERNEL_ASM_SRC ${ALL_ASM_OBJS})
 123
 124 else(GMX_ASM_USEASM-NASM)
 125
 126   enable_language(ASM-ATT)
 127   SET(CMAKE_ASM-ATT_COMPILER ${CMAKE_C_COMPILER})
 128   if(GMX_IA32_ASM)
 129     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m32")
 130   else()
 131     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m64")
 132   endif()
 133
 134 endif(GMX_ASM_USEASM-NASM)
 135 endif(NOT GMX_OPENMM)
 136
 137 add_library(gmx ${GMXLIB_SOURCES} ${BLAS_SOURCES} ${LAPACK_SOURCES} ${GMX_SSEKERNEL_C_SRC} ${GMX_SSEKERNEL_ASM_SRC} ${FORTRAN_SOURCES} ${GMX_BLUEGENE_C_SRC} ${THREAD_MPI_SRC})
 138 target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES}  ${THREAD_LIB})
 139 if(USE_VERSION_H)
 140         add_dependencies(gmx gmx_version)
 141 endif()
 142 set_target_properties(gmx PROPERTIES OUTPUT_NAME "gmx${GMX_LIBS_SUFFIX}" SOVERSION ${SOVERSION} INSTALL_NAME_DIR "${LIB_INSTALL_DIR}")
 143
 144 install(TARGETS gmx DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 145
 146 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgmx.pc.cmakein ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc @ONLY)
 147 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc
 148         DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 149         RENAME "libgmx${GMX_LIBS_SUFFIX}.pc"
 150         COMPONENT development)
 151