src/gmxlib/CMakeLists.txt

   1 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   2
   3
   4 # add target that generates version.c every time a make is run
   5 # only do this if we generate the version
   6 if(USE_VERSION_H)
   7     add_custom_target(gmx_version ALL
   8             COMMAND ${CMAKE_COMMAND}
   9                 -D Git_EXECUTABLE="${Git_EXECUTABLE}"
  10                 -D Git_VERSION="${Git_VERSION}"
  11                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  12                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  13                 -D VERSION_C_CMAKEIN="${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein"
  14                 -D VERSION_C_OUT="${CMAKE_CURRENT_BINARY_DIR}/version.c"
  15                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  16             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src/gmxlib
  17             DEPENDS ${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein
  18             COMMENT "Generating version information")
  19 endif()
  20
  21 # The nonbonded directory contains subdirectories that are only
  22 # conditionally built, so we cannot use a GLOB_RECURSE here.
  23 file(GLOB GMXLIB_SOURCES *.c
  24      selection/*.c trajana/*.c
  25      statistics/*.c nonbonded/*.c nonbonded/nb_kernel_c/*.c)
  26
  27 # This source file is generated
  28 file(GLOB VERSION_SOURCE version.c)
  29
  30 if(VERSION_SOURCE)
  31         list(REMOVE_ITEM GMXLIB_SOURCES ${VERSION_SOURCE})
  32 endif(VERSION_SOURCE)
  33
  34 # add version.c to the list of sources and tell cmake that it is generated
  35 if(USE_VERSION_H)
  36 LIST(APPEND GMXLIB_SOURCES ${CMAKE_CURRENT_BINARY_DIR}/version.c) # auto-generated
  37 set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/version.c
  38                 PROPERTIES GENERATED true)
  39 endif()
  40
  41 if(GMX_DOUBLE)
  42   set(SSETYPE sse2)
  43 else()
  44   set(SSETYPE sse)
  45 endif()
  46
  47 if(GMX_IA32_ASM)
  48   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_ia32_${SSETYPE}/*.c)
  49   if(GMX_ASM_USEASM-NASM)
  50     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*intel_syntax*.s)
  51   else()
  52     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_ia32_${SSETYPE}/*asm.s)
  53   endif()
  54 endif(GMX_IA32_ASM)
  55
  56 if(GMX_X86_64_ASM)
  57   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_x86_64_${SSETYPE}/*.c)
  58   if(GMX_ASM_USEASM-NASM)
  59     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*intel_syntax*.s)
  60   else()
  61     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_x86_64_${SSETYPE}/*asm.s)
  62   endif()
  63 endif(GMX_X86_64_ASM)
  64
  65 if(NOT GMX_EXTERNAL_BLAS)
  66   file(GLOB BLAS_SOURCES gmx_blas/*.c)
  67 endif(NOT GMX_EXTERNAL_BLAS)
  68
  69 if(NOT GMX_EXTERNAL_LAPACK)
  70   file(GLOB LAPACK_SOURCES gmx_lapack/*.c)
  71 endif(NOT GMX_EXTERNAL_LAPACK)
  72
  73 # This would be the standard way to include thread_mpi, but we want libgmx
  74 # to link the functions directly
  75 #if(GMX_THREADS)
  76 #    add_subdirectory(thread_mpi)
  77 #endif(GMX_THREADS)
  78 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
  79
  80 # Files called xxx_test.c are test drivers with a main() function for module xxx.c,
  81 # so they should not be included in the library
  82 file(GLOB_RECURSE NOT_GMXLIB_SOURCES *_test.c *\#*)
  83 list(REMOVE_ITEM GMXLIB_SOURCES ${NOT_GMXLIB_SOURCES})
  84 # Selection has test_ instead of _test.  Removing here for special case, perhaps make general?
  85 if(GMX_FAHCORE)
  86     file(GLOB SELECTION_TEST selection/test*)
  87     list(REMOVE_ITEM GMXLIB_SOURCES ${SELECTION_TEST})
  88 endif(GMX_FAHCORE)
  89
  90 # only fiddle with assembly kernels if we're not doing OpenMM build
  91 if(NOT GMX_OPENMM)
  92 if(GMX_ASM_USEASM-NASM)
  93   enable_language(ASM-NASM)
  94
  95   # if NASM is used, we need a special build command for windows...
  96   FOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
  97     GET_FILENAME_COMPONENT(FILE_BASE ${SRC} NAME_WE)
  98     SET(OBJ ${CMAKE_CURRENT_BINARY_DIR}/${FILE_BASE}${CMAKE_C_OUTPUT_EXTENSION})
  99
 100     ADD_CUSTOM_COMMAND(OUTPUT ${OBJ}
 101                        MAIN_DEPENDENCY ${SRC}
 102                        COMMAND ${CMAKE_ASM-NASM_COMPILER} -f ${CMAKE_ASM-NASM_OBJECT_FORMAT} -o ${OBJ} ${SRC})
 103
 104     SET(ALL_ASM_OBJS ${ALL_ASM_OBJS} ${OBJ})
 105   ENDFOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 106   set(GMX_SSEKERNEL_ASM_SRC ${ALL_ASM_OBJS})
 107
 108 else(GMX_ASM_USEASM-NASM)
 109
 110   enable_language(ASM-ATT)
 111   SET(CMAKE_ASM-ATT_COMPILER ${CMAKE_C_COMPILER})
 112   if(GMX_IA32_ASM)
 113     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m32")
 114   else()
 115     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m64")
 116   endif()
 117
 118 endif(GMX_ASM_USEASM-NASM)
 119 endif(NOT GMX_OPENMM)
 120
 121 add_library(gmx ${GMXLIB_SOURCES} ${BLAS_SOURCES} ${LAPACK_SOURCES} ${GMX_SSEKERNEL_C_SRC} ${GMX_SSEKERNEL_ASM_SRC} ${THREAD_MPI_SRC})
 122 target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES}  ${THREAD_LIB})
 123 add_dependencies(gmx gmx_version)
 124 set_target_properties(gmx PROPERTIES OUTPUT_NAME "gmx${GMX_LIBS_SUFFIX}" SOVERSION ${SOVERSION})
 125
 126 install(TARGETS gmx DESTINATION ${LIB_INSTALL_DIR})
 127
 128 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgmx.pc.cmakein ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc @ONLY)
 129 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig RENAME "libgmx${GMX_LIBS_SUFFIX}.pc")
 130