src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 ######################################
  36 # Output compiler and CFLAGS used
  37 ######################################
  38 include(GetCompilerInfo.cmake)
  39 get_compiler_info(C BUILD_C_COMPILER)
  40 get_compiler_info(CXX BUILD_CXX_COMPILER)
  41 if(GMX_USE_CUDA)
  42     if(NOT GMX_CLANG_CUDA)
  43         GMX_SET_CUDA_NVCC_FLAGS()
  44     endif()
  45
  46     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_DEVICE_COMPILER_FLAGS CUDA_HOST_COMPILER_FLAGS)
  47 endif()
  48
  49 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UPPER)
  50 configure_file(config.h.cmakein config.h)
  51 configure_file(gmxpre-config.h.cmakein gmxpre-config.h)
  52 configure_file(buildinfo.h.cmakein buildinfo.h ESCAPE_QUOTES)
  53 # Make a file with compiler flags used for libgromacs for each
  54 # langauge and build configuration.  The one that corresponds to
  55 # CMAKE_BUILD_TYPE is #included into buildinfo.h and populates the
  56 # fields e.g. printed to the log file.
  57 file(GENERATE
  58     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/compilerflaginfo-$<CONFIG>-$<COMPILE_LANGUAGE>.h
  59     INPUT ${CMAKE_CURRENT_SOURCE_DIR}/compilerflaginfo.h.cmakein
  60     CONDITION $<CONFIG:${CMAKE_BUILD_TYPE}>
  61     )
  62
  63 ####
  64 set(IGNORED_CLANG_ALL_WARNINGS
  65     "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  66     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  67     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  68     "-Wno-documentation-unknown-command" #Custom commands are used
  69     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  70     "-Wno-switch-enum" # default statement for enum is OK
  71
  72     # TODO uncomment the next few ignore lines when we upgrade to test with clang 8 in Jenkins
  73
  74     # The barriers we use for tMPI and Nbnxm are sufficient, but it's
  75     # not known whether they're excessive. We assume they not
  76     # excessive.
  77     # "-Wno-atomic-implicit-seq-cst"
  78
  79     # We need to use macros like
  80     # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  81     # if they don't have a semicolon after them, and might confuse
  82     # tools like IDEs also.
  83     # "-Wno-extra-semi-stmt"
  84
  85     #Following ones are undecided/TODO
  86     "-Wno-disabled-macro-expansion"
  87     "-Wno-cast-align"
  88     "-Wno-reserved-id-macro"
  89     "-Wno-global-constructors"
  90     "-Wno-exit-time-destructors"
  91     "-Wno-unused-macros"
  92     "-Wno-weak-vtables"
  93     "-Wno-conditional-uninitialized"
  94     "-Wno-format-nonliteral"
  95     "-Wno-shadow"
  96     "-Wno-cast-qual"
  97     "-Wno-documentation"
  98     "-Wno-used-but-marked-unused"
  99     "-Wno-padded"
 100     "-Wno-float-equal"
 101     "-Wno-old-style-cast"
 102     "-Wno-conversion"
 103     "-Wno-double-promotion")
 104 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
 105
 106 if (GMX_CLANG_TIDY)
 107    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
 108    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
 109        DOC "Path to clang-tidy executable")
 110    if(NOT CLANG_TIDY_EXE)
 111        message(FATAL_ERROR "clang-tidy not found.")
 112    endif()
 113 endif()
 114 #####
 115
 116 add_subdirectory(external)
 117
 118 if (BUILD_TESTING)
 119     if(NOT GMX_DEVELOPER_BUILD)
 120         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
 121     endif()
 122     include(testutils/TestMacros.cmake)
 123     add_subdirectory(testutils)
 124 endif()
 125
 126 add_subdirectory(gromacs)
 127 add_subdirectory(programs)
 128
 129 # Activate targets for new C++ API components and docs.
 130 if(GMX_NATIVE_WINDOWS OR GMX_BUILD_MDRUN_ONLY OR NOT BUILD_SHARED_LIBS)
 131     # GMXAPI has not been tested in Microsoft environments.
 132     # GMXAPI relies on libgromacs and is incompatible with an `mdrun`-only build.
 133     # GMXAPI requires position-independent code
 134     set(_GMXAPI_DEFAULT OFF)
 135 else()
 136     set(_GMXAPI_DEFAULT ON)
 137 endif()
 138 option(GMXAPI "Experimental external interfaces" ${_GMXAPI_DEFAULT})
 139 if (GMXAPI)
 140    if (GMX_BUILD_MDRUN_ONLY)
 141        message(FATAL_ERROR "GMXAPI relies on libgromacs and is incompatible with GMX_BUILD_MDRUN_ONLY.")
 142    endif()
 143    if(NOT ${BUILD_SHARED_LIBS})
 144        # Note: this conditional should check for the existence of a libgromacs target supporting PIC
 145        # using the POSITION_INDEPENDENT_CODE property, but for now the only facility we have is the global
 146        # variable, BUILD_SHARED_LIBS.
 147        # TODO: gmxapi should gracefully build for dynamic linking or static linking for PIC or without.
 148        message(FATAL_ERROR "GMXAPI requires position-independent code. Set -DGMXAPI=OFF or -DBUILD_SHARED_LIBS=ON.")
 149    endif()
 150    add_subdirectory(api)
 151 endif()