docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 option(GMX_BUILD_WEBPAGE "Whether to try to configure to build the GROMACS static webpages" OFF)
  55 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  56 mark_as_advanced(GMX_BUILD_WEBPAGE GMX_BUILD_MANUAL)
  57
  58 find_package(PythonInterp)
  59 find_package(Sphinx 1.2.3 COMPONENTS pygments)
  60
  61 # Even if we aren't going to make the full webpage, set up to put all
  62 # the documentation output in the same place, for convenience
  63 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  64 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  65
  66 # The directory from which man pages will be installed; if it remains
  67 # empty, they will be silently skipped.
  68 set(MAN_PAGE_DIR)
  69 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  70     # When building from the tarball, install the bundled man pages
  71     # (unless overridden).
  72     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  73 endif()
  74
  75 add_subdirectory(doxygen)
  76
  77 set(SOURCE_MD5SUM "unknown" CACHE STRING "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  78 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  79 mark_as_advanced(SOURCE_MD5SUM)
  80
  81 if(GMX_BUILD_MANUAL)
  82     # Make sure we only do detection of manual-building dependencies
  83     # when the user opted in for that.
  84     add_subdirectory(manual)
  85 endif()
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/conf.py)
  93     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
  94     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  95     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_TARBALL)
  96         # The real build of the webpage happens from the tarball, and
  97         # this should be set to the matching MD5 sum.
  98         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
  99     else()
 100         # But for testing the webpage build (e.g. from the repo) we
 101         # need a default value.
 102         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
 103     endif()
 104     set(SPHINX_SOURCE_FILES
 105         index.rst
 106         download.rst
 107         dev-manual/index.rst
 108         dev-manual/doxygen.rst
 109         dev-manual/doxygen-links.rst
 110         dev-manual/formatting.rst
 111         dev-manual/gmxtree.rst
 112         dev-manual/includestyle.rst
 113         dev-manual/naming.rst
 114         dev-manual/style.rst
 115         dev-manual/tools.rst
 116         dev-manual/uncrustify.rst
 117         install-guide/index.rst
 118         man/gromacs.7.rst
 119         user-guide/index.rst
 120         user-guide/getting-started.rst
 121         user-guide/flow.rst
 122         user-guide/cutoff-schemes.rst
 123         user-guide/mdrun-features.rst
 124         user-guide/mdrun-performance.rst
 125         user-guide/mdp-options.rst
 126         user-guide/file-formats.rst
 127         user-guide/tools.rst
 128         user-guide/environment-variables.rst
 129         user-guide/plotje.gif
 130         user-guide/xvgr.gif
 131         conf.py
 132         links.dat
 133         )
 134
 135     # Remove other rst files from the build tree, since they confuse Sphinx.
 136     file(GLOB_RECURSE _obsolete_sources RELATIVE ${SPHINX_INPUT_DIR}
 137          ${SPHINX_INPUT_DIR}/*.rst)
 138     list(REMOVE_ITEM _obsolete_sources ${SPHINX_SOURCE_FILES})
 139     foreach(_file ${_obsolete_sources})
 140         # Skip generated files.
 141         if (NOT _file MATCHES "^(programs/.*|man/bytopic)\\.rst$")
 142             message(STATUS "Removing obsolete Sphinx input ${_file}")
 143             file(REMOVE ${SPHINX_INPUT_DIR}/${_file})
 144         endif()
 145     endforeach()
 146
 147     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 148         EXTRA_VARS
 149             SPHINX_EXTENSION_PATH
 150             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 151             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 152             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 153         COMMENT "Configuring Sphinx configuration file")
 154     set(SPHINX_INPUT_FILES ${SPHINX_CONFIG_VARS_FILE})
 155     foreach(_file ${SPHINX_SOURCE_FILES})
 156         add_custom_command(
 157             OUTPUT ${SPHINX_INPUT_DIR}/${_file}
 158             COMMAND ${CMAKE_COMMAND} -E copy
 159                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 160                 ${SPHINX_INPUT_DIR}/${_file}
 161             DEPENDS
 162                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 163             COMMENT "Copying Sphinx input file ${_file}"
 164             VERBATIM)
 165         list(APPEND SPHINX_INPUT_FILES ${SPHINX_INPUT_DIR}/${_file})
 166     endforeach()
 167     gmx_add_custom_output_target(sphinx-input OUTPUT STAMP
 168         DEPENDS ${SPHINX_INPUT_FILES})
 169     # TODO: Make this remove obsolete .rst files.
 170     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 171         COMMAND ${CMAKE_COMMAND} -E make_directory programs
 172         COMMAND gmx -quiet help -export rst
 173         DEPENDS gmx
 174         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 175         COMMENT "Generating reStructuredText help")
 176     # This dependency ensures that the directories exist before the
 177     # executable tries to write things there.
 178     add_dependencies(sphinx-programs sphinx-input)
 179
 180     # Make the INSTALL file for CPack for the tarball. This gets put
 181     # into the tarball via the CPack rules below, which requires that
 182     # the INSTALL file is in a separate directory by itself.
 183     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 184     add_custom_target(install-guide
 185         COMMAND
 186             ${SPHINX_EXECUTABLE}
 187             -q -b text
 188             -w sphinx-install.log
 189             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 190             -c ${SPHINX_INPUT_DIR}
 191             "${SPHINX_INPUT_DIR}/install-guide"
 192             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 193         COMMAND
 194             ${CMAKE_COMMAND} -E rename
 195             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 196             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 197         WORKING_DIRECTORY
 198             ${CMAKE_CURRENT_BINARY_DIR}
 199         COMMENT "Building INSTALL with Sphinx"
 200         VERBATIM
 201         )
 202     add_dependencies(install-guide sphinx-input)
 203     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 204
 205     # Sphinx cache with pickled ReST documents
 206     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 207
 208     add_custom_target(webpage-sphinx
 209         COMMAND
 210             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 211         COMMAND
 212             ${SPHINX_EXECUTABLE}
 213             -q -b html
 214             -w sphinx-html.log
 215             -d "${SPHINX_CACHE_DIR}"
 216             "${SPHINX_INPUT_DIR}"
 217             "${HTML_OUTPUT_DIR}"
 218         WORKING_DIRECTORY
 219             ${CMAKE_CURRENT_BINARY_DIR}
 220         COMMENT "Building HTML documentation with Sphinx"
 221         VERBATIM
 222         )
 223     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 224
 225     add_custom_target(man
 226         COMMAND
 227             ${SPHINX_EXECUTABLE}
 228             -q -b man
 229             -w sphinx-man.log
 230             -d ${SPHINX_CACHE_DIR}
 231             -t do_man
 232             ${SPHINX_INPUT_DIR}
 233             ${CMAKE_CURRENT_BINARY_DIR}/man
 234         COMMENT "Building man pages with Sphinx"
 235         VERBATIM)
 236     add_dependencies(man sphinx-input sphinx-programs)
 237     if (GMX_BUILD_HELP)
 238         # If requested, install the man pages built by the 'man' target
 239         # created above.  Nothing will be installed if the user did not
 240         # manually build the target.
 241         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 242     endif()
 243 endif()
 244
 245 if (MAN_PAGE_DIR)
 246     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 247     # Trailing slash on directory is significant for
 248     # install(DIRECTORY). See CMake docs.
 249     install(DIRECTORY ${MAN_PAGE_DIR}/
 250         DESTINATION ${MAN_INSTALL_DIR}/man1
 251         COMPONENT man OPTIONAL
 252         FILES_MATCHING PATTERN "*.1")
 253     install(DIRECTORY ${MAN_PAGE_DIR}/
 254         DESTINATION ${MAN_INSTALL_DIR}/man7
 255         COMPONENT man OPTIONAL
 256         FILES_MATCHING PATTERN "*.7")
 257 endif()
 258 gmx_cpack_add_generated_source_directory(man)
 259
 260 set(HTML_BUILD_IS_POSSIBLE OFF)
 261 # We can only configure to build the webpage if the user asked for it,
 262 # the build is outside of the source dir, and all the components can
 263 # be built. There's no intrinsic need to be talkative if we fail -
 264 # most people never need to know, unless they've asked for the webpage
 265 # build.
 266 if(GMX_BUILD_WEBPAGE)
 267     set(HTML_BUILD_IS_POSSIBLE ON)
 268     # Next, turn it off in any of the preconditions are unsatisified
 269
 270     if(NOT MANUAL_BUILD_IS_POSSIBLE)
 271         set(HTML_BUILD_IS_POSSIBLE OFF)
 272         message(STATUS "Cannot build webpage without being able to build the reference PDF manual")
 273     endif()
 274
 275     if(NOT PYTHON_EXECUTABLE)
 276         set(HTML_BUILD_IS_POSSIBLE OFF)
 277         message(STATUS "Cannot build webpage without python")
 278     endif()
 279
 280     if(NOT SPHINX_FOUND)
 281         set(HTML_BUILD_IS_POSSIBLE OFF)
 282         message(STATUS "Cannot build webpage without sphinx")
 283     endif()
 284
 285     if(NOT DOXYGEN_EXECUTABLE)
 286         set(HTML_BUILD_IS_POSSIBLE OFF)
 287         message(STATUS "Cannot build webpage without doxygen")
 288     endif()
 289
 290     if(NOT DOXYGEN_MSCGEN_EXECUTABLE)
 291         set(HTML_BUILD_IS_POSSIBLE OFF)
 292         message(STATUS "Cannot build webpage without mscgen")
 293     endif()
 294 endif()
 295
 296 # TODO Get rid of the remaining content in old-html
 297 add_custom_target(webpage-old-images
 298     ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/old-html ${HTML_OUTPUT_DIR}
 299     COMMENT "Copying flowchart images"
 300     VERBATIM
 301     )
 302
 303 if(HTML_BUILD_IS_POSSIBLE)
 304     # Make the PDF reference guide
 305     # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 306     add_custom_command(
 307         OUTPUT ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 308         COMMAND ${CMAKE_COMMAND}
 309             -E remove -f ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 310         COMMAND ${CMAKE_COMMAND}
 311             -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 312         # UseLATEX.cmake makes a target called pdf, not ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf
 313         DEPENDS pdf
 314         VERBATIM
 315         )
 316
 317     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 318     # makes all the Doxygen output directly in
 319     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 320     # to).
 321
 322     # Add a top-level target for the others to hook onto
 323     add_custom_target(webpage
 324         DEPENDS
 325            ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf
 326            ${extra_webpage_dependencies}
 327         VERBATIM
 328         )
 329     add_dependencies(webpage webpage-sphinx webpage-old-images doxygen-all)
 330 else()
 331     add_custom_target(webpage
 332         COMMAND ${CMAKE_COMMAND} -E echo "Cannot build webpage because of missing requirements. Check cmake status output for reasons"
 333         COMMENT "Webpage build disabled"
 334         )
 335 endif()