src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 ######################################
  38 # Output compiler and CFLAGS used
  39 ######################################
  40 include(GetCompilerInfo.cmake)
  41 get_compiler_info(C BUILD_C_COMPILER)
  42 get_compiler_info(CXX BUILD_CXX_COMPILER)
  43 if(GMX_GPU_CUDA)
  44     if(NOT GMX_CLANG_CUDA)
  45         GMX_SET_CUDA_NVCC_FLAGS()
  46     endif()
  47
  48     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_DEVICE_COMPILER_FLAGS CUDA_HOST_COMPILER_FLAGS)
  49 endif()
  50
  51 # Make a file with compiler flags used for libgromacs for each
  52 # langauge and build configuration.  The one that corresponds to
  53 # CMAKE_BUILD_TYPE is #included into buildinfo.h and populates the
  54 # fields e.g. printed to the log file.
  55 file(GENERATE
  56     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/include/compilerflaginfo-$<CONFIG>-$<COMPILE_LANGUAGE>.h
  57     INPUT ${CMAKE_CURRENT_SOURCE_DIR}/compilerflaginfo.h.cmakein
  58     CONDITION $<CONFIG:${CMAKE_BUILD_TYPE}>
  59     )
  60
  61 ####
  62 list(APPEND IGNORED_CLANG_ALL_WARNINGS
  63     "-Wno-c++98-compat" "-Wno-c++98-compat-pedantic" #No intention of C++98 compability
  64     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  65     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  66     "-Wno-documentation-unknown-command" #Custom commands are used
  67     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  68     "-Wno-switch-enum" # default statement for enum is OK
  69
  70     # We need to use macros like
  71     # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  72     # if they don't have a semicolon after them, and might confuse
  73     # tools like IDEs also.
  74     "-Wno-extra-semi-stmt"
  75
  76     #Following ones are undecided/TODO
  77     "-Wno-disabled-macro-expansion"
  78     "-Wno-cast-align"
  79     "-Wno-reserved-id-macro"
  80     "-Wno-global-constructors"
  81     "-Wno-exit-time-destructors"
  82     "-Wno-unused-macros"
  83     "-Wno-weak-vtables"
  84     "-Wno-conditional-uninitialized"
  85     "-Wno-format-nonliteral"
  86     "-Wno-shadow"
  87     "-Wno-cast-qual"
  88     "-Wno-documentation"
  89     "-Wno-used-but-marked-unused"
  90     "-Wno-padded"
  91     "-Wno-float-equal"
  92     "-Wno-old-style-cast"
  93     "-Wno-conversion"
  94     "-Wno-double-promotion")
  95
  96 option(GMX_CLANG_TIDY "Use clang-tidy" OFF)
  97 if (GMX_CLANG_TIDY)
  98    if("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
  99    elseif("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithAssert")
 100    elseif("${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
 101    elseif("${CMAKE_BUILD_TYPE}" STREQUAL "ASAN")
 102    else()
 103        message(FATAL_ERROR "Can only use clang-tidy with build type containing asserts: Debug, RelWithAssert, RelWithDebInfo, ASAN.")
 104    endif()
 105    set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
 106    mark_as_advanced(CMAKE_EXPORT_COMPILE_COMMANDS)
 107    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
 108    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
 109        DOC "Path to clang-tidy executable")
 110    if(NOT CLANG_TIDY_EXE)
 111        message(FATAL_ERROR "clang-tidy not found.")
 112    endif()
 113    mark_as_advanced(CLANG_TIDY)
 114    mark_as_advanced(CLANG_TIDY_EXE)
 115 endif()
 116
 117 # Create a basic target for the `src` section of the build tree to capture
 118 # the library-level shared details through CMake infrastructure. It is not
 119 # installed or exported, so it must only be used as a PRIVATE dependency by
 120 # installed targets.
 121 # Initially, this is just an INTERFACE target to provide include directory.
 122 # It should also absorb global variables and compiler/linker details to be
 123 # provided as transitive usage requirements.
 124 # It could expand to aggregate the module targets in the future.
 125 add_library(common INTERFACE)
 126 target_include_directories(common INTERFACE
 127                            ${CMAKE_CURRENT_SOURCE_DIR}/include
 128                            ${CMAKE_CURRENT_BINARY_DIR}/include)
 129
 130 add_subdirectory(external)
 131
 132 if (BUILD_TESTING)
 133     if(NOT GMX_DEVELOPER_BUILD)
 134         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
 135     endif()
 136     include(testutils/TestMacros.cmake)
 137     add_subdirectory(testutils)
 138 endif()
 139
 140 add_subdirectory(gromacs)
 141 add_subdirectory(programs)
 142 add_subdirectory(api)
 143
 144 # Configure header files with configuration-specific values. This step
 145 # should follow all introspection e.g. looking for headers and
 146 # libraries. If not, cmake will need to change the contents of the
 147 # file upon subsequent runs of cmake. This can mean that
 148 #
 149 #  cmake $src && make && make test
 150 #
 151 # requires building all the source files that depend on the changed
 152 # header file in both of the make stages. That's slow, and is useless
 153 # busy work for ccache, too.
 154 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UPPER)
 155 configure_file(config.h.cmakein include/config.h)
 156 configure_file(gmxpre-config.h.cmakein include/gmxpre-config.h)
 157
 158 set(CMAKE_BUILD_CONFIGURATION_C_FLAGS   ${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UPPER}})
 159 set(CMAKE_BUILD_CONFIGURATION_CXX_FLAGS ${CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE_UPPER}})
 160 configure_file(buildinfo.h.cmakein include/buildinfo.h ESCAPE_QUOTES)