docs/doxygen/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(gmxCustomCommandUtilities)
  36 include(gmxOptionUtilities)
  37
  38 find_package(Doxygen QUIET)
  39 if (DOXYGEN_FOUND)
  40     # This logic closely follows that found in FindDoxygen.cmake for dot,
  41     # except that the PATH variable is not cached.
  42     find_program(DOXYGEN_MSCGEN_EXECUTABLE
  43         NAMES mscgen
  44         DOC "Message sequence chart renderer tool (http://www.mcternan.me.uk/mscgen/)")
  45     if (DOXYGEN_MSCGEN_EXECUTABLE)
  46         set(DOXYGEN_MSCGEN_FOUND TRUE)
  47         get_filename_component(DOXYGEN_MSCGEN_PATH "${DOXYGEN_MSCGEN_EXECUTABLE}" PATH)
  48     endif()
  49     mark_as_advanced(DOXYGEN_MSCGEN_EXECUTABLE)
  50 endif()
  51
  52 gmx_dependent_option(
  53     GMX_COMPACT_DOXYGEN
  54     "Skip parts of Doxygen documentation (in particular, many graphs) to save disk space and time"
  55     OFF
  56     DOXYGEN_FOUND)
  57 mark_as_advanced(GMX_COMPACT_DOXYGEN)
  58
  59 set(USE_PYTHON_SCRIPTS OFF)
  60 if (PYTHONINTERP_FOUND AND NOT PYTHON_VERSION_STRING VERSION_LESS "2.6")
  61     set(USE_PYTHON_SCRIPTS ON)
  62 endif()
  63
  64 # Note that if you relocate this file, you also need to change gmxtree.py.
  65 # TODO: Try to find a solution where this would be hard-coded here, completely
  66 # separate from the logic that generates it.
  67 set(INSTALLED_HEADERS_FILE ${PROJECT_BINARY_DIR}/src/gromacs/installed-headers.txt)
  68
  69 ########################################################################
  70 # Doxygen configuration
  71 #
  72 if (DOXYGEN_FOUND)
  73     # Generate Doxygen input configuration files
  74     file(GLOB NB_KERNEL_DIRS
  75          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
  76     list(REMOVE_ITEM NB_KERNEL_DIRS
  77          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
  78     foreach (dir ${NB_KERNEL_DIRS})
  79         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
  80             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${dir}")
  81     endforeach()
  82     set(DEPGRAPH_DIR ${CMAKE_CURRENT_BINARY_DIR}/depgraphs)
  83     set(DOXYGEN_SECTIONS "")
  84     set(DOXYGEN_EXTRA_SETTINGS "")
  85     if (GMX_COMPACT_DOXYGEN)
  86         set(DOXYGEN_EXTRA_SETTINGS "@INCLUDE   = ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile-compact")
  87     endif()
  88     configure_file(Doxyfile-common.cmakein Doxyfile-common)
  89     configure_file(Doxyfile-dev.cmakein Doxyfile-dev)
  90     configure_file(Doxyfile-full.cmakein Doxyfile-full)
  91     configure_file(Doxyfile-lib.cmakein Doxyfile-lib)
  92     configure_file(Doxyfile-user.cmakein Doxyfile-user)
  93     configure_file(Doxyfile-xml.cmakein Doxyfile-xml)
  94
  95     configure_file(RunDoxygen.cmake.cmakein RunDoxygen.cmake @ONLY)
  96     gmx_configure_version_file(Doxyfile-version.cmakein Doxyfile-version
  97                                TARGET doxygen-version)
  98
  99     # Add a stamp that gets updated whenever a source file that contributes to
 100     # Doxygen is updated.  All Doxygen targets can then depend on this stamp,
 101     # instead of each specifying this massive set of dependencies.
 102     # TODO: The set of files that affects Doxygen is not exactly the same as
 103     # that which affects the dependency graphs, and neither is captured
 104     # perfectly with this set, but this can be improved if it becomes a real
 105     # issue (the differences are mainly in the generated group kernel files,
 106     # but there are some minor other differences as well).
 107     if (SOURCE_IS_GIT_REPOSITORY AND GIT_FOUND)
 108         gmx_get_files_with_gitattribute(doxygen_sources gmx-doxygen)
 109         # Add also common configuration files that influence the generation.
 110         set(doxygen_deps
 111             ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-common
 112             ${CMAKE_CURRENT_BINARY_DIR}/RunDoxygen.cmake)
 113         if (GMX_COMPACT_DOXYGEN)
 114             list(APPEND doxygen_deps ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile-compact)
 115         endif()
 116         gmx_add_custom_output_target(doxygen-source-timestamp
 117             OUTPUT STAMP
 118             DEPENDS_FILE_LIST doxygen_sources
 119             DEPENDS ${doxygen_deps}
 120             COMMENT "Updating Doxygen source timestamp")
 121     else()
 122         # If there is no git, we just update the stamp every time, and the
 123         # builds are triggered every time.  This should be rare enough, but
 124         # this case still needs to be supported for the Jenkins job that builds
 125         # the documentation for a release from the release tarball.
 126         gmx_add_custom_output_target(doxygen-source-timestamp
 127             RUN_ALWAYS OUTPUT STAMP
 128             COMMENT "Updating Doxygen source timestamp")
 129     endif()
 130
 131     # Helper function to create a Doxygen build target
 132     function (add_doxygen_target TARGET TYPE COMMENT)
 133         set(_deps doxygen-source-timestamp doxygen-version
 134             ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-${TYPE})
 135         set(_fast_arg "")
 136         list (FIND ARGN "DEPGRAPHS" _index)
 137         if (${_index} GREATER -1)
 138             set(_fast_arg "ADD_FAST_TARGET")
 139             if (TARGET dep-graphs-dot)
 140                 list(APPEND _deps dep-graphs-dot)
 141             endif()
 142         endif()
 143         list (FIND ARGN "DEPGRAPHS" _index)
 144         if (${_index} GREATER -1)
 145             list(APPEND _deps doxygen-xml)
 146         endif()
 147         gmx_add_custom_output_target(${TARGET} OUTPUT STAMP ${_fast_arg}
 148             # Ensure the directory exists to avoid spurious warnings
 149             COMMAND ${CMAKE_COMMAND} -E make_directory ${DEPGRAPH_DIR}
 150             COMMAND ${CMAKE_COMMAND} -DDOCTYPE=${TYPE} -P RunDoxygen.cmake
 151             DEPENDS ${_deps}
 152             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 153             COMMENT "${COMMENT}" USES_TERMINAL)
 154         if (_fast_arg)
 155             add_dependencies(${TARGET}-fast doxygen-version)
 156         endif()
 157     endfunction()
 158
 159     # The XML target is necessary for the dependency graphs
 160     add_doxygen_target(doxygen-xml xml "Extracting Doxygen documentation to XML")
 161
 162     # Add targets for generating the dependency graphs; they are necessary for
 163     # the full and lib variants of the documentation.
 164     if (USE_PYTHON_SCRIPTS)
 165         # Add target that generates .dot files for the dependency graphs.
 166         # The output also depends on the Doxygen source files, but the
 167         # dependency on doxygen-xml takes care of that transitively.
 168         gmx_add_custom_output_target(dep-graphs-dot ADD_FAST_TARGET
 169             OUTPUT STAMP
 170             COMMAND ${PYTHON_EXECUTABLE}
 171                 ${CMAKE_CURRENT_SOURCE_DIR}/graphbuilder.py
 172                 -S ${CMAKE_SOURCE_DIR} -B ${CMAKE_BINARY_DIR}
 173                 --ignore-cycles ${CMAKE_CURRENT_SOURCE_DIR}/cycle-suppressions.txt
 174                 -o ${DEPGRAPH_DIR}
 175             DEPENDS doxygen-xml ${INSTALLED_HEADER_FILE}
 176                 ${CMAKE_CURRENT_SOURCE_DIR}/doxygenxml.py
 177                 ${CMAKE_CURRENT_SOURCE_DIR}/gmxtree.py
 178                 ${CMAKE_CURRENT_SOURCE_DIR}/graphbuilder.py
 179                 ${CMAKE_CURRENT_SOURCE_DIR}/cycle-suppressions.txt
 180             COMMENT "Generating include dependency graphs for dot"
 181             USES_TERMINAL)
 182
 183         # Add separate targets for converting the .dot files to .png.
 184         # These are not needed by the Doxygen targets, but are useful for
 185         # investigating just the graphs.
 186         set(dep_graphs_command_dot
 187             ${CMAKE_COMMAND} -DGRAPHDIR=${DEPGRAPH_DIR}
 188             -DDOT_EXECUTABLE=${DOXYGEN_DOT_EXECUTABLE}
 189             -P ${CMAKE_CURRENT_SOURCE_DIR}/generateGraphs.cmake)
 190         add_custom_target(dep-graphs      COMMAND ${dep_graphs_command_dot}
 191             COMMENT "Generating PNG include dependency graphs" VERBATIM)
 192         add_custom_target(dep-graphs-fast COMMAND ${dep_graphs_command_dot}
 193             COMMENT "Generating PNG include dependency graphs" VERBATIM)
 194         add_dependencies(dep-graphs      dep-graphs-dot)
 195         add_dependencies(dep-graphs-fast dep-graphs-dot-fast)
 196     endif()
 197
 198     # Create the actual targets to build the documentation.
 199     add_doxygen_target(doxygen-full full "Generating full documentation with Doxygen" DEPGRAPHS DEPXML)
 200     add_doxygen_target(doxygen-lib  lib  "Generating library documentation with Doxygen" DEPGRAPHS DEPXML)
 201     add_doxygen_target(doxygen-user user "Generating public API documentation with Doxygen" DEPXML)
 202     add_doxygen_target(doxygen-dev dev "Generating verbose developer docs with Doxygen" DEPGRAPHS DEPXML)
 203     # Convenience targets to build all the documentation flavors.
 204     add_custom_target(doxygen-all)
 205     add_custom_target(doxygen-all-fast)
 206     add_dependencies(doxygen-all      doxygen-full doxygen-lib doxygen-user)
 207     add_dependencies(doxygen-all-fast doxygen-full-fast doxygen-lib-fast doxygen-user)
 208
 209     # Finally, create the check-source target.
 210     if (USE_PYTHON_SCRIPTS)
 211         # TODO: Consider whether this is the best location for this code,
 212         # since not all of it is Doxygen-specific (but nearly all of it
 213         # relies on the Doxygen XML documentation).
 214         # The output .log file currently needs to be here, since Jenkins
 215         # expects that.
 216         set(check_source_command
 217             ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/check-source.py
 218             -S ${CMAKE_SOURCE_DIR} -B ${CMAKE_BINARY_DIR}
 219             -l ${CMAKE_CURRENT_BINARY_DIR}/check-source.log
 220             --ignore ${CMAKE_CURRENT_SOURCE_DIR}/suppressions.txt
 221             --ignore-cycles ${CMAKE_CURRENT_SOURCE_DIR}/cycle-suppressions.txt)
 222         add_custom_target(check-source      COMMAND ${check_source_command}
 223             COMMENT "Checking source code for various issues" VERBATIM USES_TERMINAL)
 224         add_custom_target(check-source-fast COMMAND ${check_source_command}
 225             COMMENT "Checking source code for various issues" VERBATIM USES_TERMINAL)
 226         add_dependencies(check-source       doxygen-xml)
 227     endif()
 228 else()
 229     function (add_disabled_doxygen_target TARGET)
 230         add_custom_target(${TARGET}
 231             COMMAND ${CMAKE_COMMAND} -E echo
 232                 "Cannot build/run target ${TARGET} because Doxygen is not available"
 233             COMMENT "Doxygen not available" VERBATIM)
 234     endfunction()
 235     add_disabled_doxygen_target(doxygen-all)
 236     add_disabled_doxygen_target(doxygen-all-fast)
 237     add_disabled_doxygen_target(doxygen-xml)
 238     add_disabled_doxygen_target(doxygen-user)
 239     add_disabled_doxygen_target(doxygen-lib)
 240     add_disabled_doxygen_target(doxygen-lib-fast)
 241     add_disabled_doxygen_target(doxygen-full)
 242     add_disabled_doxygen_target(doxygen-full-fast)
 243     add_disabled_doxygen_target(check-source)
 244     add_disabled_doxygen_target(check-source-fast)
 245     add_disabled_doxygen_target(dep-graphs)
 246     add_disabled_doxygen_target(dep-graphs-fast)
 247 endif()