docs/doxygen/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(gmxCustomCommandUtilities)
  36 include(gmxOptionUtilities)
  37
  38 find_package(Doxygen QUIET)
  39 if (DOXYGEN_FOUND)
  40     # This logic closely follows that found in FindDoxygen.cmake for dot,
  41     # except that the PATH variable is not cached.
  42     find_program(DOXYGEN_MSCGEN_EXECUTABLE
  43         NAMES mscgen
  44         DOC "Message sequence chart renderer tool (http://www.mcternan.me.uk/mscgen/)")
  45     if (DOXYGEN_MSCGEN_EXECUTABLE)
  46         set(DOXYGEN_MSCGEN_FOUND TRUE)
  47         get_filename_component(DOXYGEN_MSCGEN_PATH "${DOXYGEN_MSCGEN_EXECUTABLE}" PATH)
  48     endif()
  49     mark_as_advanced(DOXYGEN_MSCGEN_EXECUTABLE)
  50 endif()
  51
  52 gmx_dependent_option(
  53     GMX_COMPACT_DOXYGEN
  54     "Skip parts of Doxygen documentation (in particular, many graphs) to save disk space and time"
  55     OFF
  56     DOXYGEN_FOUND)
  57 mark_as_advanced(GMX_COMPACT_DOXYGEN)
  58
  59 set(USE_PYTHON_SCRIPTS OFF)
  60 if (PYTHONINTERP_FOUND AND NOT PYTHON_VERSION_STRING VERSION_LESS "2.6")
  61     set(USE_PYTHON_SCRIPTS ON)
  62 endif()
  63
  64 # Note that if you relocate this file, you also need to change gmxtree.py.
  65 # TODO: Try to find a solution where this would be hard-coded here, completely
  66 # separate from the logic that generates it.
  67 set(INSTALLED_HEADERS_FILE ${PROJECT_BINARY_DIR}/src/gromacs/installed-headers.txt)
  68
  69 ########################################################################
  70 # Doxygen configuration
  71 #
  72 if (DOXYGEN_FOUND)
  73     # Generate Doxygen input configuration files
  74     file(GLOB NB_KERNEL_DIRS
  75          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
  76     list(REMOVE_ITEM NB_KERNEL_DIRS
  77          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
  78     foreach (dir ${NB_KERNEL_DIRS})
  79         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
  80             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${dir}")
  81     endforeach()
  82     set(DEPGRAPH_DIR ${CMAKE_CURRENT_BINARY_DIR}/depgraphs)
  83     set(DOXYGEN_SECTIONS "")
  84     set(DOXYGEN_EXTRA_SETTINGS "")
  85     if (GMX_COMPACT_DOXYGEN)
  86         set(DOXYGEN_EXTRA_SETTINGS "@INCLUDE   = ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile-compact")
  87     endif()
  88     configure_file(Doxyfile-common.cmakein Doxyfile-common)
  89     configure_file(Doxyfile-full.cmakein Doxyfile-full)
  90     configure_file(Doxyfile-lib.cmakein Doxyfile-lib)
  91     configure_file(Doxyfile-user.cmakein Doxyfile-user)
  92     configure_file(Doxyfile-xml.cmakein Doxyfile-xml)
  93
  94     configure_file(RunDoxygen.cmake.cmakein RunDoxygen.cmake @ONLY)
  95     gmx_configure_version_file(Doxyfile-version.cmakein Doxyfile-version
  96                                TARGET doxygen-version)
  97
  98     # Add a stamp that gets updated whenever a source file that contributes to
  99     # Doxygen is updated.  All Doxygen targets can then depend on this stamp,
 100     # instead of each specifying this massive set of dependencies.
 101     # TODO: The set of files that affects Doxygen is not exactly the same as
 102     # that which affects the dependency graphs, and neither is captured
 103     # perfectly with this set, but this can be improved if it becomes a real
 104     # issue (the differences are mainly in the generated group kernel files,
 105     # but there are some minor other differences as well).
 106     if (SOURCE_IS_GIT_REPOSITORY AND GIT_FOUND)
 107         gmx_get_files_with_gitattribute(doxygen_sources gmx-doxygen)
 108         # Add also common configuration files that influence the generation.
 109         set(doxygen_deps
 110             ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-common
 111             ${CMAKE_CURRENT_BINARY_DIR}/RunDoxygen.cmake)
 112         if (GMX_COMPACT_DOXYGEN)
 113             list(APPEND doxygen_deps ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile-compact)
 114         endif()
 115         gmx_add_custom_output_target(doxygen-source-timestamp
 116             OUTPUT STAMP
 117             DEPENDS_FILE_LIST doxygen_sources
 118             DEPENDS ${doxygen_deps}
 119             COMMENT "Updating Doxygen source timestamp")
 120     else()
 121         # If there is no git, we just update the stamp every time, and the
 122         # builds are triggered every time.  This should be rare enough, but
 123         # this case still needs to be supported for the Jenkins job that builds
 124         # the documentation for a release from the release tarball.
 125         gmx_add_custom_output_target(doxygen-source-timestamp
 126             RUN_ALWAYS OUTPUT STAMP
 127             COMMENT "Updating Doxygen source timestamp")
 128     endif()
 129
 130     # Helper function to create a Doxygen build target
 131     function (add_doxygen_target TARGET TYPE COMMENT)
 132         set(_deps doxygen-source-timestamp doxygen-version
 133             ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-${TYPE})
 134         set(_fast_arg "")
 135         if ("${ARGN}" STREQUAL "DEPGRAPHS")
 136             set(_fast_arg "ADD_FAST_TARGET")
 137             if (TARGET dep-graphs-dot)
 138                 list(APPEND _deps dep-graphs-dot)
 139             endif()
 140         endif()
 141         gmx_add_custom_output_target(${TARGET} OUTPUT STAMP ${_fast_arg}
 142             # Ensure the directory exists to avoid spurious warnings
 143             COMMAND ${CMAKE_COMMAND} -E make_directory ${DEPGRAPH_DIR}
 144             COMMAND ${CMAKE_COMMAND} -DDOCTYPE=${TYPE} -P RunDoxygen.cmake
 145             DEPENDS ${_deps}
 146             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 147             COMMENT "${COMMENT}" USES_TERMINAL)
 148         if (_fast_arg)
 149             add_dependencies(${TARGET}-fast doxygen-version)
 150         endif()
 151     endfunction()
 152
 153     # The XML target is necessary for the dependency graphs
 154     add_doxygen_target(doxygen-xml xml "Extracting Doxygen documentation to XML")
 155
 156     # Add targets for generating the dependency graphs; they are necessary for
 157     # the full and lib variants of the documentation.
 158     if (USE_PYTHON_SCRIPTS)
 159         # Add target that generates .dot files for the dependency graphs.
 160         # The output also depends on the Doxygen source files, but the
 161         # dependency on doxygen-xml takes care of that transitively.
 162         gmx_add_custom_output_target(dep-graphs-dot ADD_FAST_TARGET
 163             OUTPUT STAMP
 164             COMMAND ${PYTHON_EXECUTABLE}
 165                 ${CMAKE_CURRENT_SOURCE_DIR}/graphbuilder.py
 166                 -S ${CMAKE_SOURCE_DIR} -B ${CMAKE_BINARY_DIR}
 167                 --ignore-cycles ${CMAKE_CURRENT_SOURCE_DIR}/cycle-suppressions.txt
 168                 -o ${DEPGRAPH_DIR}
 169             DEPENDS doxygen-xml ${INSTALLED_HEADER_FILE}
 170                 ${CMAKE_CURRENT_SOURCE_DIR}/doxygenxml.py
 171                 ${CMAKE_CURRENT_SOURCE_DIR}/gmxtree.py
 172                 ${CMAKE_CURRENT_SOURCE_DIR}/graphbuilder.py
 173                 ${CMAKE_CURRENT_SOURCE_DIR}/cycle-suppressions.txt
 174             COMMENT "Generating include dependency graphs for dot"
 175             USES_TERMINAL)
 176
 177         # Add separate targets for converting the .dot files to .png.
 178         # These are not needed by the Doxygen targets, but are useful for
 179         # investigating just the graphs.
 180         set(dep_graphs_command_dot
 181             ${CMAKE_COMMAND} -DGRAPHDIR=${DEPGRAPH_DIR}
 182             -DDOT_EXECUTABLE=${DOXYGEN_DOT_EXECUTABLE}
 183             -P ${CMAKE_CURRENT_SOURCE_DIR}/generateGraphs.cmake)
 184         add_custom_target(dep-graphs      COMMAND ${dep_graphs_command_dot}
 185             COMMENT "Generating PNG include dependency graphs" VERBATIM)
 186         add_custom_target(dep-graphs-fast COMMAND ${dep_graphs_command_dot}
 187             COMMENT "Generating PNG include dependency graphs" VERBATIM)
 188         add_dependencies(dep-graphs      dep-graphs-dot)
 189         add_dependencies(dep-graphs-fast dep-graphs-dot-fast)
 190     endif()
 191
 192     # Create the actual targets to build the documentation.
 193     add_doxygen_target(doxygen-full full "Generating full documentation with Doxygen" DEPGRAPHS)
 194     add_doxygen_target(doxygen-lib  lib  "Generating library documentation with Doxygen" DEPGRAPHS)
 195     add_doxygen_target(doxygen-user user "Generating public API documentation with Doxygen")
 196     # Convenience targets to build all the documentation flavors.
 197     add_custom_target(doxygen-all)
 198     add_custom_target(doxygen-all-fast)
 199     add_dependencies(doxygen-all      doxygen-full doxygen-lib doxygen-user)
 200     add_dependencies(doxygen-all-fast doxygen-full-fast doxygen-lib-fast doxygen-user)
 201
 202     # Finally, create the check-source target.
 203     if (USE_PYTHON_SCRIPTS)
 204         # TODO: Consider whether this is the best location for this code,
 205         # since not all of it is Doxygen-specific (but nearly all of it
 206         # relies on the Doxygen XML documentation).
 207         # The output .log file currently needs to be here, since Jenkins
 208         # expects that.
 209         set(check_source_command
 210             ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/check-source.py
 211             -S ${CMAKE_SOURCE_DIR} -B ${CMAKE_BINARY_DIR}
 212             -l ${CMAKE_CURRENT_BINARY_DIR}/check-source.log
 213             --ignore ${CMAKE_CURRENT_SOURCE_DIR}/suppressions.txt
 214             --ignore-cycles ${CMAKE_CURRENT_SOURCE_DIR}/cycle-suppressions.txt)
 215         add_custom_target(check-source      COMMAND ${check_source_command}
 216             COMMENT "Checking source code for various issues" VERBATIM USES_TERMINAL)
 217         add_custom_target(check-source-fast COMMAND ${check_source_command}
 218             COMMENT "Checking source code for various issues" VERBATIM USES_TERMINAL)
 219         add_dependencies(check-source       doxygen-xml)
 220     endif()
 221 else()
 222     function (add_disabled_doxygen_target TARGET)
 223         add_custom_target(${TARGET}
 224             COMMAND ${CMAKE_COMMAND} -E echo
 225                 "Cannot build/run target ${TARGET} because Doxygen is not available"
 226             COMMENT "Doxygen not available" VERBATIM)
 227     endfunction()
 228     add_disabled_doxygen_target(doxygen-all)
 229     add_disabled_doxygen_target(doxygen-all-fast)
 230     add_disabled_doxygen_target(doxygen-xml)
 231     add_disabled_doxygen_target(doxygen-user)
 232     add_disabled_doxygen_target(doxygen-lib)
 233     add_disabled_doxygen_target(doxygen-lib-fast)
 234     add_disabled_doxygen_target(doxygen-full)
 235     add_disabled_doxygen_target(doxygen-full-fast)
 236     add_disabled_doxygen_target(check-source)
 237     add_disabled_doxygen_target(check-source-fast)
 238     add_disabled_doxygen_target(dep-graphs)
 239     add_disabled_doxygen_target(dep-graphs-fast)
 240 endif()