src/external/gmock-1.7.0/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # As stated in README.Gromacs, this file is not part of GMock, but is written
  36 # specifically for the GROMACS build system from scratch.
  37
  38 include(CheckCXXCompilerFlag)
  39 check_cxx_compiler_flag("-Wno-unused-variable" HAS_NO_UNUSED_VARIABLE)
  40
  41 # Avoid compiler warnings with GCC 5, which doesn't like the way
  42 # Google Test makes int variables that hold the results of
  43 # value-parameterized test registration calls, and then doesn't use
  44 # them. Because these definitions are created by the
  45 # test-instantiation macros, there's no good way to suppress them;
  46 # we'd prefer to avoid modifying Google Test source, and don't wish to
  47 # embed compiler-specific suppressions in all our test-code source
  48 # files.
  49 #
  50 # TODO When updating the embedded Google Test version in future, check
  51 # if this is still needed
  52 #
  53 # TODO If other compilers start complaining similarly, consider a
  54 # unilateral suppression, like we use for the Google Mock source code
  55 # itself.
  56 if(CMAKE_COMPILER_IS_GNUCXX AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5")
  57     if(HAS_NO_UNUSED_VARIABLE)
  58         set(GMOCK_COMPILE_FLAGS "-Wno-unused-variable")
  59     endif()
  60 endif()
  61
  62 include(gmxGetGmockTupleWorkaround)
  63 get_gmock_tuple_workaround(GMOCK_COMPILE_DEFINITIONS)
  64
  65 # GTest/GMock suggest linking with pthreads when available for thread safety
  66 set(CMAKE_THREAD_PREFER_PTHREAD 1)
  67 find_package(Threads)
  68 set(PTHREADS_LIBRARIES)
  69 if (CMAKE_USE_PTHREADS_INIT)
  70     set(PTHREADS_LIBRARIES ${CMAKE_THREAD_LIBS_INIT})
  71 endif()
  72
  73 set(GMOCK_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  74 set(GTEST_DIR ${GMOCK_DIR}/gtest)
  75 set(GTEST_SOURCES ${GTEST_DIR}/src/gtest-all.cc)
  76 set(GMOCK_SOURCES ${GMOCK_DIR}/src/gmock-all.cc)
  77
  78 set(GTEST_INCLUDE_DIRS ${GTEST_DIR}/include)
  79 set(GMOCK_INCLUDE_DIRS ${GMOCK_DIR}/include ${GTEST_INCLUDE_DIRS})
  80
  81 include_directories(BEFORE ${GTEST_INCLUDE_DIRS})
  82 include_directories(BEFORE ${GTEST_DIR})
  83 include_directories(BEFORE ${GMOCK_INCLUDE_DIRS})
  84 include_directories(BEFORE ${GMOCK_DIR})
  85
  86 if (HAS_NO_UNUSED_VARIABLE)
  87     set_source_files_properties(${GTEST_SOURCES} PROPERTIES COMPILE_FLAGS "-Wno-unused-variable")
  88 endif()
  89
  90 add_library(gmock STATIC ${UNITTEST_TARGET_OPTIONS} ${GMOCK_SOURCES} ${GTEST_SOURCES})
  91 set_property(TARGET gmock APPEND PROPERTY COMPILE_DEFINITIONS
  92              "_GNU_SOURCE=1;${GMOCK_COMPILE_DEFINITIONS};GTEST_CAN_STREAM_RESULTS=0")
  93 set_property(TARGET gmock APPEND PROPERTY COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}")
  94
  95 set(GMOCK_LIBRARIES gmock ${PTHREADS_LIBRARIES} PARENT_SCOPE)
  96 set(GTEST_LIBRARIES ${GMOCK_LIBRARIES} PARENT_SCOPE)
  97 set(GMOCK_INCLUDE_DIRS ${GMOCK_INCLUDE_DIRS} PARENT_SCOPE)
  98 set(GTEST_INCLUDE_DIRS ${GTEST_INCLUDE_DIRS} PARENT_SCOPE)
  99 set(GMOCK_COMPILE_DEFINITIONS ${GMOCK_COMPILE_DEFINITIONS} PARENT_SCOPE)
 100 set(GMOCK_COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}" PARENT_SCOPE)