docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.4.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # The directory from which man pages will be installed; if it remains
  76 # empty, they will be silently skipped.
  77 set(MAN_PAGE_DIR)
  78 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  79     # When building from the tarball, install the bundled man pages
  80     # (unless overridden).
  81     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  82 endif()
  83
  84 add_subdirectory(doxygen)
  85 add_subdirectory(manual)
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/commitstyle.rst
 108         dev-manual/documentation-generation.rst
 109         dev-manual/contribute.rst
 110         dev-manual/doxygen.rst
 111         dev-manual/error-handling.rst
 112         dev-manual/formatting.rst
 113         dev-manual/gmxtree.rst
 114         dev-manual/includestyle.rst
 115         dev-manual/jenkins.rst
 116         dev-manual/language-features.rst
 117         dev-manual/naming.rst
 118         dev-manual/overview.rst
 119         dev-manual/redmine-states.png
 120         dev-manual/relocatable-binaries.rst
 121         dev-manual/reportstyle.rst
 122         dev-manual/style.rst
 123         dev-manual/testutils.rst
 124         dev-manual/tools.rst
 125         dev-manual/uncrustify.rst
 126         fragments/doxygen-links.rst
 127         install-guide/index.rst
 128         release-notes/index.rst
 129         release-notes/2018/2018.1.rst
 130         release-notes/2018/major/highlights.rst
 131         release-notes/2018/major/features.rst
 132         release-notes/2018/major/performance.rst
 133         release-notes/2018/major/tools.rst
 134         release-notes/2018/major/bugs-fixed.rst
 135         release-notes/2018/major/removed-features.rst
 136         release-notes/2018/major/portability.rst
 137         release-notes/2018/major/miscellaneous.rst
 138         user-guide/index.rst
 139         user-guide/cutoff-schemes.rst
 140         user-guide/getting-started.rst
 141         user-guide/force-fields.rst
 142         user-guide/faq.rst
 143         user-guide/flow.rst
 144         user-guide/floating-point.rst
 145         user-guide/system-preparation.rst
 146         user-guide/managing-simulations.rst
 147         user-guide/mdrun-features.rst
 148         user-guide/mdrun-performance.rst
 149         user-guide/mdp-options.rst
 150         user-guide/run-time-errors.rst
 151         user-guide/file-formats.rst
 152         user-guide/cmdline.rst
 153         user-guide/environment-variables.rst
 154         user-guide/terminology.rst
 155         user-guide/plotje.gif
 156         user-guide/xvgr.gif
 157         conf.py
 158         links.dat
 159         )
 160
 161     include(SphinxMacros.cmake)
 162     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 163
 164     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 165     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 166         EXTRA_VARS
 167             SPHINX_EXTENSION_PATH RELENG_PATH
 168             EXPECTED_DOXYGEN_VERSION
 169             EXPECTED_SPHINX_VERSION
 170             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 171             REQUIRED_OPENCL_MIN_VERSION
 172             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 173             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 174             GMX_TNG_MINIMUM_REQUIRED_VERSION
 175             GMX_LMFIT_MINIMUM_REQUIRED_VERSION
 176         COMMENT "Configuring Sphinx configuration file")
 177     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 178     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 179     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 180         include(${RELENG_PATH}/docs/FileList.cmake)
 181         gmx_add_sphinx_source_files(
 182             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 183             FILES ${RELENG_SPHINX_FILES})
 184     else()
 185         gmx_add_sphinx_source_files(FILES
 186             dev-manual/releng/index.rst
 187             dev-manual/releng/jenkins-howto.rst
 188             dev-manual/releng/jenkins-ui.rst
 189             )
 190     endif()
 191     gmx_add_sphinx_input_target(sphinx-input)
 192     # Remove other rst files from the build tree, since they confuse Sphinx.
 193     # Skip generated files in onlinehelp/, and fragments.
 194     # The latter do not cause issues with obsolete files, as they
 195     # are not considered as Sphinx input files, but will only be
 196     # included using an explicit .. include::.
 197     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 198
 199     # TODO: Make this remove obsolete .rst files.
 200     # TODO: This does not work in cross-compilation scenarios; disable up to
 201     # the necessary level.
 202     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 203         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 204         COMMAND gmx -quiet help -export rst
 205         DEPENDS gmx
 206         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 207         COMMENT "Generating reStructuredText help")
 208     # This dependency ensures that the directories exist before the
 209     # executable tries to write things there.
 210     add_dependencies(sphinx-programs sphinx-input)
 211
 212     # Make the INSTALL file for CPack for the tarball. This gets put
 213     # into the tarball via the CPack rules below, which requires that
 214     # the INSTALL file is in a separate directory by itself.
 215     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 216     add_custom_target(install-guide
 217         COMMAND
 218             ${SPHINX_EXECUTABLE}
 219             -q -b text
 220             -w sphinx-install.log
 221             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 222             -c ${SPHINX_INPUT_DIR}
 223             "${SPHINX_INPUT_DIR}/install-guide"
 224             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 225         COMMAND
 226             ${CMAKE_COMMAND} -E rename
 227             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 228             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 229         WORKING_DIRECTORY
 230             ${CMAKE_CURRENT_BINARY_DIR}
 231         COMMENT "Building INSTALL with Sphinx"
 232         VERBATIM
 233         )
 234     add_dependencies(install-guide sphinx-input)
 235     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 236
 237     # Sphinx cache with pickled ReST documents
 238     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 239
 240     add_custom_target(webpage-sphinx
 241         COMMAND
 242             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 243         COMMAND
 244             ${SPHINX_EXECUTABLE}
 245             -q -b html
 246             -w sphinx-html.log
 247             -d "${SPHINX_CACHE_DIR}"
 248             "${SPHINX_INPUT_DIR}"
 249             "${HTML_OUTPUT_DIR}"
 250         WORKING_DIRECTORY
 251             ${CMAKE_CURRENT_BINARY_DIR}
 252         COMMENT "Building HTML documentation with Sphinx"
 253         VERBATIM
 254         )
 255     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 256
 257     add_custom_target(man
 258         COMMAND
 259             ${SPHINX_EXECUTABLE}
 260             -q -b man
 261             -w sphinx-man.log
 262             -d ${SPHINX_CACHE_DIR}
 263             -t do_man
 264             ${SPHINX_INPUT_DIR}
 265             ${CMAKE_CURRENT_BINARY_DIR}/man
 266         COMMENT "Building man pages with Sphinx"
 267         VERBATIM)
 268     add_dependencies(man sphinx-input sphinx-programs)
 269     if (GMX_BUILD_HELP)
 270         # If requested, install the man pages built by the 'man' target
 271         # created above.  Nothing will be installed if the user did not
 272         # manually build the target.
 273         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 274     endif()
 275 else()
 276     add_custom_target(webpage-sphinx
 277         COMMAND ${CMAKE_COMMAND} -E echo
 278             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 279         VERBATIM)
 280     add_custom_target(install-guide
 281         COMMAND ${CMAKE_COMMAND} -E echo
 282             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 283         VERBATIM)
 284     add_custom_target(man
 285         COMMAND ${CMAKE_COMMAND} -E echo
 286             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 287         VERBATIM)
 288 endif()
 289
 290 if (MAN_PAGE_DIR)
 291     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 292     # Trailing slash on directory is significant for
 293     # install(DIRECTORY). See CMake docs.
 294     install(DIRECTORY ${MAN_PAGE_DIR}/
 295         DESTINATION ${MAN_INSTALL_DIR}/man1
 296         COMPONENT man OPTIONAL
 297         FILES_MATCHING PATTERN "*.1")
 298 endif()
 299 gmx_cpack_add_generated_source_directory(man)
 300
 301 # Determine whether we can build all the HTML pages and content linked from
 302 # there.  If not, construct an informative message if the user tries to
 303 # build the target; most people never need to know, unless they've asked for
 304 # the webpage build.
 305 set(HTML_BUILD_IS_POSSIBLE ON)
 306 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 307 set(HTML_BUILD_WARNINGS)
 308
 309 # Next, turn it off if any of the preconditions are unsatisified
 310 if (NOT PYTHON_EXECUTABLE)
 311     set(HTML_BUILD_IS_POSSIBLE OFF)
 312     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 313 elseif (NOT SPHINX_FOUND)
 314     # Hardly anything gets built if Sphinx is not available, so don't bother.
 315     set(HTML_BUILD_IS_POSSIBLE OFF)
 316     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 317 endif()
 318 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 319     list(APPEND HTML_BUILD_WARNINGS
 320          "Reference PDF manual was not built, so links to it do not work")
 321 endif()
 322 if (NOT DOXYGEN_EXECUTABLE)
 323     list(APPEND HTML_BUILD_WARNINGS
 324         "Doxygen was not available, so links to Doxygen do not work")
 325 endif()
 326 if (NOT DOXYGEN_DOT_EXECUTABLE)
 327     list(APPEND HTML_BUILD_WARNINGS
 328         "dot/graphviz was not found, so some graphs are missing")
 329 endif()
 330
 331 if (HTML_BUILD_IS_POSSIBLE)
 332     set(_webpage_target_properties)
 333     if (HTML_BUILD_WARNINGS)
 334         list(APPEND _webpage_target_properties
 335              COMMAND ${CMAKE_COMMAND} -E echo
 336                  "webpage was built, but with the following limitations:")
 337         foreach(_warning ${HTML_BUILD_WARNINGS})
 338         list(APPEND _webpage_target_properties
 339              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 340         endforeach()
 341     endif()
 342
 343     if (MANUAL_BUILD_IS_POSSIBLE)
 344         # Make the PDF reference guide
 345         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 346         # TODO Make this depend on the output of the manual build, so that the
 347         # file actually gets copied multiple times.
 348         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 349         add_custom_command(
 350             OUTPUT ${_manual_target_location}
 351             COMMAND ${CMAKE_COMMAND}
 352                 -E remove -f ${_manual_target_location}
 353             COMMAND ${CMAKE_COMMAND}
 354                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 355             DEPENDS manual
 356             VERBATIM)
 357         list(APPEND _webpage_target_properties
 358              DEPENDS ${_manual_target_location})
 359     endif()
 360
 361     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 362     # makes all the Doxygen output directly in
 363     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 364     # to).
 365
 366     # Add a top-level target that builds everything related to the webpage,
 367     # for Jenkins (and possibly others) to use
 368     add_custom_target(webpage ${_webpage_target_properties}
 369         COMMENT "Building webpage"
 370         VERBATIM)
 371     add_dependencies(webpage webpage-sphinx doxygen-all)
 372 else()
 373     add_custom_target(webpage
 374         COMMAND ${CMAKE_COMMAND} -E echo
 375             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 376         COMMENT "Webpage build not possible"
 377         VERBATIM)
 378 endif()