src/contrib/CMakeLists.txt

   1 set(CONTRIB_PROGRAMS
   2      #add here any programs you want to compile
   3
   4 )
   5
   6 # Uncomment the next line to build OpenMM:
   7 #option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (no longer supported" ON)
   8
   9 # At run time, you may need to set the environment variable
  10 # OPENMM_PLUGIN_DIR=PATH_TO_GROMACS/openmm/lib/plugins
  11 # to make things work
  12
  13 if(GMX_OPENMM)
  14     if(GMX_GPU)
  15         message(FATAL_ERROR "The OpenMM build is not compatible with the native GPU build")
  16     endif()
  17
  18     enable_language(CXX)
  19     set (GMX_BINARY_SUFFIX "-openmm")
  20     set (GMX_LIBS_SUFFIX "_openmm")
  21
  22 #######################################################################
  23 # Check for options incompatible with OpenMM build                    #
  24 #######################################################################
  25     # we'll use the built-in fft to avoid unnecessary dependencies
  26     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
  27     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
  28         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
  29         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
  30                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
  31     endif()
  32     if(GMX_MPI)
  33         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
  34     endif(GMX_MPI)
  35     if(GMX_THREAD_MPI)
  36         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
  37         set(GMX_THREAD_MPI OFF CACHE BOOL
  38                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
  39     endif(GMX_THREAD_MPI)
  40     if(GMX_OPENMP)
  41         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
  42         set(GMX_OPENMP OFF CACHE BOOL
  43             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
  44     endif()
  45     if(GMX_SOFTWARE_INVSQRT)
  46         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
  47                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
  48     endif(GMX_SOFTWARE_INVSQRT)
  49     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
  50     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
  51         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
  52         set(GMX_CPU_ACCELERATION "None" CACHE STRING
  53             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
  54     endif()
  55     if(GMX_FAHCORE)
  56         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
  57     endif(GMX_FAHCORE)
  58     if(GMX_DOUBLE)
  59         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
  60     endif()
  61
  62     set(CUDA_BUILD_EMULATION OFF)
  63     find_package(CUDA 3.1 REQUIRED)
  64     add_definitions(-DGMX_OPENMM)
  65     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
  66         set(CUDA_VERBOSE_BUILD ON)
  67     endif()
  68     list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/src/contrib)
  69     find_package(OpenMM)
  70
  71     # mark as advanced the unused variables
  72     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
  73         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
  74
  75 else(GMX_OPENMM)
  76
  77      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
  78         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
  79
  80 endif(GMX_OPENMM)
  81
  82 foreach(PROG ${CONTRIB_PROGRAMS})
  83         add_executable(${PROG} ${PROG}.c ${NGMX_COMMON_SOURCE})
  84         set_target_properties(${PROG} PROPERTIES OUTPUT_NAME "${PROG}${GMX_BINARY_SUFFIX}")
  85 endforeach(PROG)