python_packaging/src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This CMakeLists.txt allows source distributions of the gmxapi Python package
  36 # to rely on scikit-build for support of various Python packaging systems. The
  37 # simplest use case is to allow the `setup.py` file to invoke skbuild to
  38 # configure and run CMake. CMake could be invoked directly by the user or a
  39 # parent package, but the Python distribution would not be packaged automatically.
  40 # Reference https://redmine.gromacs.org/issues/2896 for additional discussion.
  41 cmake_minimum_required(VERSION 3.9.6)
  42
  43 # This needs to be set before project() in order to pick up toolchain files
  44 #list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../../cmake)
  45
  46 # OS X deployment target should be >=10.9 for modern C++ compatibility.
  47 # Reference https://scikit-build.readthedocs.io/en/latest/generators.html#macosx
  48 # and https://github.com/MacPython/wiki/wiki/Spinning-wheels
  49 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.9 CACHE STRING
  50     "OS X deployment target below 10.9 does not use modern standard library"
  51     FORCE)
  52 set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  53     "OS X should build Python package for 64-bit architecture"
  54     FORCE)
  55
  56 project(gmxapi VERSION 0.1.0)
  57
  58 # Check if Python package is being built directly or via add_subdirectory
  59 set(GMXAPI_MASTER_PROJECT OFF)
  60 if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
  61     set(GMXAPI_MASTER_PROJECT ON)
  62 endif()
  63
  64 set(CMAKE_CXX_STANDARD 14)
  65 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  66
  67 # Only interpret if() arguments as variables or keywords when unquoted.
  68 cmake_policy(SET CMP0054 NEW)
  69 # honor the language standard settings for try_compile()
  70 cmake_policy(SET CMP0067 NEW)
  71 if(POLICY CMP0074) #3.12
  72     # Allow gmxapi_ROOT hint.
  73     cmake_policy(SET CMP0074 NEW)
  74 endif()
  75
  76 if(GMXAPI_MASTER_PROJECT)
  77     find_package(gmxapi 0.0.8 REQUIRED
  78                  HINTS "$ENV{GROMACS_DIR}"
  79                  )
  80 endif()
  81 if(gmxapi_FOUND)
  82     set(_suffix "")
  83     # GROMACS master branch and development branches may have divergent
  84     # pre-release APIs. This check allows us to distinguish them and behave
  85     # differently if needed. github.com/kassonlab/gromacs-gmxapi devel branch
  86     # sets gmxapi_EXPERIMENTAL=TRUE. Upstream GROMACS master branch does not.
  87     # Ref: https://github.com/kassonlab/gmxapi/issues/166
  88     if(gmxapi_EXPERIMENTAL)
  89         set(_suffix " (unofficial)")
  90     endif()
  91     message(STATUS "Found gmxapi version ${gmxapi_VERSION}${_suffix}")
  92 endif()
  93
  94 # The Gromacs::gmxapi target could be imported from an existing installation or
  95 # provided as an alias target within the GROMACS build tree.
  96 if (NOT TARGET Gromacs::gmxapi)
  97     message(FATAL_ERROR "Cannot build Python package without GROMACS gmxapi support.")
  98 endif ()
  99
 100 # TODO: Provide user hints for mpi4py installation.
 101 # Note that neither the Python package nor the Gromacs::gmxapi CMake target are
 102 # built with MPI in any case, but they _should_ be built with a C++ compiler
 103 # that is compatible with the available MPI compiler wrappers, and technically
 104 # _that_ is what we want to help the user identify when installing mpi4py, even
 105 # if libgromacs is not built with MPI support either.
 106 # For convenience, it is fine if libgmxapi and _gmxapi are built with the mpi
 107 # compiler wrapper.
 108
 109 option(GMXAPI_USE_BUNDLED_PYBIND
 110        "Use pybind11 headers bundled with this repository. If OFF, CMake does `find_package(pybind11)`."
 111        ON)
 112 if(GMXAPI_USE_BUNDLED_PYBIND)
 113     add_subdirectory(external/pybind)
 114 else()
 115     # Reference https://redmine.gromacs.org/issues/2896
 116     find_package(pybind11 2.2 REQUIRED)
 117 endif()
 118
 119 set(GMXAPI_PYTHON_EXTENSION_SOURCES
 120     gmxapi/module.cpp
 121     gmxapi/export_context.cpp
 122     gmxapi/export_exceptions.cpp
 123     gmxapi/export_system.cpp
 124     gmxapi/export_tprfile.cpp
 125     gmxapi/pycontext.cpp
 126     gmxapi/pysystem.cpp
 127     )
 128
 129 pybind11_add_module(_gmxapi
 130                     ${GMXAPI_PYTHON_EXTENSION_SOURCES}
 131                     )
 132
 133 target_include_directories(_gmxapi PRIVATE
 134                            ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi
 135                            ${CMAKE_CURRENT_BINARY_DIR}/gmxapi
 136                            )
 137
 138 # RPATH management: make sure build artifacts can find GROMACS library.
 139 set_target_properties(_gmxapi PROPERTIES SKIP_BUILD_RPATH FALSE)
 140
 141 # Python sources (*.py) will be packaged by scikit-build and setuptools.
 142 # Note that library targets are built in CMAKE_LIBRARY_OUTPUT_DIRECTORY if not otherwise specified.
 143 # This may be an unexpected location, whether inherited from the GROMACS build tree
 144 # or the SKBUILD framework. Note, also, that when scikit-build is invoked with setup.py,
 145 # the CMake build takes place in a subdirectory of ./_skbuild/.
 146 set(GMXAPI_PYTHON_STAGING_DIR ${CMAKE_CURRENT_BINARY_DIR}/gmxapi_staging)
 147 set_target_properties(_gmxapi PROPERTIES
 148                       LIBRARY_OUTPUT_DIRECTORY ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi)
 149
 150 # scikit-build sets SKBUILD when running Python packaging tools through setup.py
 151 # (e.g. with pip)
 152 if(SKBUILD)
 153     # The Python module is being built for a GROMACS installation.
 154     set_target_properties(_gmxapi PROPERTIES BUILD_WITH_INSTALL_RPATH TRUE)
 155     set_target_properties(_gmxapi PROPERTIES INSTALL_RPATH_USE_LINK_PATH TRUE)
 156     target_link_libraries(_gmxapi PRIVATE Gromacs::gmxapi)
 157     # By default, scikit-build expects the library to be installed into a directory
 158     # named for the Python package as in setup.py.
 159     install(TARGETS _gmxapi LIBRARY DESTINATION gmxapi)
 160 else()
 161     # The Python module is being built against GROMACS in its build tree.
 162     # Note: we do not have plans to install the staged package when SKBUILD != TRUE
 163     set_target_properties(_gmxapi PROPERTIES BUILD_WITH_INSTALL_RPATH FALSE)
 164     target_link_libraries(_gmxapi PRIVATE Gromacs::gmxapi)
 165
 166     # TODO: Determine packaging and installation cases and implementation.
 167     # Reference https://redmine.gromacs.org/issues/2896 for additional discussion.
 168     # Currently, CMake should be run by scikit-build through setup.py for proper Python packaging.
 169     # We don't want to install by default in the outer scope of the GROMACS
 170     # CMake procedure because we could end up trying to install to a system directory
 171     # the user did not intend, or a user might install a Python-installation-specific
 172     # package into an overly generic GROMACS path.
 173
 174     # Instead, we should probably build a source package and alert the user of its location.
 175     # We can use CMake to call the Python packaging tools to create an 'sdist'
 176     # source distribution archive to be installed in the GROMACS installation
 177     # destination. We can use the build directory as the working directory for
 178     # easier clean-up, as well.
 179     # TODO: (ref issue #2896) Build and install 'sdist' with GROMACS.
 180
 181     # However, we can still produce an importable package for documentation builds and
 182     # basic testing in ${CMAKE_CURRENT_BINARY_DIR}/gmxapi_staging
 183     if(CMAKE_VERSION VERSION_LESS 3.12)
 184         file(GLOB_RECURSE _py_sources
 185              ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi/*.py)
 186     else()
 187         # CONFIGURE_DEPENDS appears in CMake 3.12 and can help to more robustly detect
 188         # the need to update anything depending on the staged package.
 189         file(GLOB_RECURSE _py_sources
 190              CONFIGURE_DEPENDS
 191              ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi/*.py)
 192     endif()
 193     foreach(_package_file IN LISTS _py_sources)
 194         get_filename_component(_absolute_dir ${_package_file} DIRECTORY)
 195         file(RELATIVE_PATH _relative_dir ${CMAKE_CURRENT_SOURCE_DIR} ${_absolute_dir})
 196         file(COPY ${_package_file} DESTINATION gmxapi_staging/${_relative_dir})
 197     endforeach()
 198     file(COPY setup.py CMakeLists.txt DESTINATION ${GMXAPI_PYTHON_STAGING_DIR})
 199     # Set CMake variable pybind11_DIR to ${CMAKE_CURRENT_SOURCE_DIR}/external/pybind/tools
 200     # if re-invoking CMake (including via Python setuptools) for the files in gmxapi_staging.
 201
 202     # Unit test and build docs using PYTHONPATH=$CMAKE_CURRENT_BINARY_DIR/gmxapi_staging
 203     set_target_properties(_gmxapi PROPERTIES staging_dir ${GMXAPI_PYTHON_STAGING_DIR})
 204     # Note: Integration testing for multiple Python versions and/or CMake-driven
 205     # sdist preparation could be performed with CMake custom_commands and custom_targets.
 206 endif()
 207
 208 # When building as part of GROMACS umbrella project, add a testing target
 209 # to the `check` target. Normal usage is to first install the Python package,
 210 # then run `pytest` on the `tests` directory. Refer to gmxapi package documentation.
 211 if(NOT GMXAPI_MASTER_PROJECT)
 212     add_subdirectory(test)
 213 endif()