src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 ######################################
  36 # Output compiler and CFLAGS used
  37 ######################################
  38 include(GetCompilerInfo.cmake)
  39 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
  40 get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
  41 if(GMX_USE_CUDA)
  42     if(NOT GMX_CLANG_CUDA)
  43         GMX_SET_CUDA_NVCC_FLAGS()
  44         # Source files generated by NVCC can include gmxmpi.h, and so
  45         # need access to thread-MPI.
  46         set(CUDA_INCLUDE_DIRS ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  47     endif()
  48
  49     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_COMPILER_FLAGS)
  50 endif()
  51
  52 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UPPER)
  53 configure_file(config.h.cmakein config.h)
  54 configure_file(gmxpre-config.h.cmakein gmxpre-config.h)
  55 configure_file(buildinfo.h.cmakein buildinfo.h ESCAPE_QUOTES)
  56
  57 ####
  58 set(IGNORED_CLANG_ALL_WARNINGS
  59     "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  60     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  61     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  62     "-Wno-documentation-unknown-command" #Custom commands are used
  63     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  64     "-Wno-switch-enum" # default statement for enum is OK
  65
  66     # TODO uncomment the next few ignore lines when we upgrade to test with clang 8 in Jenkins
  67
  68     # The barriers we use for tMPI and Nbnxm are sufficient, but it's
  69     # not known whether they're excessive. We assume they not
  70     # excessive.
  71     # "-Wno-atomic-implicit-seq-cst"
  72
  73     # We need to use macros like
  74     # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  75     # if they don't have a semicolon after them, and might confuse
  76     # tools like IDEs also.
  77     # "-Wno-extra-semi-stmt"
  78
  79     #Following ones are undecided/TODO
  80     "-Wno-disabled-macro-expansion"
  81     "-Wno-cast-align"
  82     "-Wno-reserved-id-macro"
  83     "-Wno-global-constructors"
  84     "-Wno-exit-time-destructors"
  85     "-Wno-unused-macros"
  86     "-Wno-weak-vtables"
  87     "-Wno-conditional-uninitialized"
  88     "-Wno-format-nonliteral"
  89     "-Wno-shadow"
  90     "-Wno-cast-qual"
  91     "-Wno-documentation"
  92     "-Wno-used-but-marked-unused"
  93     "-Wno-padded"
  94     "-Wno-float-equal"
  95     "-Wno-old-style-cast"
  96     "-Wno-conversion"
  97     "-Wno-double-promotion")
  98 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  99
 100 if (GMX_CLANG_TIDY)
 101    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
 102    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
 103        DOC "Path to clang-tidy executable")
 104    if(NOT CLANG_TIDY_EXE)
 105        message(FATAL_ERROR "clang-tidy not found.")
 106    endif()
 107 endif()
 108 #####
 109
 110 if (BUILD_TESTING)
 111     if(NOT GMX_DEVELOPER_BUILD)
 112         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
 113     endif()
 114     if (GMX_BUILD_UNITTESTS)
 115         add_subdirectory(external/googletest)
 116     endif()
 117     include(testutils/TestMacros.cmake)
 118     add_subdirectory(testutils)
 119 endif()
 120
 121 add_subdirectory(gromacs)
 122 add_subdirectory(programs)
 123
 124 # Activate targets for new C++ API components and docs.
 125 if(GMX_NATIVE_WINDOWS OR GMX_BUILD_MDRUN_ONLY OR NOT BUILD_SHARED_LIBS)
 126     # GMXAPI has not been tested in Microsoft environments.
 127     # GMXAPI relies on libgromacs and is incompatible with an `mdrun`-only build.
 128     # GMXAPI requires position-independent code
 129     set(_GMXAPI_DEFAULT OFF)
 130 else()
 131     set(_GMXAPI_DEFAULT OFF)
 132 endif()
 133 option(GMXAPI "Experimental external interfaces" ${_GMXAPI_DEFAULT})
 134 if (GMXAPI)
 135    if (GMX_BUILD_MDRUN_ONLY)
 136        message(FATAL_ERROR "GMXAPI relies on libgromacs and is incompatible with GMX_BUILD_MDRUN_ONLY.")
 137    endif()
 138    if(NOT ${BUILD_SHARED_LIBS})
 139        # Note: this conditional should check for the existence of a libgromacs target supporting PIC
 140        # using the POSITION_INDEPENDENT_CODE property, but for now the only facility we have is the global
 141        # variable, BUILD_SHARED_LIBS.
 142        # TODO: gmxapi should gracefully build for dynamic linking or static linking for PIC or without.
 143        message(FATAL_ERROR "GMXAPI requires position-independent code. Set -DGMXAPI=OFF or -DBUILD_SHARED_LIBS=ON.")
 144    endif()
 145    add_subdirectory(api)
 146 endif()