python_packaging/src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This CMakeLists.txt allows source distributions of the gmxapi Python package
  36 # to rely on scikit-build for support of various Python packaging systems. The
  37 # simplest use case is to allow the `setup.py` file to invoke skbuild to
  38 # configure and run CMake. CMake could be invoked directly by the user or a
  39 # parent package, but the Python distribution would not be packaged automatically.
  40 # Reference https://gitlab.com/gromacs/gromacs/-/issues/2896 for additional discussion.
  41 cmake_minimum_required(VERSION 3.13.0)
  42
  43 # This needs to be set before project() in order to pick up toolchain files
  44 #list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../../cmake)
  45
  46 # OS X deployment target should be >=10.14 for modern C++ compatibility.
  47 # Reference https://scikit-build.readthedocs.io/en/latest/generators.html#macosx
  48 # and https://github.com/MacPython/wiki/wiki/Spinning-wheels
  49 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  50     "OS X deployment target below 10.14 does not use modern standard library"
  51     FORCE)
  52 set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  53     "OS X should build Python package for 64-bit architecture"
  54     FORCE)
  55
  56 project(gmxapi VERSION 0.1.0)
  57
  58 # Check if Python package is being built directly or via add_subdirectory
  59 set(GMXAPI_MASTER_PROJECT OFF)
  60 if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
  61     set(GMXAPI_MASTER_PROJECT ON)
  62 endif()
  63
  64 set(CMAKE_CXX_STANDARD 17)
  65 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  66
  67 # Only interpret if() arguments as variables or keywords when unquoted.
  68 cmake_policy(SET CMP0054 NEW)
  69 # honor the language standard settings for try_compile()
  70 cmake_policy(SET CMP0067 NEW)
  71 if(POLICY CMP0074) #3.12
  72     # Allow gmxapi_ROOT hint.
  73     cmake_policy(SET CMP0074 NEW)
  74 endif()
  75
  76 if(GMXAPI_MASTER_PROJECT)
  77     find_package(gmxapi 0.0.8 REQUIRED
  78                  HINTS "$ENV{GROMACS_DIR}"
  79                  )
  80 endif()
  81 if(gmxapi_FOUND)
  82     set(_suffix "")
  83     # GROMACS master branch and development branches may have divergent
  84     # pre-release APIs. This check allows us to distinguish them and behave
  85     # differently if needed. github.com/kassonlab/gromacs-gmxapi devel branch
  86     # sets gmxapi_EXPERIMENTAL=TRUE. Upstream GROMACS master branch does not.
  87     # Ref: https://github.com/kassonlab/gmxapi/issues/166
  88     if(gmxapi_EXPERIMENTAL)
  89         set(_suffix " (unofficial)")
  90     endif()
  91     message(STATUS "Found gmxapi version ${gmxapi_VERSION}${_suffix}")
  92 endif()
  93
  94 # The Gromacs::gmxapi target could be imported from an existing installation or
  95 # provided as an alias target within the GROMACS build tree.
  96 if (NOT TARGET Gromacs::gmxapi)
  97     message(FATAL_ERROR "Cannot build Python package without GROMACS gmxapi support.")
  98 endif ()
  99
 100 # TODO: Provide user hints for mpi4py installation.
 101 # Note that neither the Python package nor the Gromacs::gmxapi CMake target are
 102 # built with MPI in any case, but they _should_ be built with a C++ compiler
 103 # that is compatible with the available MPI compiler wrappers, and technically
 104 # _that_ is what we want to help the user identify when installing mpi4py, even
 105 # if libgromacs is not built with MPI support either.
 106 # For convenience, it is fine if libgmxapi and _gmxapi are built with the mpi
 107 # compiler wrapper.
 108
 109 option(GMXAPI_USE_BUNDLED_PYBIND
 110        "Use pybind11 headers bundled with this repository. If OFF, CMake does `find_package(pybind11)`."
 111        ON)
 112 if(GMXAPI_USE_BUNDLED_PYBIND)
 113     add_subdirectory(external/pybind)
 114 else()
 115     # Reference https://gitlab.com/gromacs/gromacs/-/issues/2896
 116     find_package(pybind11 2.2 REQUIRED)
 117 endif()
 118
 119 set(GMXAPI_PYTHON_EXTENSION_SOURCES
 120     gmxapi/module.cpp
 121     gmxapi/export_context.cpp
 122     gmxapi/export_exceptions.cpp
 123     gmxapi/export_system.cpp
 124     gmxapi/export_tprfile.cpp
 125     gmxapi/pycontext.cpp
 126     gmxapi/pysystem.cpp
 127     )
 128
 129 pybind11_add_module(_gmxapi
 130                     ${GMXAPI_PYTHON_EXTENSION_SOURCES}
 131                     )
 132
 133 target_include_directories(_gmxapi PRIVATE
 134                            ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi
 135                            ${CMAKE_CURRENT_BINARY_DIR}/gmxapi
 136                            )
 137
 138 # RPATH management: make sure build artifacts can find GROMACS library.
 139 set_target_properties(_gmxapi PROPERTIES SKIP_BUILD_RPATH FALSE)
 140
 141 # Python sources (*.py) will be packaged by scikit-build and setuptools.
 142 # Note that library targets are built in CMAKE_LIBRARY_OUTPUT_DIRECTORY if not otherwise specified.
 143 # This may be an unexpected location, whether inherited from the GROMACS build tree
 144 # or the SKBUILD framework. Note, also, that when scikit-build is invoked with setup.py,
 145 # the CMake build takes place in a subdirectory of ./_skbuild/.
 146 set(GMXAPI_PYTHON_STAGING_DIR ${CMAKE_CURRENT_BINARY_DIR}/gmxapi_staging)
 147 set_target_properties(_gmxapi PROPERTIES
 148                       LIBRARY_OUTPUT_DIRECTORY ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi)
 149
 150 if(GMXAPI_MASTER_PROJECT)
 151     find_package(GROMACS 2021 REQUIRED
 152                  HINTS "$ENV{GROMACS_DIR}"
 153                  )
 154 endif()
 155
 156 # Get details of GROMACS installation needed by the Python package at run time.
 157
 158 # Get the MPI capability.
 159 get_target_property(_gmx_mpi Gromacs::gmxapi MPI)
 160 if (${_gmx_mpi} STREQUAL "library")
 161     set(_gmx_mpi_type "\"library\"")
 162 elseif(${_gmx_mpi} STREQUAL "tmpi")
 163     set(_gmx_mpi_type "\"tmpi\"")
 164 elseif(${_gmx_mpi} STREQUAL "none")
 165     set(_gmx_mpi_type "null")
 166 else()
 167     message(FATAL_ERROR "Unrecognized gmxapi MPI value: ${_gmx_mpi}")
 168 endif ()
 169 unset(_gmx_mpi)
 170 # Get the path of the command line entry point and binary install directory.
 171 if (NOT TARGET Gromacs::gmx)
 172     message(FATAL_ERROR "GROMACS command line tool not found.")
 173 endif ()
 174 get_target_property(_gmx_executable_imported Gromacs::gmx IMPORTED)
 175 if (_gmx_executable_imported)
 176     get_target_property(_gmx_executable Gromacs::gmx LOCATION)
 177     get_filename_component(_gmx_bindir ${_gmx_executable} DIRECTORY)
 178     message(STATUS "Imported ${_gmx_bindir} executable.")
 179     unset(_gmx_executable_imported)
 180 else()
 181     get_target_property(_gmx_bindir Gromacs::gmx RUNTIME_OUTPUT_DIRECTORY)
 182     get_target_property(_gmx_executable Gromacs::gmx OUTPUT_NAME)
 183     set(_gmx_executable "${_gmx_bindir}/${_gmx_executable}")
 184     message(STATUS "Using ${_gmx_executable} from build tree.")
 185 endif ()
 186 if (NOT _gmx_bindir OR NOT _gmx_executable)
 187     message(FATAL_ERROR "Could not get path for gmx wrapper binary.")
 188 endif ()
 189 configure_file(gmxapi/gmxconfig.json.in ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi/gmxconfig.json)
 190 unset(_gmx_executable)
 191 unset(_gmx_bindir)
 192 unset(_gmx_mpi_type)
 193
 194 # scikit-build sets SKBUILD when running Python packaging tools through setup.py
 195 # (e.g. with pip)
 196 if(SKBUILD)
 197     # The Python module is being built for a GROMACS installation.
 198     set_target_properties(_gmxapi PROPERTIES BUILD_WITH_INSTALL_RPATH TRUE)
 199     set_target_properties(_gmxapi PROPERTIES INSTALL_RPATH_USE_LINK_PATH TRUE)
 200     target_link_libraries(_gmxapi PRIVATE Gromacs::gmxapi)
 201     # By default, scikit-build expects the library to be installed into a directory
 202     # named for the Python package as in setup.py.
 203     install(TARGETS _gmxapi LIBRARY DESTINATION gmxapi)
 204     install(FILES ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi/gmxconfig.json DESTINATION gmxapi)
 205 else()
 206     # The Python module is being built against GROMACS in its build tree.
 207     # Note: we do not have plans to install the staged package when SKBUILD != TRUE
 208     set_target_properties(_gmxapi PROPERTIES BUILD_WITH_INSTALL_RPATH FALSE)
 209     target_link_libraries(_gmxapi PRIVATE Gromacs::gmxapi)
 210
 211     # TODO: Determine packaging and installation cases and implementation.
 212     # Reference https://gitlab.com/gromacs/gromacs/-/issues/2896 for additional discussion.
 213     # Currently, CMake should be run by scikit-build through setup.py for proper Python packaging.
 214     # We don't want to install by default in the outer scope of the GROMACS
 215     # CMake procedure because we could end up trying to install to a system directory
 216     # the user did not intend, or a user might install a Python-installation-specific
 217     # package into an overly generic GROMACS path.
 218
 219     # Instead, we should probably build a source package and alert the user of its location.
 220     # We can use CMake to call the Python packaging tools to create an 'sdist'
 221     # source distribution archive to be installed in the GROMACS installation
 222     # destination. We can use the build directory as the working directory for
 223     # easier clean-up, as well.
 224     # TODO: (ref Issue #2896) Build and install 'sdist' with GROMACS.
 225
 226     # However, we can still produce an importable package for documentation builds and
 227     # basic testing in ${CMAKE_CURRENT_BINARY_DIR}/gmxapi_staging
 228     file(GLOB_RECURSE _py_sources
 229          CONFIGURE_DEPENDS
 230          ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi/*.py)
 231     foreach(_package_file IN LISTS _py_sources)
 232         get_filename_component(_absolute_dir ${_package_file} DIRECTORY)
 233         file(RELATIVE_PATH _relative_dir ${CMAKE_CURRENT_SOURCE_DIR} ${_absolute_dir})
 234         file(COPY ${_package_file} DESTINATION ${GMXAPI_PYTHON_STAGING_DIR}/${_relative_dir})
 235     endforeach()
 236     file(COPY setup.py CMakeLists.txt DESTINATION ${GMXAPI_PYTHON_STAGING_DIR})
 237     # Set CMake variable pybind11_DIR to ${CMAKE_CURRENT_SOURCE_DIR}/external/pybind/tools
 238     # if re-invoking CMake (including via Python setuptools) for the files in gmxapi_staging.
 239
 240     # Unit test and build docs using PYTHONPATH=$CMAKE_CURRENT_BINARY_DIR/gmxapi_staging
 241     set_target_properties(_gmxapi PROPERTIES staging_dir ${GMXAPI_PYTHON_STAGING_DIR})
 242     # Note: Integration testing for multiple Python versions and/or CMake-driven
 243     # sdist preparation could be performed with CMake custom_commands and custom_targets.
 244 endif()
 245
 246 # When building as part of GROMACS umbrella project, add a testing target
 247 # to the `check` target. Normal usage is to first install the Python package,
 248 # then run `pytest` on the `tests` directory. Refer to gmxapi package documentation.
 249 if(NOT GMXAPI_MASTER_PROJECT)
 250     add_subdirectory(test)
 251 endif()